Tutoriel : Apprenez à programmer en VB .NET

D'où vient le Visual Basic ?

Nous allons donc commencer par un petit morceau d'histoire, car il est toujours intéressant de connaître le pourquoi de l'invention d'un langage (il doit bien y avoir une raison ; sinon, nous serions encore tous à l'assembleur :p ).

J'ai récupéré l'essentiel des articles de Wikipédia sur notre sujet et vous l'ai résumé.

Le BASIC

BASIC est un acronyme pour Beginner's All-purpose Symbolic Instruction Code. Le BASIC a été conçu en 1963 par John George Kemeny et Thomas Eugene Kurtz au Dartmouth College pour permettre aux étudiants qui ne travaillaient pas dans des filières scientifiques d'utiliser les ordinateurs. En effet, à l'époque, l'utilisation des ordinateurs nécessitait l'emploi d'un langage de programmation assembleur dédié, ce dont seuls les spécialistes étaient capables.

Les huit principes de conception du BASIC étaient :

• Être facile d'utilisation pour les débutants (Beginner) ;

• Être un langage généraliste (All-purpose) ;

• Autoriser l'ajout de fonctionnalités pour les experts (tout en gardant le langage simple pour les débutants) ;

• Être interactif ;

• Fournir des messages d'erreur clairs et conviviaux ;

• Avoir un délai de réaction faible pour les petits programmes ;

• Ne pas nécessiter la compréhension du matériel de l'ordinateur ;

• Isoler l'utilisateur du système d'exploitation.

Tout ce qu'il nous faut, donc. :)

Le Visual Basic

De ce langage — le BASIC — est né le Visual Basic. Le VB est directement dérivé du BASIC et permet le développement rapide d'applications, la création d'interfaces utilisateur graphiques, l'accès aux bases de données, ainsi que la création de contrôles ou d'objets ActiveX.
Je pense qu'avec ces possibilités on va déjà pouvoir créer de petites choses. :p
Le traditionnel « Hello World ! » en Visual Basic :

Sub Main()
    MsgBox("Hello World !")
End Sub

Ce code ouvre une MsgBox (comme un message d'erreur Windows) dans laquelle est contenu le message « Hello World ! ».

Il faut savoir que le BASIC, ancêtre du Visual Basic, est un langage de haut niveau. En programmation, les langages peuvent se trier par niveau : plus le niveau du langage est bas, plus celui-ci est proche du matériel informatique (le C est considéré comme un langage de bas niveau). Un développeur utilisant un langage de bas niveau devra, entre autres, gérer la mémoire qu'il utilise. Il peut même aller jusqu'à spécifier les registres matériels dans lesquels écrire pour faire fonctionner son programme.
Un langage de haut niveau fait abstraction de tout cela ; il le fait en interne, c'est-à-dire que le développeur ne voit pas toutes ces opérations. Après, tout dépend de votre envie et de votre cahier des charges : si vous devez développer une application interagissant directement avec les composants, un langage de bas niveau est requis. En revanche, si vous ne souhaitez faire que du graphisme, des calculs, du fonctionnel, etc., un langage de haut niveau vous permettra de vous soustraire à beaucoup de manipulations fastidieuses.

Le Visual Basic est donc un langage de haut niveau. Il a d'emblée intégré les concepts graphiques et visuels des programmes que l'on concevait avec. Il faut savoir que les premières versions de VB, sorties au début des années 1990, tournaient sous DOS et utilisaient des caractères pour simuler une fenêtre.

|---------------------------|
|    Ma fenêtre en VB 1.0   |
|---------------------------|
|                           |
|                           |
|                           |
|                           |
|                           |
|                           |
|---------------------------|

Ce n'était pas la joie, certes, mais déjà une révolution !

Aujourd'hui, le VB a laissé place au VB .NET. Le suffixe .NET spécifie en fait qu'il nécessite le framework.NET de Microsoft afin de pouvoir être exécuté. À savoir qu'il est également possible d'exécuter un programme créé en VB sous d'autres plates-formes que Windows grâce à Mono.

Très bonne question. Un framework (dans notre cas, le framework .NET de Microsoft) est une sorte d'immense bibliothèque informatique contenant des outils qui vont faciliter la vie du développeur. Le framework .NET est compatible avec le Visual Basic et d'autres langages tels que le C#, le F#, le J#, etc.

La plate-forme .NET fournit un ensemble de fonctionnalités qui facilitent le développement de tous types d'applications :

• Les applications Windows classiques ;

• Les applications web ;

• Les services Windows ;

• Les services web.

En Visual Basic, toutes ces applications sont réalisables grâce au framework .NET.

Du développement de l'application jusqu'à son exécution, le framework .NET prend en charge l'intégralité de la vie de cette application.

Ce framework doit être hébergé sur le système d'exploitation avec lequel il doit interagir. Pas d'inquiétude, nous allons nous en charger.

Le framework .NET (voir figure suivante) a été créé par Microsoft : le premier système d'exploitation permettant de le posséder est bien sûr Windows, mais d'autres versions sont disponibles, permettant l'adaptation de la plate-forme .NET à des systèmes d'exploitation tel que Linux ou Unix.

Cela doit vous sembler bien compliqué, mais retenez bien son utilité première : nous mâcher le travail. Par exemple, si vous souhaitez lire et écrire dans un fichier (ce que nous verrons plus tard), le développement depuis zéro d'un programme capable d'effectuer cette tâche est longue et fastidieuse. Il va falloir envisager toutes les possibilités d'erreurs, trouver un moyen d'interagir avec votre disque dur, etc. Cela s'appelle de la programmation bas niveau (proche du matériel informatique en lui-même).

Cependant, des personnes ont déjà codé les éléments permettant d'effectuer ces actions. Tout cela a été intégré au framwork .NET et installé sur vos machines. Vous allez donc pouvoir réutiliser leur travail pour vous simplifier la vie et diminuer le risque d'erreurs. Cela s'appelle de la programmation haut niveau (éloigné du matériel).

L'environnement de développement

Eh oui, pour coder en Visual Basic, il nous faut des outils adaptés !

Comme je l'ai expliqué précédemment, nous allons utiliser du Visual Basic et non pas du BASIC. Cela signifie que nous créerons des interfaces graphiques et ergonomiques pour nos logiciels, et tout cela facilement. :-°

Non, on ne va pas procéder de la sorte. Ce serait bien trop compliqué !
Sachez que des outils spécifiques existent : utilisons-les ! Bien, allons-y…

Visual Studio Express

Microsoft a créé une suite logicielle nommée « Visual Studio », qui rassemble Visual Basic, Visual C++, Visual C#, et j'en passe.

La suite provenant de Microsoft, on peut facilement deviner qu'elle coûte une certaine somme !
Heureusement, l'éditeur nous propose généreusement une version « Express » gratuite de chaque logiciel de cette suite.

Nous allons donc utiliser Visual Basic 2010 Express (les étudiants peuvent toujours récupérer une version de Visual Studio 2010 sur la MSDN pour étudiants).

Si vous êtes assez débrouillards, vous pouvez toujours conserver votre version. Je m'explique : Microsoft a sorti des versions différentes du framework (comme des bibliothèques) pour chaque version de Visual Studio : VS 2003 (Framework 1.1), VS 2005 (Framework 2.0), VS 2008 (Framework 3.5) et VS 2010 (Framework 4.0).

Vous l'avez donc certainement compris : si vous utilisez une autre version, vous aurez un ancien framework. De ce fait, certains objets ou propriétés évoqués ou utilisés dans le tutoriel sont peut-être différents voire inexistants dans les versions précédentes. Je vous conseille donc tout de même d'installer cette version « Express » qui est relativement légère et vous permettra de suivre le tutoriel dans les meilleures conditions.

Étape par étape

Passons immédiatement au téléchargement du petit logiciel intermédiaire, qui ne pèse que quelques Mo et qui va télécharger Visual Basic 2010 Express.

Vous lancez donc le programme et arrivez à la première page (figure suivante).

Sur cette page, l'installateur vous propose déjà une case à cocher. Si vous autorisez Microsoft à récupérer des informations sur votre ordinateur et des statistiques pour ses bases de données, laissez comme tel. Dans le cas contraire, décochez la case. Cliquez ensuite sur le bouton « Suivant ». Lisez puis acceptez les termes du contrat de licence. Cela fait, appuyez une nouvelle fois sur « Suivant ».

Comme pour n'importe quelle autre installation, choisissez le dossier dans lequel vous souhaitez que le logiciel s'installe. Cliquez ensuite sur « Installer ». Une nouvelle page apparaît. Elle indique la progression du téléchargement du logiciel, le taux de transfert et la partie du programme en cours d'installation, comme à la figure suivante.

Il ne vous reste plus qu'à attendre la fin du téléchargement, suivi de l'installation. Une fois cela terminé, vous voilà avec Visual Basic 2010 Express installé !

L'interface de VB 2010 Express

Vous avez donc installé Visual Basic 2010 Express. En passant, sachez que ce dernier est un IDE (environnement de développement intégré) qui rassemble les fonctions de conception, édition de code, compilation et débogage. Lors du premier lancement, vous constatez qu'un petit temps de chargement apparaît : le logiciel configure l'interface pour la première fois.

Page d'accueil

Nous voici sur la page de démarrage du logiciel (voir figure suivante). Vous pouvez la parcourir, elle contient des informations utiles aux développeurs (vous) et conservera l'historique de vos projets récents.

Barre d'outils

La barre d'outils (voir figure suivante) vous sera indispensable afin de travailler avec une parfaite ergonomie. Je vais récapituler les boutons présents (de gauche à droite), actifs ou non durant vos travaux.

• 

  Nouveau projet : crée un projet.

• 

  Ouvrir un fichier : à utiliser pour ouvrir un projet existant ou une page simple.

• 

  Ajouter un nouvel élément : disponible quand un projet est ouvert ; il permet d'ajouter des feuilles au projet.

• 

  Enregistrer : raccourci CTRL + S.

• 

  Enregistrer tout : raccourci CTRL + MAJ + S.

• 

  Couper : raccourci CTRL + X.

• 

  Copier : raccourci CTRL + C.

• 

  Coller : raccourci CTRL + V.

• 

  Rechercher : fort utile dans le cas de gros projets ; raccourci CTRL + F.

• 

  Commenter les lignes : je reviendrai plus tard sur le principe des commentaires.

• 

  Décommenter les lignes.

• 

  Annuler : raccourci CTRL + Z.

• 

  Rétablir : raccourci CTRL + MAJ + Z.

• 

  Démarrer le débogage : expliqué plus tard.

• 

  Arrêter le débogage : expliqué plus tard.

• 

  Pas à pas détaillé : expliqué plus tard.

• 

  Pas à pas principal : expliqué plus tard.

• 

  Pas à pas sortant : expliqué plus tard.

• 

  Explorateur de solutions : affiche la fenêtre de solutions.

• 

  Fenêtre des propriétés : affiche la fenêtre des propriétés.

• 

  Boîte à outils : permet d'afficher la boîte à outils.

• 

  Gestionnaire d'extensions : permet de gérer les extensions que vous pouvez ajouter à Visual Basic Express.

• 

  Liste d'erreurs : affiche la fenêtre des erreurs.

Toutes ces commandes ne seront pas forcément utiles ; au besoin, n'hésitez pas à revenir voir cette liste.

Nouveau projet

Je vous invite, seulement pour appréhender l'interface, à créer un projet Windows Forms (voir figure suivante). Pour ce faire, trois solutions s'offrent à vous : cliquer sur le bouton « Nouveau projet », se rendre dans le menu Fichier > Nouveau projet, ou utiliser le raccourci clavier CTRL + N.

Cliquez donc sur l'icône correspondant à Application Windows Forms.
Saisissez un nom de projet dans la case « Nom ». Vous pouvez laisser le nom par défaut, ce projet ne sera pas utilisé. Cliquez ensuite sur « OK », et vous voici dans un nouveau projet ! Vous remarquez que beaucoup plus de choses s'offrent à vous (voir figure suivante).

Nous allons tout voir en détail.

Espace de travail

Cette partie (voir figure suivante) correspond à notre espace de travail : c'est ici que nous allons créer nos fenêtres, entrer nos lignes de code, etc.

Boîte à outils

Sur la gauche de l'interface, nous avons accès à la boîte à outils. Pour afficher cette boîte, vous allez devoir cliquer sur le petit onglet qui dépasse sur la gauche. Une fois la boîte sortie, cliquez sur la punaise pour la « fixer » et la maintenir visible. La boîte à outils (voir figure suivante) nous sera d'une grande utilité lorsque nous créerons la partie graphique de nos applications, mais inutile lors de l'écriture du code VB. Dès lors, si vous voulez la rentrer automatiquement, cliquez une nouvelle fois sur la punaise.

Fenêtre de solutions

De l'autre côté de notre écran, nous remarquons la fenêtre de solutions (voir figure suivante) : elle récapitule l'arborescence de notre projet. Elle servira également à gérer les bases de données, mais plus tard. :)

Fenêtre des propriétés

Autre partie essentielle : la fenêtre des propriétés (voir figure suivante) qui va nous permettre, en mode conception, de modifier les propriétés de nos objets. Vous n'avez rien compris ? Mettez ce terme dans un coin de votre tête, nous allons rapidement y revenir.

La dernière fenêtre est celle des erreurs. J'espère que vous n'en aurez pas l'utilité, mais elle saura se faire remarquer quand il le faudra, ne vous inquiétez pas. :p

En attendant, je vous laisse vous familiariser avec l'environnement : déplacez les boîtes, les fenêtres, et redimensionnez-les à votre guise.

• Le Visual Basic .NET est une amélioration du langage BASIC qui ajoute une partie de gestion de l'interface visuelle associée au framework .NET de Microsoft.

• On télécharge Visual Basic Express edition sur le site de Microsoft, cette version est gratuite et sans limitation de temps.

Notre premier programme !

Nous allons donc aborder les principes fondamentaux du langage. Pour cela, empressons-nous de créer un nouveau projet, cette fois en application console.

Créez un nouveau projet (CTRL + N) et cliquez sur Application console. De nombreux mots de langue étrangère apparaissent. Pas de panique, je vais vous tout expliquer.

Voici ce qui devrait s'afficher chez vous :

Module Module1

    Sub Main()

    End Sub

End Module

Si ce n'est pas exactement ce code que vous voyez, faites en sorte que cela soit le cas, afin que nous ayons tous le même point de départ.

Ces mots barbares figurant dans votre feuille de code sont indispensables ! Si vous les supprimez, l'application ne se lancera pas. C'est le code minimal que l'IDE (Visual Studio) génère lorsque l'on crée un projet de type console.

Chaque grosse partie, telle qu'une fonction, un module, un sub, voire une boucle conditionnelle (nous allons revenir sur ces termes), aura une balise de début : ici, Module Module1 et Sub Main(), et une balise de fin : End Module et End Sub. Module1 est le nom du module, que vous pouvez modifier si l'envie vous en prend. Il nous sera réellement pratique lorsque nous utiliserons plusieurs feuilles.

Pour ce qui est du Main(), n'y touchez pas, car lorsqu'on va lancer le programme la première chose que ce dernier va faire sera de localiser la partie appelée Main() et de sauter dedans. S'il ne la trouve pas, cela ne fonctionnera pas ! :p

Tout d'abord, nous cherchons le moyen d'écrire quelque chose dans la console… Ah, j'ai omis de vous expliquer en quoi consiste la console. Je suis confus ! Regardez la figure suivante.

Voilà ma console. Je suis conscient que ce n'est visuellement pas exceptionnel, mais c'est plus simple pour apprendre les bases.

Du calme ! L'essentiel dans l'apprentissage de la programmation est d'y aller progressivement.

Cette console vous permettra d'apprendre les bases et les concepts fondamentaux du VB sans vous embrouiller directement l'esprit avec les objets qui orneront nos interfaces graphiques (c'est pour votre bien ;) ). Nous allons donc créer un programme qui écrit dans cette console. Je vais écrire pour vous la ligne qui va effectuer cette action.

Hello World !

Console.Write("Hello World !")

Donc, pour ceux qui ont quelque peu suivi, où va-t-on placer cette ligne ?

Dans le Main() ! Eh bien oui, je l'ai dit plus haut : le programme va se rendre directement dans le Main(), autant donc y placer nos lignes (instructions) — c'est-à-dire entre Sub Main() et End Sub. :)

Pour lancer le programme, cliquez sur la petite flèche verte de la barre d'outils.

Déroulement du programme

Je vous explique : dans notre cas, le programme entre dans le Main() et exécute les actions de haut en bas, instruction par instruction. Attention, ce ne sera plus le cas lorsque nous aborderons des notions telles que les boucles ou les fonctions.

Voici nos lignes de code :

1. Module Module1 : le programme entre dans son module au lancement. Forcément, sinon rien ne se lancerait jamais. La console s'initialise donc.

2. Il se retrouve à entrer dans le Main(). La console est ouverte.

3. Il continue et tombe sur notre ligne qui lui dit « Affiche "Hello World !" », il affiche donc « Hello World ! » dans la console.

4. Il arrive à la fin du Main() (End Sub). Rien ne se passe, « Hello World ! » est toujours affiché.

5. Il rencontre le End Module : la console se ferme.

Résultat des courses : la console s'est ouverte, a affiché « Hello World ! » et s'est fermée à nouveau… mais tout cela en une fraction de seconde, on n'a donc rien remarqué !

La pause

La parade : donner au programme une ligne à exécuter sur laquelle il va attendre quelque chose. On pourrait bien lui dire : « Attends pendant dix secondes… », mais il y a un moyen plus simple et préféré des programmeurs : attendre une entrée. Oui, la touche Entrée de votre clavier (Return pour les puristes). On va faire attendre le programme, qui ne bougera pas avant que la touche Entrée ne soit pressée.

Pour cela, voici la ligne de code qui effectue cette action :

Console.Read()

Cette ligne dit à l'origine « Lis le caractère que j'ai entré », mais nous allons l'utiliser pour dire au programme : « Attends l'appui sur la touche Entrée ».

Maintenant, où la placer ?

Module Module1
    Sub Main()
        Console.Write("Hello World !")
        Console.Read()
    End Sub
End Module

J'ai fourni l'intégralité du code pour ceux qui seraient déjà perdus. J'ai bien placé notre instruction après la ligne qui demande l'affichage de notre texte. En effet, si je l'avais mise avant, le programme aurait effectué une pause avant d'afficher la ligne : je l'ai dit plus haut, il exécute les instructions du haut vers le bas.

On clique sur notre fidèle flèche :

Hello World !

Victoire, notre « Hello World ! » reste affiché ! Si l'on presse la touche Entrée, la console se ferme : nous avons atteint nos objectifs !

Vous l'avez peut-être remarqué : au moment où vous avez écrit « Console. », une liste s'est affichée en dessous de votre curseur (voir figure suivante). Dans cette partie, je vais vous expliquer l'utilité de cette liste.

Nous avons donc notre console au début du schéma de la figure suivante. Sous VB, la console est considérée comme un objet. Cet objet possède des fonctions et d'autres objets. Je vais déjà expliquer cela.

Fonctions

Une fonction est une séquence de code déjà existante et conçue pour obtenir un effet bien défini. Concrètement, cela nous permet de n'écrire qu'une seule fois ce que va faire cette séquence, puis d'appeler la fonction correspondante autant de fois que nous le voulons (la séquence exécutera bien entendu ce qu'on a défini au préalable dans la fonction… que des mots compliqués ! :p ).

Par exemple, nos deux lignes qui nous permettaient d'afficher « Hello World ! » et d'effectuer une pause auraient pu être placées dans une fonction séparée. Dans ce cas, en une ligne (l'appel de la fonction), on aurait pu effectuer cette séquence ; imaginez alors le gain de temps et les avantages dans des séquences de plusieurs centaines de lignes.

Un autre exemple : notre fonction Write avait pour but d'écrire ce que l'on lui donnait comme arguments (je vous expliquerai cela par la suite). La fonction Write a donc été écrite par un développeur qui y a placé une série d'instructions (et pas des moindres !) permettant d'afficher du texte dans la console.

Objets

Pour faire simple, les objets permettent d'organiser notre code. Par exemple, notre fonction Write est, vous l'avez vu, liée à l'objet Console. C'est ainsi que le programme sait où effectuer le Write. Nous verrons plus en détail ce concept d'objets lorsque nous nous attaquerons au graphisme, mais vous venez de lire quelques notions de programmation orientée objet (aussi appelée POO).

À noter : les « liens » entre les objets se font par des points (« . »). Le nombre d'objets liés n'est limité que si l'objet que vous avez sélectionné ne vous en propose pas. Sinon, vous pouvez en raccorder dix si vous le voulez.

Pas de panique si vous n'avez pas compris ces concepts de fonctions, d'objets, etc. Nous allons justement nous pencher sur la structure d'un appel de fonction, car nous en aurons besoin très bientôt ; pour cela, nous allons étudier une fonction simple : le BEEP (pour faire « bip » avec le haut-parleur de l'ordinateur). Afin d'y accéder, nous allons écrire Console.Beep.

Ici, deux choix s'offrent à nous : le classique () ou alors (frequency as integer, duration as integer).

On va y aller doucement ! La première forme va émettre un « bip » classique lors de l'exécution. La seconde demande des arguments. Il s'agit de paramètres passés à la fonction pour lui donner des indications plus précises. Précédemment, lorsque nous avons écrit Write("Hello World !"), l'argument était "Hello World !" ; la fonction l'a récupéré et l'a affiché, elle a donc fait son travail.

Pour certaines fonctions, on a le choix de donner des arguments ou non, selon la façon dont elles ont été créées (c'est ce qu'on appelle la surcharge, pour les personnes ayant déjà des notions d'orienté objet).

La seconde forme prend donc deux arguments, que vous voyez d'ailleurs s'afficher dès que vous tapez quelque chose entre les parenthèses, comme sur l'une des images ci-avant. Le premier sert à définir la fréquence du « bip » : entrez donc un nombre pour lui donner une fréquence. Le second, quant à lui, détermine la durée du « bip ». Les arguments sont délimités par une virgule, et si vous avez bien compris, vous devriez obtenir une ligne de ce genre :

Console.Beep(500, 100)

Placez-la dans le programme comme nos autres lignes. Si vous la mettez avant ou après le Console.Read(), cela déterminera si le « bip » doit se produire avant ou après l'appui sur Entrée. Eh oui, le programme n'avancera pas tant que cette ligne ne sera pas exécutée.

Les nombres n'ont pas besoin de cette syntaxe particulière. Je m'explique : une variable ne peut pas avoir un nom composé uniquement de chiffres. Et donc, si vous écrivez des chiffres, le programme détectera immédiatement qu'il s'agit d'un nombre ; tandis que si vous écrivez des lettres, le programme ne saura pas s'il faut afficher le texte ou si c'est le nom d'une variable. :) Donc, pour les noms de variables, il ne faut pas de guillemets, mais pour un simple texte, si. ;)

Tenez, ça tombe bien, nous allons justement découvrir ce qu'est réellement une variable !

• Une fonction permet d'effectuer des traitements. Elle peut contenir des arguments (ou paramètres).

• Dans un projet de type console, la fonction Main() est celle appelée lors du démarrage du programme.

• Chaque ligne de programme est une instruction.

Les variables se déclinent sous différents types : il y a par exemple un type spécifique pour stocker des nombres, un autre pour stocker du texte, etc.
D'ailleurs, si vous tentez d'enregistrer du texte dans une variable créée pour contenir un nombre, l'ordinateur va vous afficher une petite erreur. ;)

Au tableau suivant, vous trouverez un récapitulatif des types que nous allons utiliser.

Il existe de nombreux autres types, mais ils ne vous seront pas utiles pour le moment.

J'ai précisé que le type Integer (abrégé Int) existait sous trois déclinaisons : Int16, Int32 et Int64. Le nombre après le mot Int désigne la place qu'il prendra en mémoire : plus il est grand (16, 32, 64), plus votre variable prendra de la place, mais plus le nombre que vous pourrez y stocker sera grand. Pour ne pas nous compliquer la vie, nous utiliserons le Integer (Int) tout simple.
Si vous voulez en savoir plus sur l'espace mémoire utilisé par les variables, vous pouvez vous renseigner sur les « bits ». ;)

Pour ce qui est du texte, on a de la place : il n'y a pas de limite apparente. Vous pouvez donc y stocker sans souci un discours entier. Si le booléen, ce petit dernier, ne vous inspire pas et ne vous semble pas utile, vous allez apprendre à le découvrir. :p

Telle est la question à laquelle nous allons répondre.

Que vous reste-t-il de vos cours de maths de 3e (sujet sensible :-° ) ?

Bon… si j'écris ceci : $\$\$x^3\; +\; 5x^2\; -\; 3x\; +\; 1\; =\; 0\$\$$, qu'est-ce qui se produit ?

1. Mon doigt se précipite pour éteindre l'écran.

2. Je ferme immédiatement le navigateur web.

3. Je prends une feuille de papier et résous cette équation. :waw:

Excusez-moi de vous avoir attaqués par derrière comme je l'ai fait, mais c'était dans le but de vous faire observer que l'attribution des variables est en de nombreux points similaire à notre vieil ami x en maths. :zorro:
Comme pour attribuer une valeur à une variable, on place un « = » entre deux éléments.

Le sens

Ce n'est pas difficile : en VB, et même dans tous les langages de programmation, ce qui se situe à gauche du « = » correspond à l'opération qui se trouve à droite. C'est ainsi, cela ne changera pas ! :p

Regardez la figure suivante.

1. On entre le chiffre 3 dans la variable appelée X, pas de problème ;

2. Ensuite, on souhaite mettre X dans 3 ! Aïe, cela ne va pas fonctionner ! Si vous écrivez quelque chose de ce genre, une erreur va se produire : comme si vous disiez « 3 = 2 », le compilateur va vous regarder avec des yeux grands comme ça et se demandera ce qu'il doit faire !

3. Ensuite, on met la variable Y dans la variable X ;

4. Et enfin, X dans Y.

Pas de problème pour le reste.
Je ne sais pas si vous l'avez remarqué, mais j'ai mis une variable dans une autre : c'est tout à fait possible, aucun problème à ce niveau-là. Par contre, l'affectation d'une valeur à une variable écrase l'ancienne valeur, comme schématisé à la figure suivante.

Revoilà donc mes boîtes. J'explique le schéma : vous ordonnez à votre programme « mets 3 dans X », ce qu'il va faire. Ensuite, vous lui dites « mets 5 dans X », mais il va oublier le 3 et écrire 5. :honte:

Attention, donc !

Mais en contrepartie, les variables offrent un stockage « nettoyable » à volonté. :p Je m'explique : vous pouvez les lire et y écrire autant de fois que vous le souhaitez. Lorsque vous lisez la valeur d'une variable, son contenu reste à l'intérieur (évident, me diront certains, mais sachez qu'il y a quelques dizaines d'années les valeurs stockées dans la mémoire RAM s'effaçaient lors de leur lecture ; à l'époque, c'était des « tores » qui stockaient les bits et, lors de leur lecture, l'énergie se dissipait et faisait disparaître l'information).

Si vous avez bien compris, je pourrais écrire ceci (j'en profite pour vous montrer comment on initialise une variable, mais j'y reviendrai juste après) :

Dim MaVariable As Integer
MaVariable = 5
MaVariable = 8
MaVariable = 15
MaVariable = 2
MaVariable = 88
MaVariable = 23

Que vaudra MaVariable à la fin de ces instructions ? 23 !

Cette petite partie de lecture vous a ennuyés ? On va remédier à ce malaise ! Nous allons mettre en œuvre tout ce que je vous ai expliqué.

Tout d'abord, en VB, il faut déclarer une variable avant de l'utiliser. Autrement, l'ordinateur ne saura pas de quel type est la variable et ne saura donc pas comment réagir.

Nouvelle variable

Voici l'instruction servant à déclarer une variable, par exemple de type Integer :

Dim MaVariable As Integer

Effectivement, les mots que vous allez utiliser et qui serviront d'instructions dans vos programmes, comme par exemple Write, If, Then, etc., sont en anglais ; mais si l'on décortique la ligne que je viens de vous montrer, on obtient ceci :

En somme, le mot « MaVariable » est le nom attribué à la variable. C'est vous qui le choisissez !

Bon, excusez-moi… j'avais dit qu'on allait pratiquer. Eh bien, on y va ! :pirate:
Retournez sur votre projet, qui doit encore être ouvert (du moins, je l'espère…). Si vous ne l'avez pas conservé, recréez-le (désolé :-° ).

Nous revoici donc avec nos lignes :

Module Module1
    Sub Main()
        Console.Write("Salut")
        Console.Read()
    End Sub
End Module

J'ai retiré notre essai sur la fonction BEEP, car je pense que vous ne souhaitez pas entendre votre ordinateur biper à chaque test. :)

MaVariable doit être égale à 5 !

Nous allons donc déclarer une variable et lui assigner une valeur. Je vous ai expliqué comment déclarer une variable.
Je vous ai aussi rapidement expliqué comment attribuer une valeur à une variable. Essayez donc de créer une variable de type Integer appelée « MaVariable » et d'y entrer la valeur « 5 ».

Dim MaVariable As Integer
MaVariable = 5

C'est la question fatidique ! Si vous vous rappelez le schéma sur l'ordre d'exécution des lignes dans un programme, vous devriez vous rappeler qu'une fois entrés dans un Sub ou une fonction, sauf indications contraires (que nous étudierons dans un prochain chapitre), nous allons de haut en bas.

De ce fait, si vous avez besoin de votre variable à la ligne 4 de votre programme, il vous faut l'initialiser avant.
Même chose pour lui assigner une valeur : si vous l'affectez seulement à la ligne 6, la ligne 4 ne pourra pas lire ce résultat.

Dernière chose : je parie que vous souhaitez faire quelque chose de cette variable, ne serait-ce que l'afficher ?
J'ai expliqué comment afficher un texte avec le Console.Write. Pensez-vous être capables de faire en sorte d'afficher la valeur de la variable dans la console ?

Module Module1
    Sub Main()
        Dim MaVariable As Integer
        MaVariable = 5
        Console.Write(MaVariable)
        Console.Read()
    End Sub
End Module

Voici le résultat :

5

Voilà, vous pouvez tester : ce code affiche « 5 » dans la console.

C'était le piège (sauf si vous avez bien lu précédemment) ! ^^

Si vous conservez les doubles quotes, la fonction Write affichera en dur le mot « MaVariable », et non sa valeur. Il faut donc enlever les doubles quotes pour que la fonction utilise le contenu de la variable MaVariable.

Vous êtes désormais capables de déclarer des variables et de leur affecter des valeurs. Vous en apprendrez plus durant l'exploration d'autres sujets. Rien de tel que de pratiquer pour s'améliorer. ^^

Dernière chose : il faut toujours essayer d'assigner une valeur à une variable dès le début ! Sinon, la variable n'est égale à rien, et des erreurs peuvent survenir dans certains cas. Donc, systématiquement : une déclaration, une assignation. :magicien:

• Une variable peut contenir une valeur.

• Les variables et donc les valeurs qu'elles contiennent peuvent être de différents types.

• Des guillements : « " " » délimitent une variable de type chaîne de caractères.

• Le type String contient les chaînes de caractères, Integer les entiers, Double les nombres à virgule, et Date les dates et heures.

Nous allons à présent apprendre à modifier des variables, et effectuer des opérations avec elles.

Voici un exemple : vous souhaitez créer un programme qui calcule la somme de deux nombres ; pour ce faire, il vous faudra utiliser des opérations. Je vais vous expliquer la marche à suivre.

Reprenons notre programme, déclarons-y une variable MaVariable en Integer et assignons-lui la valeur 5 (ce qui, normalement, est déjà fait).
Déclarons maintenant une seconde variable intitulée MaVariable2, de nouveau en Integer, et assignons-lui cette fois la valeur 0.

Si vous avez correctement suivi la démarche, vous devriez obtenir le résultat suivant :

Module Module1
    Sub Main()
        Dim MaVariable As Integer
        Dim MaVariable2 As Integer
        MaVariable = 5
        MaVariable2 = 0
        Console.Write(MaVariable)
        Console.Read()
    End Sub
End Module

Dans le cas où vous avez plusieurs variables du même type, vous pouvez rassembler leur déclaration comme suit :

Dim MaVariable, MaVariable2 As Integer

Vous pouvez également initialiser vos variables dès leur déclaration, comme ci-dessous, ce qui est pratique pour les déclarations rapides.

Dim MaVariable As Integer = 5

À l'attaque

Passons maintenant au concret !

On va additionner un nombre à notre variable MaVariable. Pour ce faire, rien de plus simple ! Démonstration.

MaVariable + 5

Voilà ! Simple, n'est-ce pas ? En résumé, vous avez additionné 5 à la variable MaVariable. Le programme a effectué cette opération. Seulement, le résultat n'est allé nulle part : nous n'avons pas mis le signe égal (« = ») !

Mais non, c'est pour vous montrer ce qu'il faut faire et ce qu'il ne faut pas faire. :D Imaginez un parent mettre ses doigts dans la prise et montrer à bébé l'effet que cela produit ; il comprendra tout de suite mieux ! :-° (Mauvais exemple.)

Pour y remédier, il faut ajouter le signe égal, comme lorsque nous initialisons nos variables.

MaVariable2 = MaVariable + 5

Nous allons donc nous retrouver avec… 10, dans la variable MaVariable2.

À noter que nous avons initialisé MaVariable2 avec 0. Si nous l'avions fait, par exemple, avec 7, le résultat aurait été identique puisque, souvenez-vous, l'entrée d'une valeur dans une variable écrase l'ancienne.

Vous savez à présent comment additionner un nombre à une variable. Nous allons donc découvrir les autres opérations possibles.

J'explique ce petit tableau par un exemple : nous avons appris que, pour additionner 3 et 2, la syntaxe est 3+2. C'est évident, me direz-vous… mais si je vous avais demandé de diviser 10 par 5, comment auriez-vous procédé ?

Eh bien, désormais, vous savez à quel caractère correspond chaque opération, la division de 10 par 5 aurait donc été : 10/5.

Très bonne question. Le modulo est une opération spécifique en programmation, qui permet de récupérer le reste d'une division.

Exemples :

• 10 mod 5 correspond à 10/5 ; le résultat est 2, le reste est 0, donc 10 mod 5 = 0.

• 14 mod 3 correspond à 14/3 ; le résultat est 4, le reste 2, donc 14 mod 3 = 2.

Nous allons immédiatement mettre en pratique ces informations. Toutes les instructions que nous allons ajouter se feront dans le Main().

Essayez d'attribuer des valeurs à vos variables et d'effectuer des opérations entre elles pour finalement stocker le résultat dans une troisième variable et afficher le tout.

Petite parenthèse : je vais en profiter pour vous expliquer comment écrire sur plusieurs lignes.
Si vous écrivez une fonction Write, puis une autre en dessous de façon à donner ceci :

Console.Write("test")
Console.Write("test")

… vous allez vous retrouver avec le résultat suivant :

testtest

Afin d'écrire sur deux lignes, on va utiliser le procédé le plus simple pour le moment, qui est la fonction WriteLine(). Elle prend aussi comme argument la variable ou le texte à afficher, mais insère un retour à la ligne au bout. Un code du genre…

Console.WriteLine("test")
Console.WriteLine("test")

… produira le résultat suivant :

test
test

Avec ces nouvelles informations, essayez donc de multiplier 8 par 9 (chaque nombre mis au préalable dans une variable), le tout étant entré dans une troisième variable. En outre, un petit supplément serait d'afficher l'opération que vous faites.

Je vous laisse chercher ! :)

Module Module1
    Sub Main()
        Dim MaVariable As Integer
        Dim MaVariable2 As Integer
        Dim MaVariable3 As Integer

        MaVariable = 8
        MaVariable2 = 9
        MaVariable3 = MaVariable * MaVariable2

        Console.Write("9 x 8 = ")
        Console.Write(MaVariable3)

        Console.Read()
    End Sub
End Module

Ce code, que j'ai tenté d'écrire de la façon la plus claire possible, nous affiche donc ceci :

9 x 8 = 72

Essayez de modifier les valeurs des variables, l'opération, etc.

Nous avons donc créé un code affichant 9 x 8 = 72. Ce code, comme vous l'avez certainement constaté, est très long pour le peu qu'il fait ; pourtant, je vous ai donné quelques astuces.

Mon code peut donc être simplifié de plusieurs manières.

Tout d'abord, l'initialisation lors de la déclaration :

Dim MaVariable As Integer = 8
Dim MaVariable2 As Integer = 9
Dim MaVariable3 As Integer = 0

Puis, un seul Write :

Console.Write("9 x 8 = " & MaVariable3)

Bonne question. C'est ce qu'on appelle la concaténation, elle permet d'assembler deux éléments en un ; ici, par exemple, j'ai assemblé la chaîne de caractères "9 x 8 = " et le contenu de la variable, ce qui aura pour effet de m'afficher directement 9 x 8 = 72 (je parle d'assembler deux éléments en un, car en faisant cela on assemble le tout dans le même argument).

Dernière amélioration possible : la suppression d'une variable intermédiaire ; on se retrouve à faire l'opération directement dans le Write.

Console.Write("9 x 8 = " & MaVariable * MaVariable2)

Oui, effectivement. Mais dans ce cas, vos variables ne servent plus à rien et cette instruction ne sera valable que pour faire 9 * 8…

Grâce à ces modifications, notre code devient plus clair :

Module Module1
    Sub Main()
        Dim MaVariable As Integer = 8
        Dim MaVariable2 As Integer = 9

        Console.Write("9 x 8 = " & MaVariable * MaVariable2)

        Console.Read()
    End Sub
End Module

Pour cela, la parade arrive (eh oui, il y en a toujours une ; du moins, presque) ! :magicien:

Les commentaires vont nous servir à éclaircir le code. Ce sont des phrases ou des indications que le programmeur laisse pour lui-même ou pour ceux qui travaillent avec lui sur le même code.

Une ligne est considérée comme commentée si le caractère « ' » (autrement dit, une simple quote) la précède ; une ligne peut aussi n'être commentée qu'à un certain niveau.

Exemples :

'Commentaire
MaVariable = 9 * 6 ' Multiplie 9 et 6 et entre le résultat dans MaVariable

Par exemple, voici notre programme dûment commenté :

Module Module1
    Sub Main()
        'Initialisation des variables
        Dim MaVariable As Integer = 8
        Dim MaVariable2 As Integer = 9

        'Affiche "9 x 8 = " puis le résultat (multiplication de MaVariable par MaVariable2)
        Console.Write("9 x 8 = " & MaVariable * MaVariable2)

        'Crée une pause factice de la console
        Console.Read()
    End Sub
End Module

Autre chose : si vous voulez commenter plusieurs lignes rapidement, ce qui est pratique lorsque vous testez le programme avec d'autres fonctions mais que vous souhaitez garder les anciennes si cela ne fonctionne pas, Visual Basic Express vous permet de le faire avec son interface. Sélectionnez pour cela les lignes souhaitées, puis cliquez sur le bouton que j'ai décrit dans la barre d'outils et qui porte le nom « Commenter les lignes sélectionnées ».

Vous allez sûrement trouver cela long, fastidieux et inutile au début, mais plus tard, cela deviendra une habitude, et vous les insérerez sans que je vous le dise.

Il existe d'autres astuces pour expliquer et trier son code, que j'aborderai lorsque nous créerons nos propres fonctions.

Je vais immédiatement aborder ce passage, mais assez sommairement puisqu'il ne sera valable qu'en mode console.

Pour lire en mode console, par exemple si vous souhaitez que l'utilisateur saisisse deux nombres que vous additionnerez, il vous faut utiliser la fonction ReadLine(). Nous avions utilisé Read, mais cette fonction lit uniquement un caractère, elle est donc inutile pour les nombres supérieurs à 9.

Notre nouvelle fonction s'utilise de la manière suivante :

MaVariable = Console.ReadLine()

Vous avez donc certainement déjà dû écrire ce code, qui multiplie les deux nombres entrés :

Module Module1
    Sub Main()
        'Initialisation des variables
        Dim MaVariable As Integer = 0
        Dim MaVariable2 As Integer = 0

        Console.WriteLine("- Multiplication de deux nombres -")

        'Demande du premier nombre stocké dans MaVariable
        Console.WriteLine("Veuillez entrer le premier nombre")
        MaVariable = Console.ReadLine()
        'Demande du second nombre stocké dans MaVariable2
        Console.WriteLine("Veuillez entrer le second nombre")
        MaVariable2 = Console.ReadLine()

        'Affiche "X x Y = " puis le résultat (multiplication de MaVariable par MaVariable2)
        Console.WriteLine(MaVariable & " x " & MaVariable2 & " = " & MaVariable * MaVariable2)

        'Crée une pause factice de la console
        Console.ReadLine()
    End Sub
End Module

Ce programme demande donc les deux nombres, l'un puis l'autre, et les multiplie.

Ce qui nous amène à notre prochain chapitre : les boucles conditionnelles.

• Une variable peut stocker différentes valeurs.

• Les variables ont un type leur permettant de stocker des informations spécifiques : numérique, chaîne de caractères, etc.

• Le modulo permet de retourner le reste d'une division entière.

• Les commentaires sont des lignes de code non exécutées, uniquement destinées au programmeur, elles sont précédées par une apostrophe : « ' ».

• L'instruction Console.Writeline permet d'afficher un message à la console.

Retenez bien que les « mots » que le programme comprend et utilise sont anglais et ont donc une traduction qui peut vous aider à vous rappeler à quoi ils servent.

Aperçu des différentes boucles

« If », mot anglais traduisible par « si »

Attaquons avec la boucle la plus simple, mais non sans intérêt : If.

Une ligne commençant par If est toujours terminée par Then, ce qui signifie « Si, alors ». C'est entre ces deux mots que vous placez la condition souhaitée.

Donc, si j'écris le code If MaVariable = 10 Then, ce qui se trouve en dessous ne sera exécuté que si la valeur de MaVariable est égale à 10. Regardez la figure suivante.

Eh bien oui, du moins jusqu'à ce qu'il rencontre End If, traduisible par « Fin si ». Comme pour un Sub ou un Module, une boucle est associée à sa fin correspondante.

If MaVariable = 10 Then
      MaVariable = 5
End If

Si vous avez bien compris, vous devriez être capables de m'expliquer l'utilité du code ci-dessus.

Si MaVariable est égale à 10, il met MaVariable à 5.
Exactement !

Bonne observation. Eh bien, non, cela ne change rien : c'est en arrivant à la ligne du If que tout se joue. Ensuite, si la variable change, le programme ne s'en préoccupe plus.

« Else », mot anglais traduisible par « sinon »

« Sinon », il faut y penser parfois pour gérer toutes les éventualités. Le Else doit être placé dans une boucle If, donc entre le Then et le End If. Regardez la figure suivante.

La syntaxe est la suivante :

If MaVariable = 10 Then
    'Code exécuté si MaVariable = 10
Else
    'Code exécuté si MaVariable est différente de 10
End If

ElseIf

La figure suivante schématise le ElseIf.

Si vous voulez un cas particulier et non le reste des autres cas de votre condition, il existe le ElseIf.

Voici un exemple :

If MaVariable = 10 Then
    'Code exécuté si MaVariable = 10
ElseIf MaVariable = 5 Then
    'Code exécuté si MaVariable = 5
Else
    'Code exécuté si MaVariable est différente de 10 et de 5
End If

If MaVariable = 10 Then
    If MaVariable2 = 1 Then
       'Code exécuté si MaVariable = 10 et MaVariable2 = 1
    Else
       'Code exécuté si MaVariable = 10 et MaVariable2 <> 1
    End If
ElseIf MaVariable = 5 Then
    If MaVariable2 = 2 Then
       'Code exécuté si MaVariable = 5 et MaVariable2 = 2
    End If
Else
       'Code exécuté si MaVariable est différente de 10 et de 5
End If

Nous avons vu If, ElseIf et Else.

Mais pour ce qui est, par exemple, du cas d'un menu dans lequel vous avez 10 choix différents, comment faire ?

Une première façon de procéder serait la suivante :

If Choix = 1 Then
     Console.WriteLine("Vous avez choisi le menu n° 1")
ElseIf Choix = 2 Then
     Console.WriteLine("Vous avez choisi le menu n° 2")
ElseIf Choix = 3 Then
     Console.WriteLine("Vous avez choisi le menu n° 3")
ElseIf Choix = 4 Then
     Console.WriteLine("Vous avez choisi le menu n° 4")
ElseIf Choix = 5 Then
     Console.WriteLine("Vous avez choisi le menu n° 5")
ElseIf Choix = 6 Then
     Console.WriteLine("Vous avez choisi le menu n° 6")
ElseIf Choix = 7 Then
     Console.WriteLine("Vous avez choisi le menu n° 7")
ElseIf Choix = 8 Then
     Console.WriteLine("Vous avez choisi le menu n° 8")
ElseIf Choix = 9 Then
     Console.WriteLine("Vous avez choisi le menu n° 9")
ElseIf Choix = 10 Then
     Console.WriteLine("Vous avez choisi le menu n° 10")
Else
     Console.WriteLine("Le menu n'existe pas")
End If

Il s'agit de la méthode que je viens de vous expliquer (qui est tout à fait correcte, ne vous inquiétez pas).

Il faut néanmoins que vous sachiez que les programmeurs sont très fainéants, et ils ont trouvé sans cesse des moyens de se simplifier la vie. C'est donc dans le cas que nous venons d'évoquer que les Select deviennent indispensables, et grâce auxquels on simplifie le tout. La syntaxe se construit de la manière suivante :

Select Case MaVariable
      Case 1
          'Si MaVariable = 1
      Case 2
          'Si MaVariable = 2
      Case Else
          'Si MaVariable <> 1 et <> 2
   End Select

Dans le même cas de figure, revoici notre menu :

Select Case Choix
            Case 1
                Console.WriteLine("Vous avez choisi le menu n° 1")
            Case 2
                Console.WriteLine("Vous avez choisi le menu n° 2")
            Case 3
                Console.WriteLine("Vous avez choisi le menu n° 3")
            Case 4
                Console.WriteLine("Vous avez choisi le menu n° 4")
            Case 5
                Console.WriteLine("Vous avez choisi le menu n° 5")
            Case 6
                Console.WriteLine("Vous avez choisi le menu n° 6")
            Case 7
                Console.WriteLine("Vous avez choisi le menu n° 7")
            Case 8
                Console.WriteLine("Vous avez choisi le menu n° 8")
            Case 9
                Console.WriteLine("Vous avez choisi le menu n° 9")
            Case 10
                Console.WriteLine("Vous avez choisi le menu n° 10")
            Case Else
                Console.WriteLine("Le menu n'existe pas")
        End Select

Pour que vous compreniez bien, voici un petit schéma en figure suivante.

Ce code correspond exactement à celui qui se trouve plus haut. Le Case Else, ici aussi, prend en compte toutes les autres possibilités.

Petites astuces avec Select

Non, une petite astuce du Select est de rassembler toutes les valeurs en un seul Case. Par exemple, le code suivant…

Select Case Choix
       Case 3,4,5
            'Choix 3, 4 et 5
End Select

… est identique à celui-ci :

Select Case Choix
       Case 3
            'Choix 3, 4 et 5
       Case 4
            'Choix 3, 4 et 5
       Case 5
            'Choix 3, 4 et 5
End Select

Astuce également valable pour de grands intervalles : le code suivant…

Select Case Choix
       Case 5 to 10
            'Choix 5 à 10
End Select

… correspond à ceci :

Select Case Choix
       Case 5
            'Choix 5 à 10
       Case 6
            'Choix 5 à 10
       Case 7
            'Choix 5 à 10
       Case 8
            'Choix 5 à 10
       Case 9
            'Choix 5 à 10
       Case 10
            'Choix 5 à 10
End Select

Voilà, j'espère que ces différentes formes vous seront utiles. :p

À présent, nous allons réellement aborder le terme de « boucle ».

Non, ce ne sont pas à proprement parler des boucles ; en programmation, on appelle boucle un espace dans lequel le programme reste pendant un temps choisi, c'est-à-dire qu'il tourne en rond.

On va tout de suite étudier le cas de While.

« While », mot anglais traduisible par « tant que »

Vu la traduction du mot « while », vous devriez vous attendre à ce que va faire notre boucle.
Elle va effectivement « tourner » tant que la condition est vraie.

Retenez bien ce « vrai ». Vous souvenez-vous du concept des booléens que nous avons étudié dans le chapitre sur les variables ? Eh bien voilà, dans ce cas-ci, le While va vérifier que le booléen est vrai.

La syntaxe est similaire à celle du If de tout à l'heure. Voyons cela !

While MaVariable = 10
    'Exécuté tant que MaVariable = 10
End While

Voici donc un schéma à la figure suivante pour vous aider à comprendre.

En clair, le programme arrive au niveau de l'instruction While, vérifie que la condition est vraie et, si c'est le cas, entre dans le While, puis exécute les lignes qui se trouvent à l'intérieur ; il arrive ensuite au End While et retourne au While. Cela tant que la condition est vraie.

Eh oui, lorsque vous écrivez MaVariable = 10, le programme va faire un petit calcul dans son coin afin de vérifier que la valeur de MaVariable est bien égale à 10 ; si c'est le cas, il transforme cela en un booléen de type Vrai.
Il s'agit du même principe que pour les autres boucles conditionnelles (If, Else, etc.).

Oh, mais quelle coïncidence, une boucle spéciale existe pour un tel cas ! (C'est beau le hasard, parfois, n'est-ce pas ? :p )

Do While

À l'instar du While, le Do While (traduisible par « faire tant que ») passe au moins une fois dans la boucle. Regardez la figure suivante.

Do
   'Instruction exécutée au moins une fois
Loop While MaVariable = 10

Un code de ce type…

Do

Loop Until MaVariable = 10

… revient à écrire ceci :

Do 

Loop While MaVariable <> 10

J'espère ne pas avoir été trop brusque… :D

Vous êtes désormais en mesure d'utiliser les boucles While, If et Select. Une dernière pour la route ?

« For », mot anglais traduisible par « pour »

For est indissociable de son To, comme un If a son Then (sauf cas particuliers, tellement particuliers que vous ne les utiliserez pas dans l'immédiat :) ).

Et tel If, For To a un Next (qui correspond à peu près au End If).

Je m'explique. Si je souhaite effectuer une instruction dix fois de suite, je vais écrire ceci :

Dim x As Integer = 0

While x <> 10
   'Instruction à exécuter 10 fois
   x = x + 1  'Augmente x de 1
End While

Je profite de cet exemple pour vous signaler que l'incrémentation d'une variable de 1 peut s'écrire x += 1. Pas besoin de « = », cette instruction seule remplace x = x + 1.
Tant que j'y suis, x -= 1 remplace x = x - 1.

La boucle sera parcourue à dix reprises. Eh bien, For remplace ce code par celui-ci :

Dim x As Integer
For x = 1 to 10
   'Instruction à exécuter 10 fois
Next

Les deux codes effectueront la même chose. Le Next correspond à « ajoute 1 à ma variable ».

• On peut déclarer les variables dans la ligne du For, de cette manière :

  For x As Integer = 1 to 10
       'Instruction à exécuter 10 fois
  Next

  Cela reviendra de nouveau au même.

• Si vous voulez ajouter 2 au Next à la place de 1 (par défaut) :

  For x As Integer = 1 to 10 step 2
       'Instruction à exécuter 5 fois
  Next

Opérateurs

Vous savez maintenant vous servir des grands types de boucles. Rassurez-vous, tout au long du tutoriel, je vous apprendrai d'autres choses en temps voulu.

Je voulais vous donner de petits éclaircissements à propos des boucles. Pour valider la condition d'une boucle, il existe des opérateurs :

Grâce à ces opérateurs, vous allez déjà pouvoir bien exploiter les boucles.
Comment les utiliser ? C'est très simple.

Si vous voulez exécuter un While tant que « x » est plus petit que 10 :

While x < 10

Voilà !

Explication des boucles

Second élément : une boucle est considérée comme vraie si le booléen correspondant est vrai (souvenez-vous du booléen, un type qui ne peut être que vrai ou faux).

En gros, si j'écris le code suivant :

Dim x As Integer = 0
If x = 10 Then
End If

… c'est comme si j'écrivais ceci :

Dim x As Integer = 0
Dim b As Boolean = false
b = (x = 10)
If b Then
End If

Eh oui, quelle découverte ! Si je place un boolean dans la condition, il est inutile d'ajouter If b = true Then.

J'espère vous avoir éclairés… et non enfoncés ! :euh:

And, or, not

Nous pouvons également utiliser des mots dans les boucles !

Non, pas question !

Commençons donc par le mot-clé not, dont le rôle est de préciser à la boucle d'attendre l'inverse.
Exemple : un While not = 10 correspond à un While <> 10.

Et puis ?

Un second mot permet d'ordonner à une boucle d'attendre plusieurs conditions : ce cher ami s'appelle And. Il faut que toutes les conditions reliées par And soient vérifiées.

While MaVariable >= 0 And MaVariable <= 10

Ce code tournera tant que la variable est comprise entre 0 et 10.

Faites attention à rester logiques dans vos conditions :

While MaVariable = 0 And MaVariable = 10

Le code précédent est totalement impossible, votre condition ne pourra donc jamais être vraie…

Ou bien ?

Le dernier mot que je vais vous apprendre pour le moment est Or.
Ce mot permet de signifier « soit une condition, soit l'autre ».

Voici un exemple dans lequel Or est impliqué :

While MaVariable >= 10 Or MaVariable = 0

Cette boucle sera exécutée tant que la variable est supérieure ou égale à 10, ou égale à 0.

Ensemble, mes amis !

Eh oui, ces mots peuvent s'additionner, mais attention au sens.

While MaVariable > 0 And not MaVariable >= 10 Or MaVariable = 15

Ce code se comprend mieux avec des parenthèses : (MaVariable > 0 et non MaVariable >= 10) ou MaVariable = 15.
Donc, cela se traduit par « si MaVariable est comprise entre 1 et 10 ou si elle est égale à 15 ».

J'espère avoir été suffisamment compréhensible. :p

• If signifie « si », on s'en sert pour exécuter une série d'instructions uniquement si une condition est vérifiée.

• Else signifie « sinon », on l'utilise avec If pour couvrir les cas où la condition ne sera pas vérifiée.

• While et Until permettent d'effectuer sans arrêt une série d'instructions tant que la condition sera, respectivement, vraie et fausse.

• For permet de boucler un certain nombre de fois.

Cahier des charges

Donc, c'est parti : je veux (j'ai toujours rêvé de dire ça ! :D ) un programme qui effectue l'addition de deux nombres demandés au préalable à l'utilisateur. Attention à prévoir le cas où l'utilisateur ne saisirait pas un nombre.

Vous connaissez déjà la marche à suivre pour demander des nombres, les additionner, afficher le résultat (je l'ai déjà indiqué, au cas où vous ne le sauriez pas), mais un problème subsiste : comment vérifier qu'il s'agit bel et bien d'un nombre ?

IsNumeric()

Il vous faut faire appel à une fonction évoquée précédemment, qui prend en argument une variable (de toute façon, ce sera indiqué lorsque vous le taperez) et renvoie un booléen (vrai si cette variable est un nombre, faux dans le cas contraire).

Il va donc falloir stocker la valeur que la personne a entrée dans une variable de type string.

Eh bien, tout simplement parce que si la personne entre une lettre il y aura une erreur : le programme ne peut pas entrer de lettre dans un integer, à l'inverse d'un string.

Ensuite, vous allez utiliser la fonction IsNumeric() sur cette variable.

Je vous laisse, alors ? :p Bonne chance !

Module Module1

    Sub Main()
        'Déclaration des variables
        Dim ValeurEntree As String = ""
        Dim Valeur1 As Double = 0
        Dim Valeur2 As Double = 0

        Console.WriteLine("- Addition de deux nombres -")
        'Récupération du premier nombre
        Do
            Console.WriteLine("Entrez la première valeur")
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)
        'Écriture de la valeur dans un double
        Valeur1 = ValeurEntree

        'Récupération du second nombre
        Do
            Console.WriteLine("Entrez la seconde valeur")
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)
        'Écriture de la valeur dans un double
        Valeur2 = ValeurEntree

        'Addition
        Console.WriteLine(Valeur1 & " + " & Valeur2 & " = " & Valeur1 + Valeur2)

        'Pause factice
        Console.Read()
    End Sub

End Module

Le résultat

- Addition de deux nombres -
Entrez la première valeur
10
Entrez la seconde valeur
k
Entrez la seconde valeur
20
10 + 20 = 30

Comme ceci ?

Do
    Console.WriteLine("Entrez la première valeur")
    Valeur1 = Console.ReadLine()
    'Tourne tant que ce n'est pas un nombre
Loop While not IsNumeric(Valeur1)

C'est tout à fait juste.

Et voilà l'occasion d'utiliser le not vu précédemment. Et de toute façon, si vous ne vous souveniez plus de ce mot clé, vous aviez Until à votre disposition !

À cause des types : avec votre suggestion, il aurait fallu mettre Valeur1 et Valeur2 en string, on est d'accord ? Sauf qu'une addition sur un string, autrement dit une chaîne de caractères, même si elle contient un nombre, aura comme effet de « coller » les deux textes. Si vous avez essayé, vous avez dû récupérer un « 1020 » comme résultat, non ? :p

Parce qu'avec un If, si ce n'est pas un nombre, le programme ne le demandera pas plus d'une fois. Un simple While aurait en revanche suffi ; il aurait juste fallu initialiser les deux variables sans nombres à l'intérieur. Mais je trouve plus propre d'utiliser les Do.

Nous venons donc de réaliser un programme qui additionne deux nombres.

Cahier des charges

Au tour maintenant de celui qui effectue toutes les opérations.

Oui, exactement. Vous êtes tout à fait capables de réaliser ce petit module. La différence entre les deux applications est simplement un « menu », qui sert à choisir quelle opération effectuer. Je vous conseille donc la boucle Select Case pour réagir en fonction du menu. Autre chose : pensez à implémenter une fonction qui vérifie que le choix du menu est valide.

Vous avez toutes les clés en main ; les boucles et opérations sont expliquées précédemment. Bonne chance ! :)

Module Module1

    Sub Main()
        'Déclaration des variables
        Dim Choix As String = ""
        Dim ValeurEntree As String = ""
        Dim Valeur1 As Double = 0
        Dim Valeur2 As Double = 0

        'Affichage du menu
        Console.WriteLine("-   Minicalculatrice   -")
        Console.WriteLine("-  Opérations possibles -")
        Console.WriteLine("-     Addition : 'a'    -")
        Console.WriteLine("-   Soustraction : 's'  -")
        Console.WriteLine("-  Multiplication : 'm' -")
        Console.WriteLine("-     Division : 'd'    -")

        Do
            Console.WriteLine("- Faites votre choix :  -")
            'Demande de l'opération
            Choix = Console.ReadLine()
            'Répète l'opération tant que le choix n'est pas valide
        Loop Until Choix = "a" Or Choix = "s" Or Choix = "m" Or Choix = "d"

        'Récupération du premier nombre
        Do
            Console.WriteLine("Entrez la première valeur")
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)
        'Écriture de la valeur dans un double
        Valeur1 = ValeurEntree

        'Récupération du second nombre
        Do
            Console.WriteLine("Entrez la seconde valeur")
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)
        'Écriture de la valeur dans un double
        Valeur2 = ValeurEntree

        Select Case Choix
            Case "a"
                'Addition
                Console.WriteLine(Valeur1 & " + " & Valeur2 & " = " & Valeur1 + Valeur2)
            Case "s"
                'Soustraction
                Console.WriteLine(Valeur1 & " - " & Valeur2 & " = " & Valeur1 - Valeur2)
            Case "m"
                'Multiplication
                Console.WriteLine(Valeur1 & " x " & Valeur2 & " = " & Valeur1 * Valeur2)
            Case "d"
                'Division
                Console.WriteLine(Valeur1 & " / " & Valeur2 & " = ")
                Console.WriteLine("Valeur exacte : " & Valeur1 / Valeur2)
                Console.WriteLine("Résultat entier : " & Valeur1 \ Valeur2)
                Console.WriteLine("Reste : " & Valeur1 Mod Valeur2)
        End Select

        'Pause factice
        Console.Read()
    End Sub

End Module

J'ai choisi de faire appel à une méthode plutôt fastidieuse. En effet, dans la ligne Loop Until Choix = "a" Or Choix = "s" Or Choix = "m" Or Choix = "d", j'ai réécrit toutes les valeurs possibles du menu, mais imaginez-vous dans le cas d'un menu de vingt choix…

Dans cette situation, l'astuce serait d'utiliser un menu à numéros et, carrément, d'exclure une plage avec un nombre supérieur à 10, par exemple.

Voici ce que j'obtiens lorsque je lance le programme :

-   Minicalculatrice   -
-  Opérations possibles -
-     Addition : 'a'    -
-   Soustraction : 's'  -
-  Multiplication : 'm' -
-     Division : 'd'    -
- Faites votre choix :  -
y
- Faites votre choix :  -
d
Entrez la première valeur
255
Entrez la seconde valeur
12m
Entrez la seconde valeur
36
255 / 36 =
Valeur exacte : 7,08333333333333
Résultat entier : 7
Reste : 3

Vous avez sûrement dû déclarer votre « variable intermédiaire » en integer. Si c'est le cas, je vous explique le problème : le integer ne sert pas à stocker des nombres à virgule. Essayez de placer cette variable en double pour vérifier. Idem pour les autres variables : si l'utilisateur veut additionner deux nombres à virgule, cela n'ira pas !

Alors, pas sorcier pour le reste ? Du moins, je l'espère. Allez, on passe à la suite ! :)

Remplacer des caractères

On va commencer par la fonction la plus simple : le Replace() qui, comme son nom l'indique, permet de remplacer des caractères ou groupes de caractères au sein d'une chaîne.

La syntaxe est la suivante :

Dim MonString As String = "Phrase de test"
MonString = MonString.Replace("test", "test2")

Le premier argument de cette fonction est le caractère (ou mot) à trouver, et le second, le caractère (ou mot) par lequel le remplacer.
Dans cette phrase, le code remplacera le mot « test » par « test2 ».

Si vous avez bien assimilé le principe des fonctions, des variables peuvent être utilisées à la place des chaînes de caractères en « dur ».

Mettre en majuscules

La fonction ToUpper() se rattachant à la chaîne de caractères en question (considérée comme un objet) permet cette conversion.
Elle s'utilise comme suit :

Dim MonString As String = "Phrase de test"
MonString = MonString.ToUpper()

Cette phrase sera donc mise en MAJUSCULES.

Mettre en minuscules

Cette fonction s'appelle ToLower() ; elle effectue la même chose que la précédente, sauf qu'elle permet le formatage du texte en minuscules.

Dim MonString As String = "Phrase de test"
MonString = MonString.ToLower()

Ces petites fonctions pourront sûrement nous être utiles pour l'un de nos TP. :p

Nous passons donc aux dates et à l'heure. Il s'agit d'un sujet assez sensible puisque, lorsque nous aborderons les bases de données, la syntaxe d'une date et son heure sera différente de la syntaxe lisible par tout bon francophone (âgé de plus de deux ans).

Tout d'abord, pour travailler, nous allons avoir besoin d'une date. Ça vous dirait, la date et l'heure d'aujourd'hui ? Nous allons utiliser l'instruction Date.Now, qui nous donne… la date et l'heure d'aujourd'hui, sous la forme suivante :

16/06/2009 21:06:33

La première partie est la date ; la seconde, l'heure.

Nous allons ainsi pouvoir travailler. Entrons cette valeur dans une variable de type… date, et amusons-nous !

Récupérer uniquement la date

La première fonction que je vais vous présenter dans ce chapitre est celle qui convertit une chaîne date, comme celle que je viens de vous présenter, mais uniquement dans sa partie « date ».

Je m'explique : au lieu de « 16/06/2009 21:06:33 » (oui, je sais, il est exactement la même heure qu'il y a deux minutes…), nous obtiendrons « 16/06/2009 ».

ToShortDateString()

Cette fonction s'utilise sur une variable de type date. J'ignore si vous vous souvenez de mon petit interlude sur les objets et fonctions, au cours duquel je vous ai expliqué que le point (« . ») servait à affiner la recherche. Nous allons donc utiliser ce point pour lier le type (qui est également un objet dans notre cas) et cette fonction.

Cette syntaxe que vous avez, je pense, déjà écrite vous-mêmes (MaVariableDate.ToShortDateString()), convertit votre date en date sans heure, mais flotte dans les airs… Il faut bien la récupérer, non ? Pour ce faire, affichons-la !

Pour ma part, je me retrouve avec ceci :

Module Module1

    Sub Main()
        'Initialisation des variables
        Dim MaVariableDate As Date = Date.Now
        'Écriture de la forme courte de la date
        Console.WriteLine(MaVariableDate.ToShortDateString)
        'Pause
        Console.Read()
    End Sub

End Module

Voici le résultat qui est censé s'afficher dans la console :

16/06/2009

Ah, l'erreur ! La variable de type date est formatée obligatoirement comme je l'ai montré au début, ce qui veut dire que si vous y entrez par exemple uniquement une heure, elle affichera automatiquement une date.

Bah, pourquoi ne pas mettre cela dans un string ? (Vous n'aimez pas les string ? :p )

La date avec les libellés

Seconde fonction : récupérer la date avec le jour et le mois écrits en toutes lettres. Rappelez-vous l'école primaire, où l'on écrivait chaque matin « mardi 16 juin 2009 » (non, je n'ai jamais écrit cette date à l'école primaire !).

Donc, pour obtenir cela, notre fonction s'intitule ToLongDateString() (je n'ai pas trop cherché :D ).

Le résultat obtenu est Mardi 16 Juin 2009.

L'heure uniquement

Voici la fonction qui sert à récupérer uniquement l'heure :

ToShortTimeString()

Ce qui nous renvoie ceci :

21:06

L'heure avec les secondes

Même chose qu'au-dessus, sauf que la fonction se nomme :

ToLongTimeString()

Cela nous renvoie :

21:06:33

Sur ce, j'espère que vous avez bien compris comment manipuler les dates, les heures et les chaînes de caractères ; nous allons faire un mini-TP !

L'horloge

Eh oui, je ne suis pas allé chercher bien loin : ce TP aura pour but de mettre en œuvre une horloge (heures:minutes:secondes). Heureusement que vous avez lu ce qui est indiqué précédemment, car vous aurez besoin de la fonction qui renvoie seulement les heures, les minutes et les secondes.

Je ne vais pas vous mâcher tout le travail, parce que vous devenez grands (dans le domaine du Visual Basic, en tous cas ! :D ) ; je vais donc me contenter de vous énumérer les fonctions dont vous aurez besoin pour mener à bien votre travail.

La première fonction consiste à mettre en pause le programme pendant une durée passée en argument. Attention : cette valeur s'exprime en millisecondes.

System.Threading.Thread.Sleep()

La seconde servira à effacer l'écran de la console ; si vous avez déjà fait du Bash, c'est pareil :

Console.Clear()

Avec ces deux fonctions et les connaissances du reste du chapitre, vous devez être capables de réaliser cette horloge.

Non, je ne vous aiderai pas plus !
N'insistez pas ! :o

Vous avez terminé ? Bon, dans ce cas, faisons le compte-rendu de ce que nous venons de coder.

Module Module1
    Sub Main()
        'Initialisation des variables
        Dim MaVariableDate As Date

        'Boucle infinie /!\
        While 1
            'Récupération de la date actuelle
            MaVariableDate = Date.Now
            'Affichage des heures, minutes, secondes
            Console.WriteLine("----------------")
            Console.WriteLine("--- " & MaVariableDate.ToLongTimeString & " ---")
            Console.WriteLine("----------------")
            'Pause de 1 seconde
            System.Threading.Thread.Sleep(1000)
            'Efface l'écran de la console
            Console.Clear()
        End While
    End Sub
End Module

Je vais vous expliquer mon code.

J'ai tout d'abord déclaré une variable de type date, ce que vous avez également dû faire. Ensuite, j'ai créé une boucle infinie avec un While 1.

Le programme tourne donc jusqu'à ce qu'on l'arrête dans cette boucle.

Parce que le « 1 » est toujours vrai, cela signifie donc : « Tourne, mon grand, ne t'arrête pas ! ».

Au début de cette boucle, je récupère la date actuelle et l'écris dans ma variable.
J'affiche cette variable en utilisant la fonction permettant d'en extraire l'heure, les minutes et les secondes.

Je fais une pause d'une seconde (1000 ms = 1 s).

J'efface ensuite l'écran, puis je recommence, et ainsi de suite.

On obtient donc ceci :

----------------
--- 21:10:11 ---
----------------

Notez que vous n'êtes pas obligés de saisir des petits tirets comme je l'ai fait. :D

Parce que, que j'utilise « 100 ms », « 1 s » ou même « 1 ms », cela aura la même précision. L'horloge change à chaque seconde, pourquoi donc aller plus vite qu'elle ?

Simplification du code

Pourquoi passer par une variable ? Pourquoi ne pas entrer l'instruction qui récupère l'heure actuelle et la formater en une seule ligne ?

Module Module1
    Sub Main()
        'Boucle infinie /!\
        While 1
            'Affichage des heures, minutes, secondes
            Console.WriteLine(Date.Now.ToLongTimeString)
            'Pause de 1 seconde
            System.Threading.Thread.Sleep(1000)
            'Efface l'écran de la console
            Console.Clear()
        End While
    End Sub
End Module

Voilà mon exemple de simplification du code. Je vous l'avais bien dit : les programmeurs sont fainéants ! :)

Je l'ai expliqué lorsque j'ai parlé des fonctions et des objets. Il n'y a pas de limite d'objets que l'on peut relier, on a donc le droit de faire ça.

• Nous venons de voir différentes fonctions disponibles sur une chaîne de caractères.

• Une chaîne de caractères a le type String.

• Une date et une heure sont contenus dans des variables de type Date.

Tableau à une dimension

Comme vous le voyez, c'est exactement comme sous Excel.

Pour déclarer un tableau de ce type en Visual Basic, c'est très simple : on écrit notre déclaration de variable, d'Integer (entier) par exemple, et on place l'index du tableau entre parenthèses. Voici le code source de l'exemple que je viens de vous montrer :

Dim MonTableau(4) As Integer

Voilà mon tableau !

Oui, sa longueur est de 4. Vous devez savoir qu'un tableau commence toujours par 0. Et donc, si vous avez compris, un tableau longueur 4 possède les cases 0, 1, 2, 3 et 4, soit cinq cases, comme sur le dessin.

Le nombre de cases d'un tableau est toujours « indice + 1 ».
Réciproquement, l'index de sa dernière case est « taille - 1 ».

Souvenez-vous de cela, ce sera utile par la suite.

Comment écrire dans un tableau ?
C'est très simple. Vous avez par exemple votre tableau de cinq cases (dimension 4) ; pour écrire dans la case 0 (soit la première case), on écrit ceci :

MonTableau(0) = 10

Eh oui, il s'utilise comme une simple variable ! Il suffit juste de mettre la case dans laquelle écrire, accolée à la variable et entre parenthèses.

Eh bien, effectivement, la syntaxe est la même que celle de la fonction ; le logiciel de développement vous donnera des indications lorsque vous allez écrire la ligne, pour que vous évitiez de confondre fonctions et tableaux.

Si vous comprenez aussi vite, passons au point suivant.

Tableaux à deux dimensions

Il s'agit ici d'un tableau à deux dimensions : une pour la hauteur, une autre pour la largeur. Pour créer ce type de tableau, le code est presque identique :

Dim MonTableau(3,4) As Integer

Cela créera un tableau avec quatre lignes et cinq colonnes, comme sur le schéma.

Pour ce qui est de le remplir, le schéma l'explique déjà très bien :

MonTableau(0,0) = 10

Cela attribuera « 10 » à la case en haut à gauche.

Un tableau à deux dimensions peut servir comme tableau à double entrée par exemple.

Tableaux à trois dimensions

Regardez la figure suivante.

Comme vous le voyez, ce type de tableau est représentable par un « cube ». Il peut être utile lors de représentations tridimensionnelles (du moins, je ne vois que cette utilisation). Pour le déclarer, je pense que vous avez compris la marche à suivre.

Dim MonTableau(2,3,4) As Integer

Soit un tableau de trois cases de profondeur (le premier nombre), de quatre lignes (le second nombre) et de cinq colonnes (le dernier nombre).

Idem pour lui attribuer une valeur :

MonTableau(2,3,4) = 10

Voilà comment mettre « 10 » dans le coin inférieur droit et au fond du « cube » (pas vraiment cubique, d'ailleurs !).

Plus…

Bien qu'on puisse aller jusqu'à une trentaine de dimensions, les tableaux supérieurs à trois dimensions sont rarement utilisés. Si vous voulez stocker plus d'informations, je vous conseille de créer un tableau de tableau à trois dimensions (cela devient compliqué !).

Dim MonTableau(1)(2,3,4) As Integer

Ce code crée un tableau de tableaux à trois dimensions.

Pareil pour y accéder :

MonTableau(0)(2,3,4) = 10

Je pense que vous avez compris comment les déclarer et les utiliser sommairement. Ça tombe bien : on continue !

Ici, nous allons découvrir quelques trucs et astuces supplémentaires concernant les tableaux.

Redimensionner un tableau

La taille d'un tableau peut être redimensionnée au cours d'une application. L'instruction Redim permet de modifier la taille du tableau.

Redim monTableau(20)

Imaginons que ce tableau qui possédait 10 cases auparavant en possède maintenant 21 pour stocker des informations. Le seul problème, c'est que lorsque le programme rencontre cette ligne, le contenu entier du tableau est supprimé de la mémoire lors du redimensionnement. :(
Mais… il existe une solution ! :) Pour pouvoir conserver le contenu d'un tableau lors d'un redimensionnement, il faut spécifier le mot-clé Preserve après Redim.

Redim Preserve monTableau(20)

Retourner un tableau

Voici une fonction qui nous sera utile si l'on souhaite inverser le sens d'un tableau.

Par exemple, j'ai un tableau qui contient les nombres de 1 à 10, je souhaite avoir ce comptage de 10 à 1. Cette méthode peut alors être utilisée pour effectuer cette opération.

Son utilisation :

Array.Reverse(monTableau)

Pas besoin de beaucoup d'explications je suppose, on passe simplement le tableau à retourner en paramètre.

Vider un tableau

Pour vider rapidement un tableau, une méthode existe. Supposons que vous veniez de faire un traitement sur un tableau, vous voulez le retrouver ensuite « comme neuf » pour pouvoir le réutiliser. Plutôt que d'en créer un nouveau, pourquoi ne pas nettoyer l'ancien ?

Array.Clear(monTableau, 0, 10)

Trois paramètres sont nécessaires ici. Le premier est très simplement le tableau à vider, le second spécifie à partir de quel index vider, et le troisième indique le nombre de cases à vider.

Vous l'avez donc compris, si je veux garder les dix premiers éléments de mon tableau intacts et vider les éléments de 10 à 20, j'écrirai :

Array.Clear(monTableau, 10, 10)

Copier un tableau dans un autre

Dernière petite fonction utile, celle permettant de copier un tableau dans un autre.

Array.Copy(monTableau1, monTableau2, 5)

Trois paramètres, les deux premiers étant des tableaux. Le premier tableau étant la source (celui dans lequel nous allons copier les éléments) et le second est la destination (celui dans lequel nous allons coller les éléments). Le troisième paramètre est le nombre d’éléments à copier (depuis l'élément 0). Ainsi, 5 indique que 5 cases seront copiées dans l'autre tableau.

Bon, on va pratiquer un peu : je vais vous donner un petit exercice. Tout d'abord, récupérez le code suivant :

Dim MonTableau(50) As Integer
For i As Integer = 0 To MonTableau.Length - 1
     MonTableau(i) = Rnd(1) * 10
Next

J'explique sommairement ce code : il crée un tableau de 51 cases, de 0 à 50.
Il remplit chaque case avec un nombre aléatoire allant de 0 à 10.

En passant, vous pourrez vous servir assez souvent de la ligne For i As Integer = 0 To MonTableau.Length - 1 puisqu'elle est, je dirais, universelle ; c'est d'ailleurs ce qu'il faut faire le plus possible dans votre code. Pourquoi universelle ? Parce que, si vous changez la taille du tableau, les cases seront toujours toutes parcourues.

L'instruction MonTableau.Length renvoie la taille du tableau, je lui retire 1 car le tableau va de 0 à 50, et la taille est de 51 (comme je l'ai expliqué plus haut).

Je veux donc que vous me comptiez ce tableau si fièrement légué !

Eh bien oui, je suis exigeant : je veux connaître le nombre de 0, de 1, etc.

Au travail, vous connaissez tout ce qu'il faut !

Module Module1

    Sub Main()
        'Initialisation des variables
        Dim MonTableau(50), Nombres(10), NumeroTrouve As Integer

        'Remplissage du tableau de nombres aléatoires
        For i As Integer = 0 To MonTableau.Length - 1
            MonTableau(i) = Rnd(1) * 10
        Next

        'Initialisation du tableau « Nombres » avec des 0
        For i = 0 To Nombres.Length - 1
            Nombres(i) = 0
        Next

        'Comptage
        For i = 0 To MonTableau.Length - 1
            'Entre la valeur trouvée dans une variable intermédiaire
            NumeroTrouve = MonTableau(i)
            'Ajoute 1 à la case correspondant au numéro
            Nombres(NumeroTrouve) = Nombres(NumeroTrouve) + 1
        Next

        'Affichage des résultats
        For i = 0 To Nombres.Length - 1
            Console.WriteLine("Nombre de " & i & " trouvés : " & Nombres(i))
        Next

        'Pause
        Console.Read()
    End Sub

End Module

J'espère que vous avez réussi par vous-mêmes. Sachez que ce n'est pas grave si votre programme n'est pas optimisé, ou très long… ce n'est que le début !

J'explique donc ce que je viens de faire.

J'ai créé un tableau de onze cases appelé Nombres que j'ai initialisé avec des 0. Dans la boucle de comptage, je récupère le numéro présent dans la case actuelle et l'utilise comme indice de mon tableau Nombres, comme à la figure suivante.

En gros, si c'est un 4 qui est présent dans le tableau, il se positionne sur la quatrième case de Nombres, après quoi il ajoute 1 à cette valeur.

Enfin, j'affiche les résultats.

Petite remarque :

NumeroTrouve = MonTableau(i)
Nombres(NumeroTrouve) = Nombres(NumeroTrouve) + 1

Sachez que le code ci-dessus peut se résumer en une ligne :

Nombres(MonTableau(i)) = Nombres(MonTableau(i)) + 1

Les résultats des tests sont les suivants :

Nombre de 0 trouvés : 4
Nombre de 1 trouvés : 5
Nombre de 2 trouvés : 1
Nombre de 3 trouvés : 2
Nombre de 4 trouvés : 4
Nombre de 5 trouvés : 4
Nombre de 6 trouvés : 5
Nombre de 7 trouvés : 5
Nombre de 8 trouvés : 1
Nombre de 9 trouvés : 3
Nombre de 10 trouvés : 6

Le fait d'avoir utilisé des .Length à chaque reprise me permet de changer uniquement la taille du tableau dans la déclaration pour que le comptage s'effectue sur un plus grand tableau.

Un petit exercice : le tri. Je vais vous montrer comment faire, parce que certains d'entre vous vont rapidement être perdus.

Nous allons utiliser le tri à bulles. Pour en apprendre plus concernant l'algorithme de ce tri, je vous invite à lire ce cours rédigé par ShareMan.

Je vais vous énumérer tout ce qu'il faut faire en français, ce que l'on appelle également un algorithme (un algorithme étant une séquence à accomplir pour arriver à un résultat souhaité).

1. Créer un booléen qui deviendra vrai uniquement lorsque le tri sera bon.

2. Créer une boucle parcourue tant que le booléen n'est pas vrai.

3. Parcourir le tableau ; si la valeur de la cellule qui suit est inférieure à celle examinée actuellement, les inverser.

J'ai expliqué ce qu'il fallait que vous fassiez en suivant le tutoriel du tri à bulles.

Le présent exercice demande un peu plus de réflexion que les autres, mais essayez tout de même.

Module Module1

    Sub Main()
        'Initialisation des variables
        Dim MonTableau(20), Intermediaire, TailleTableau As Integer
        Dim EnOrdre As Boolean = False

        'Remplissage du tableau de nombres aléatoires
        For i As Integer = 0 To MonTableau.Length - 1
            MonTableau(i) = Rnd(1) * 10
        Next

        'Tri à bulles 
        TailleTableau = MonTableau.Length
        While Not EnOrdre
            EnOrdre = True
            For i = 0 To TailleTableau - 2
                If MonTableau(i) > MonTableau(i + 1) Then
                    Intermediaire = MonTableau(i)
                    MonTableau(i) = MonTableau(i + 1)
                    MonTableau(i + 1) = Intermediaire
                    EnOrdre = False
                End If
            Next
            TailleTableau = TailleTableau - 1
        End While

        'Affichage des résultats
        For i = 0 To MonTableau.Length - 1
            Console.Write(" " & MonTableau(i))
        Next

        'Pause
        Console.Read()

    End Sub

End Module

Voilà donc mon code, que j'explique : le début, vous le connaissez, je crée un tableau avec des nombres aléatoires. J'effectue ensuite le tri à bulles en suivant l'algorithme donné. Enfin, j'affiche le tout !

Le résultat est le suivant :

0 0 0 1 2 2 2 3 3 5 5 5 5 6 7 8 8 9 9 10 10

Parce que j'effectue un test sur la case située à la taille du tableau + 1. Ce qui signifie que si je vais jusqu'à la dernière case du tableau, ce test sur la dernière case + 1 tombera dans le néant ; et là, c'est le drame : erreur et tout ce qui va avec (souffrance, douleur et apocalypse). :lol:

J'espère que ce petit exercice vous a quand même éclairés concernant les tableaux !

Nous allons maintenant nous pencher sur un type un peu plus spécial : les énumérations. Une énumération va nous permettre de définir un ensemble de constantes qui sont liées entre elles.

Par exemple, il pourrait être très facile de représenter les jours de la semaine dans une énumération plutôt que dans un tableau :

Enum jours
    Dimanche
    Lundi
    Mardi
    Mercredi
    Jeudi
    Vendredi 
    Samedi
End Enum

On définit une énumération par le mot-clé Enum, une énumération se termine par End Enum.

Dans une énumération, la première valeur est initialisée à 0, la suivante est augmentée de 1 : dans notre exemple Dimanche vaut 0, Lundi vaut 1, Mardi vaut 2…

Il est possible d'entrer des valeurs pour chaque valeur de l'énumération :

Enum jours
    Dimanche = 10 'Dimanche vaut 10
    Lundi  'Lundi vaut 11
    Mardi = 26  'Mardi vaut 26
    Mercredi = 11  'Mercredi vaut 11
    Jeudi   'Jeudi vaut 12
    Vendredi = 30  'Vendredi vaut 30
    Samedi  'Samedi vaut 31
End Enum

Les valeurs de l'énumération qui n'ont pas reçu de valeur particulière prendront la valeur précédente augmentée de 1.

Une fois définie, une énumération peut ensuite être utilisée comme un type de variable spécifique :

Dim joursSemaine As jours

Ce qui donne en entier :

Enum jours
    Dimanche
    Lundi
    Mardi
    Mercredi
    Jeudi
    Vendredi 
    Samedi
End Enum

Sub Main()
    Dim joursSemaine As jours

    joursSemaine = jours.Dimanche
    Console.WriteLine(joursSemaine)
End Sub

Ce qui nous donne :

Dimanche

• Un tableau peut contenir plusieurs valeurs.

• Un tableau a des cases, on peut accéder à chaque case en particulier.

• La première case d'un tableau a toujours la position 0.

• Un tableau peut être à plusieurs dimensions. Les tableaux de base sont à une dimension et sont comparables à des listes.

Nous allons donc créer notre première fonction, la plus basique qui soit : sans argument, sans retour. Mais on va tout de même lui faire faire quelque chose… Pourquoi, par exemple, ne pas additionner deux nombres que l'on saisit à l'écran ?

Vous vous rappelez certainement le TP avec l'addition. Eh bien, on va factoriser l'addition avec la demande des nombres (« factoriser » signifie mettre sous forme de fonction).

Module Module1

    Sub Main()
        Addition()
    End Sub

    Sub Addition()
        Dim ValeurEntree As String = ""
        Dim Valeur1 As Integer = 0
        Dim Valeur2 As Integer = 0

        Console.WriteLine("- Addition de deux nombres -")
        'Récupération du premier nombre
        Do
            Console.WriteLine("Entrez la première valeur")
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)
        'Écriture de la valeur dans un integer
        Valeur1 = ValeurEntree

        'Récupération du second nombre
        Do
            Console.WriteLine("Entrez la seconde valeur")
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)
        'Écriture de la valeur dans un integer
        Valeur2 = ValeurEntree

        'Addition
        Console.WriteLine(Valeur1 & " + " & Valeur2 & " = " & Valeur1 + Valeur2)

        'Pause factice
        Console.Read()
    End Sub
End Module

Bien au contraire : j'ai placé dans le Main() l'appel de la fonction.

Lorsque vous créez une fonction, ce n'est pas comme le Main(), elle ne se lance pas toute seule ; si je n'avais pas ajouté cet appel, le programme n'aurait rien fait !

La ligne Addition() appelle donc la fonction, mais pourquoi ? Avez-vous remarqué le Sub que j'ai placé en dessous du Main() ?

C'est pour cela que j'ai écrit Sub Addition(), et non Function Addition() (Function étant le mot-clé déclarant une fonction). Et donc, dans ce Sub, j'ai copié-collé exactement le code de notre TP sur l'addition.

Vous pouvez tester : ça fonctionne !

Vous avez vu comment créer une fonction que je qualifierais d'« indépendante », ce qui signifie que cette dernière n'influera pas sur le reste du programme, et exécutera toujours la même chose : demander des valeurs, les additionner et afficher le résultat.

Cependant, ce style de raisonnement va vite nous limiter. Heureusement, les créateurs des langages de programmation ont pensé à quelque chose de génial : les arguments et le retour.

Les arguments

Vous savez déjà ce qu'est un argument. Par exemple, dans la fonction Write(), l'argument est la valeur placée entre parenthèses, et cette fonction effectue « Affiche-moi cette valeur ! ».

Vous l'avez donc sûrement compris, les arguments sont mis entre parenthèses… « les », oui, exactement, parce qu'il peut y en avoir plusieurs ! Et vous l'avez déjà remarqué : lorsque nous avons étudié le BEEP, les arguments étaient la fréquence et la durée. Et tous deux séparés par… une virgule (« , ») !

Dans une fonction, les différents arguments sont séparés par une virgule. Vous savez donc comment passer des arguments à une fonction, mais comment créer une fonction qui les reçoive ?

La ligne se présente sous la forme suivante :

Sub Addition(ByVal Valeur1 As Integer, ByVal Valeur2 As Integer)

Vous remarquez bien les ByVal Valeur1 As Integer ; cette syntaxe est à utiliser pour chaque argument : le mot ByVal, le nom de la variable, le mot As, et le type de la variable.

Ce qui nous donne, dans un cas comme notre addition :

Sub Addition(ByVal Valeur1 As Integer, ByVal Valeur2 As Integer)
        'Addition des deux arguments
        Console.WriteLine(Valeur1 & " + " & Valeur2 & " = " & Valeur1 + Valeur2)

        'Pause factice
        Console.Read()
End Sub

Voilà par exemple le Sub que j'ai écrit, et qui additionne deux valeurs passées en arguments.

Elles ont été automatiquement déclarées dans la ligne de création de fonction.

Si vous souhaitez appeler cette fonction, comment faut-il procéder ?

Addition(Valeur1, Valeur2)

Vous avez bien compris ?

Vous avez dû le remarquer, il faut obligatoirement utiliser tous les arguments lors de l'appel de la fonction, sauf une petite exception que je vous présenterai plus tard.

Valeur de retour

Imaginez que vous ayez envie d'une fonction qui effectue un calcul très compliqué ou qui modifie votre valeur d'une certaine manière. Vous voudriez sans doute récupérer la valeur ? C'est ce qu'on appelle le retour :

Function Addition(ByVal Valeur1 As Integer, ByVal Valeur2 As Integer) As Integer

C'est le morceau du bout (As Integer) qui nous intéresse : c'est cette partie qui indiquera à la fonction le type de valeur qu'elle doit renvoyer. Dans le cas présent, il s'agit d'un type numérique, mais j'aurais très bien pu écrire As String.

Je vous l'ai dit tout en haut : les Sub ne renvoient rien, il faut donc passer par les fonctions si on veut une valeur de retour.

Function Addition(ByVal Valeur1 As Integer, ByVal Valeur2 As Integer) As Integer
        Dim Resultat As Integer
        'Addition des deux arguments
        Resultat = Valeur1 + Valeur2

        'Renvoie le résultat
        Return Resultat
End Function

Cette fonction additionne donc les deux nombres passés en arguments et renvoie le résultat.

La ligne Return Resultat est très importante, car c'est elle qui détermine le retour : si vous n'écrivez pas cette ligne, aucun retour ne se fera.

Maintenant, comment appeler cette fonction ? La forme Addition(Valeur1, Valeur2) aurait pu fonctionner, mais où va la valeur de retour ? Il faut donc récupérer cette valeur avec un « = ».

Resultat = Addition(Valeur1, Valeur2)

Une fois cet appel écrit dans le code, ce dernier additionne les deux valeurs. Je suis conscient que cette démarche est assez laborieuse et qu'un simple Resultat = Valeur1 + Valeur2 aurait été plus simple, mais c'était pour vous faire découvrir le principe.

Cette fonction peut être directement appelée dans une autre, comme ceci par exemple :

Console.WriteLine(Addition(Valeur1, Valeur2))

Sachez que les fonctions vont vous être très utiles. J'espère qu'à présent vous savez les utiliser. :p

Les arguments facultatifs

Tout d'abord, une petite astuce que je vais vous expliquer : l'utilisation des arguments facultatifs. Je vous ai dit que tous les arguments étaient indispensables, sauf exception ; eh bien, voici l'exception.

Les arguments facultatifs sont des arguments pour lesquels on peut choisir d'attribuer une valeur ou non au moment de l'appel de la fonction. Pour les déclarer, tapez Optional ByVal Valeur3 As Integer = 0.

Le mot-clé Optional est là pour dire qu'il s'agit d'un argument facultatif, le reste de la syntaxe étant la même que pour les autres fonctions.

Function Operation(ByVal Valeur1 As Integer, ByVal Valeur2 As Integer, Optional ByVal Valeur3 As Integer = 0) As Integer
        Return Valeur1 + Valeur2 + Valeur3
End Function

Voilà donc la nouvelle fonction. Dans l'appel de cette fonction, je peux maintenant écrire Operation(1, 5), ce qui me renverra 6, ou alors Operation(10, 15, 3) qui me renverra 28. Les deux appels sont valides.

Commenter sa fonction

Je vous ai déjà résumé la marche à suivre pour commenter des lignes. Mais voilà, comment faire pour commenter des fonctions entières ?
Placez-vous sur la ligne juste avant la fonction.

Function Operation(ByVal Valeur1 As Integer, ByVal Valeur2 As Integer, Optional ByVal Valeur3 As Integer = 0) As Integer
        Return Valeur1 + Valeur2 + Valeur3
End Function

Ajoutez ensuite trois quotes : « ''' ».
Des lignes vont s'afficher :

''' <summary>
''' 
''' </summary>
''' <param name="Valeur1"></param>
''' <param name="Valeur2"></param>
''' <param name="Valeur3"></param>
''' <returns></returns>
''' <remarks></remarks>

Ces lignes permettent de commenter la fonction : dans summary, expliquez brièvement le rôle de la fonction ; dans les paramètres, précisez à quoi ils correspondent ; et dans la valeur de retour, indiquez ce que la fonction retourne.

Par exemple, j'ai commenté ma fonction comme ceci :

''' <summary>
''' Additionne les valeurs passées en argument
''' </summary>
''' <param name="Valeur1">Première valeur à additionner</param>
''' <param name="Valeur2">Seconde valeur à additionner</param>
''' <param name="Valeur3">Troisième valeur à additionner, Optionnel</param>
''' <returns>L'addition des arguments</returns>
''' <remarks></remarks>

Cliquez ensuite sur cette petite flèche pour « replier » cette zone, comme à la figure suivante.

À présent, à chaque endroit où vous allez écrire cette fonction, un cadre s'affichera vous indiquant ce qu'il faut lui donner comme arguments, comme à la figure suivante.

Cela est très utile lorsque vous avez beaucoup de fonctions.

Pour clore ce chapitre, je vous propose un petit exercice.

Je vais vous demander de remplir un tableau de dix cases et d'additionner les valeurs, la récupération de ces valeurs devant se faire en toute sécurité, comme dans notre TP sur l'addition.
La partie qui demande la valeur et qui vérifie s'il s'agit d'un nombre devra être écrite dans une fonction séparée.

À vos claviers !

Module Module1

    Sub Main()
        Dim TableauDeValeurs(9) As Integer
        Dim Resultat As Integer = 0

        'Demande les valeurs en passant par la fonction
        For i As Integer = 0 To TableauDeValeurs.Length - 1
            TableauDeValeurs(i) = DemandeValeur(i)
        Next

        'Additionne les valeurs
        For i As Integer = 0 To TableauDeValeurs.Length - 1
            Resultat = Resultat + TableauDeValeurs(i)
        Next

        'Affiche le résultat
        Console.WriteLine(Resultat)

        'Pause
        Console.Read()
    End Sub

    Function DemandeValeur(ByVal Numero As Integer) As Integer
        Dim ValeurEntree As String

        'Demande la valeur
        Do
            Console.WriteLine("Entrez valeur " & Numero + 1)
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)

        'Convertit la valeur en integer et la renvoie
        Return CInt(ValeurEntree)
    End Function
End Module

Clarifions un peu ce code.

J'entre dans une boucle dans laquelle j'appelle la fonction, en passant comme paramètre le numéro de la boucle. Mais pourquoi ?
Allons faire un tour du côté de la fonction : ce paramètre me permet de dire à l'utilisateur quel est le numéro qu'il entre (Console.WriteLine("Entrez valeur " & Numero + 1) ; j'ajoute « 1 » pour ne pas avoir de Entrez valeur 0).

Cette fonction, vous la connaissez : c'est la même que pour l'addition ; sauf que… la ligne Return CInt(ValeurEntree) vous inquiète…

J'explique : ce que je viens de faire s'appelle un cast, c'est-à-dire que l'on convertit un type en un autre.
Cette ligne fait appel à la fonction CInt(), qui permet de convertir une variable de type string, par exemple, en integer. Pourquoi ai-je fait cela ?

Parce que je renvoie un integer, et que la variable est pour le moment un string. Je peux le faire en toute sécurité puisque je vérifie que mon string contient bien une valeur numérique ; s'il avait contenu, par exemple, un mot, il y aurait eu une erreur.

Vous auriez très bien pu passer par une variable intermédiaire, comme on l'a vu précédemment.

Voilà qui clôt notre chapitre sur les fonctions.

• Si l'on commence la déclaration de la fonction avec le mot-clé Sub, elle ne retournera pas de valeur, ce sera alors une méthode.

• Une fois l'instruction contenant return exécutée, la fonction ne continue pas son exécution.

• Vous utilisez des centaines de fonctions déjà écrites dans le framework de Visual Basic .NET, vous pouvez en créer autant que vous le voulez.

• Les arguments optionnels sont définis avec le mot-clé Optionnal.

Pour commencer cette partie des inclassables, je vais vous apprendre ce qu'est une constante en programmation.

Je pense que vous savez ce qu'est une constante dans le langage normal : c'est une variable qui ne varie pas (rigolo ! :-° ) ; elle garde toujours la même valeur.
Dans notre programme, ce sera pareil : une constante ne variera jamais au cours de notre programme, on ne peut donc pas lui assigner de valeur une fois sa déclaration effectuée.

C'est assez intéressant : imaginez un tableau dans lequel vous demandez dix valeurs à l'utilisateur. Vous allez le déclarer comme ceci :

Dim MonTableau(9) As Integer

Et, dans le reste du code, vos boucles auront pour fin :

to MonTableau.Length - 1

Si vous souhaitez changer et demander vingt valeurs au lieu de dix, vous allez devoir modifier cela dans la déclaration du tableau, ce qui, pour le moment, est simple si votre déclaration est faite au début de votre code.

Seulement, vous allez rapidement prendre l'habitude de déclarer vos variables en plein milieu du code, là où vous en avez besoin.
La joie pour retrouver son petit morceau de tableau dans tout ça…

Une autre solution serait de déclarer une constante, comme ceci :

Const LONGUEURTABLEAU As Integer = 9

… et de déclarer votre tableau ainsi :

Dim MonTableau(LONGUEURTABLEAU) As Integer

Eh oui, ça fonctionne ! Maintenant, vous rassemblez toutes vos constantes en haut de la page (ou dans une page à part pour les gros programmes), et voilà le moyen d'adapter facilement vos programmes sans trop de difficultés.

Une autre chose qui pourra vous être utile dans certains programmes : les structures.

Alors, à quoi sert une structure, ou plutôt un tableau de structure ? (Eh oui, on grille les étapes ! :p ) Et comment l'utiliser ?

Tout d'abord, une structure est un assemblage de plusieurs variables ; une fois n'est pas coutume, je vais vous donner un exemple.

Vous avez l'intention de créer des fiches de livres dans votre programme. Chaque fiche rassemble les informations d'un livre : titre, auteur, genre, etc. Eh bien, dans ce cas, un tableau de structure va vous être utile (je parle de tableau de structure, car si on n'utilise la structure qu'une seule fois, elle est presque inutile).

Maintenant, comment l'utiliser ?

Sa déclaration est simple :

Structure FicheLivre
   Dim ID        As Integer
   Dim Titre     As String
   Dim Auteur    As String
   Dim Genre     As String
End Structure

Nous voici donc avec une structure définie (comme pour une fonction, il y a un End Structure à la fin). Comme vous pouvez le constater, je l'ai nommée « FicheLivre ».
En définissant cette structure, c'est comme si on avait créé un nouveau type de variable (symboliquement). Mais il faut à présent la déclarer et, pour ce faire, utilisons ce nouveau type ! :p

C'est au moment de la déclaration que l'on décide si l'on souhaite un tableau de structure ou une simple structure :

'Déclare une simple structure
Dim MaStructure As FicheLivre
'Déclare un tableau de structure
Dim MonTableauDeStructure(9) As FicheLivre

Je vais donc utiliser le tableau pour vous montrer comment on utilise cette structure.

MonTableauDeStructure(0).ID = 0
MonTableauDeStructure(0).Titre = "Les Misérables"
'…
MonTableauDeStructure(9).Auteur = "Dan Brown"
MonTableauDeStructure(9).Genre = "Policier"

Voilà comment remplir votre structure ; cette méthode de programmation permet de se retrouver facilement dans le code.

Voici un exemple pour afficher cette structure :

For i As Integer = 0 To 10
   Console.WriteLine("ID : " & MonTableauDeStructure(i).ID)
   Console.WriteLine("Titre : " & MonTableauDeStructure(i).Titre)
   Console.WriteLine("Auteur : " & MonTableauDeStructure(i).Auteur)
   Console.WriteLine("Genre : " & MonTableauDeStructure(i).Genre)
Next

Voilà encore un petit truc toujours utile. :)

Vous vous souvenez encore des boucles conditionnelles ? :-°

Eh bien, je vais vous en faire découvrir deux nouvelles : For Each et IIf.

Désolé, mais tout à l'heure vous ne pouviez pas vous en servir : vous n'aviez pas encore les connaissances requises.

Bon, je passe tout de suite à la première boucle !

For Each, traduisible par « pour chaque »

Vous vous souvenez des tableaux ?

Dim MonTableau(9) As integer

Eh bien, la boucle For Each permet de parcourir ce tableau (un peu à la manière du For traditionnel) et de récupérer les valeurs.

Utilisons donc immédiatement cette boucle :

For Each ValeurDeMonTableau As Integer In MonTableau
   If ValeurDeMonTableau < 10 Then
      Console.WriteLine(ValeurDeMonTableau)
   End If
Next

Ce qui se traduit en français par ceci : « Pour chaque ValeurDeMonTableau qui sont des entiers dans MonTableau ».

Ce code parcourt mon tableau et vérifie si chaque valeur est inférieure à 10 ; si c'est le cas, il l'affiche.

Très utile, donc, pour lire toutes les valeurs d'un tableau, d'un objet liste par exemple (que nous verrons plus tard).

IIF

IIF est très spécial et peu utilisé : en un certain sens, il simplifie le If. Voici un exemple de son utilisation dans le code précédent :

Dim MaChaine As String = "Salut"
Dim Compteur As Integer = 0
For Each Caractere As String In MaChaine
   If Caractere = "a" Then
       Compteur = Compteur + 1
   End If
Next
Console.WriteLine(IIF(Compteur > 0, "La lettre 'a' a été trouvée dans " & MaChaine, "La lettre 'a' n'a pas été trouvée dans " & MaChaine))

En clair, si vous avez bien analysé : si le premier argument est vrai (c'est un booléen), on retourne le second argument ; à l'inverse, s'il est faux, on retourne le dernier.

Pour mieux comprendre :

IIF(MonBooleen, "MonBooleen est true", "MonBooleen est false")

MonBooleen

peut bien évidemment être une condition.

J'ai brièvement parlé des casts dans un chapitre précédent : lorsque j'ai converti un string en un integer et que je vous ai dit que j'avais casté la variable.

Donc, vous l'avez compris, un cast convertit une variable d'un certain type en un autre.

Alors, il existe plusieurs moyens d'effectuer des casts : une fonction universelle, et d'autres plus spécifiques.

Ctype()

La fonction universelle se nomme Ctype. Voici sa syntaxe :

Ctype(MaVariableString, Integer)

Ce code convertira MaVariableString en integer.

Voici un exemple concret :

Dim MonString As String = "666"
If Ctype(MonString, Integer) = 666 Then
'…
End If

Encore une fois, faites attention. Un code du style…

Dim MonString As String = "a666"
If Ctype(MonString, Integer) = 666 Then
'…
End If

… produira une grosse erreur !

Les fonctions spécifiques

On a vu l'exemple de Ctype(), utile lorsqu'il s'agit de types peu courants. Mais pour les types courants, il existe des fonctions plus rapides et adaptées :

• CBool() : retourne un Boolean.

• CByte() : retourne un Byte.

• CChar() : retourne un Char.

• *CDate() : retourne une date.

• *CDbl() : retourne un Double.

• CDec() : retourne un nombre décimal.

• *CInt() : retourne un Integer.

• CLng() : retourne un Long.

• CSng() : retourne un Single.

• *CStr() : retourne un String.

• CUInt() : retourne un Unsigned Integer.

• CULng() : retourne un Unsigned Long.

• CUShort() : retourne un Unsigned Short.

Toutes ces fonctions ne prennent qu'un argument : la variable à convertir… c'est facile à retenir !
Les fonctions que j'ai fait précéder d'une astérisque « * » sont les plus utilisées. Attention, les « * » ne font pas partie de la fonction, c'est uniquement pour mieux les repérer.

Ah, tenez… c'est une bonne occasion de vous en parler.
Vous connaissez le type numérique integer ? (Oui, évidemment ! :D )

Eh bien, le Unsigned permet d'augmenter la capacité de vos variables : au lieu d'aller d'environ - 2 000 000 000 à 2 000 000 000 dans le cas d'un int, cette capacité s'étend plutôt de 0 à 4 000 000 000 (approximativement) ; Unsigned signifiant « non signé », il n'y a plus de signe.

En quoi cela peut-il nous être utile ? Je n'ai pas encore trouvé d'utilisation particulière parce que, si j'ai besoin d'un nombre plus grand que quatre milliards, j'utilise Long, qui peut contenir des nombres beaucoup plus grands.

De retour à nos petites fonctions : leur utilisation.

Dim MonString As String = "666"
If CInt(MonString) = 666 Then
'…
End If

Un élément supplémentaire dans cette partie « petits plus » : je vais vous présenter un nouveau type, appelé object.

Ce type object (qui remplace le type variant en VB6) est utilisé lorsque l'on ne sait pas ce que va contenir notre variable. Il peut donc contenir des mots, des nombres, etc.

Exemple concret : vous vous souvenez de notre calculatrice ; les instructions dans lesquelles on demandait la valeur tout en vérifiant qu'il s'agissait d'un nombre étaient les suivantes :

'Récupération du premier nombre
        Do
            Console.WriteLine("Entrez la première valeur")
            ValeurEntree = Console.ReadLine()
            'Tourne tant que ce n'est pas un nombre
        Loop Until IsNumeric(ValeurEntree)
        'Écriture de la valeur dans un double
        Valeur1 = ValeurEntree

Nous allons refaire cette partie en utilisant le type object.
Déclarons notre variable de type objet :

Dim MonObjet As Object

Nous allons devoir tourner dans notre boucle tant qu'il ne s'agit pas d'un nombre.

Il est tout à fait possible d'utiliser la fonction IsNumeric() dans le cas d'un object, mais il existe aussi TypeOf MonObjet Is Integer qui renvoie un booléen.
Une fois qu'il est placé dans une boucle, on retrouve notre programme sous une autre forme :

Dim MonObjet As Object
Do
    Console.WriteLine("Entrez la première valeur")
    MonObjet = Console.ReadLine()
    'Tourne tant que ce n'est pas un nombre
Loop Until IsNumeric(MonObjet)
MonObjet = CInt(MonObjet)

Cela revient au même que le code précédent, hormis que l'on n'utilise qu'une seule variable.

Deux petites choses qui peuvent également vous aider : les MsgBox et les InputBox (voir figures suivantes).

À quoi ça sert ?

Première question… Eh bien, diverses utilisations peuvent en être faites, puisqu'elles seront utilisables du côté visuel également.

Les MsgBox peuvent signaler une erreur, demander une confirmation, etc. Les InputBox, quant à elles, peuvent être utilisées dans des scores par exemple, pour demander le nom du joueur.

Beaucoup d'arguments existent pour les paramétrer, je vais vous les expliquer.

La MsgBox

Les paramètres

Voici la liste des arguments. Pas de panique, il n'y en a que trois ! Je vais vous les décrire :

1. Prompt : message qui apparaîtra dans la MsgBox.

2. Buttons : type de bouton à utiliser (style de la boîte).

3. Title : titre de la boîte.

Pour ce qui est du deuxième argument — les boutons à utiliser —, lorsque vous êtes sur le point d'entrer cet argument, une liste s'offre à vous : c'est cette liste qu'il vous faut utiliser pour trouver votre bonheur.

Voici dans le tableau suivant divers exemples de style.

Les numéros indiqués correspondent aux ID, que vous pouvez cumuler. En gros, si vous souhaitez que votre boîte bloque le système et que l'on doive y répondre avant de continuer, avec une icône « Message critique » et des boutons « OK − Annuler », il faut que vous tapiez… 4096 + 1 + 16 = 4113 !

Voici donc le code correspondant, les Chr(13) représentant des retours à la ligne :

MsgBox("Je suis une MsgBox qui bloque votre système tant que vous n'avez pas répondu" & Chr(13) & " J'ai l'icône d'une croix rouge (critical) et mes boutons sont : Ok / Annuler" & Chr(13) & "Je vous souhaite un agréable vol sur notre compagnie ...", 4113, "Ma boiboitte")

Cela donne le résultat visible à la figure suivante.

Pour le moment, c'est bon ? :lol:

Le retour

Passons à la valeur de retour !

Les boutons sur lesquels on clique ne renvoient pas tous la même valeur :

1. OK → 1

2. Cancel → 2

3. Abort → 3

4. Retry → 4

5. Ignore → 5

6. Yes → 6

7. No → 7

Un petit If devrait vous permettre d'effectuer une action précise en fonction de ce que l'utilisateur a entré !

InputBox

Les paramètres

Les arguments de l'InputBox sont un peu moins ennuyeux et ne sont pas difficiles à retenir :

1. Le Prompt, comme pour la MsgBox.

2. Le titre de la fenêtre.

3. La valeur par défaut entrée dans le champ à remplir.

4. La position de la boîte en X (sur l'horizontale, en partant de la gauche).

5. La position de la boîte en Y (sur la verticale, en partant du haut).

L'origine du repère se situe donc en haut à gauche. Si vous entrez « 0 » pour les positions X et Y, alors la boîte se retrouvera en haut à gauche ; pour la laisser centrée, ne mettez rien.

Le retour

Cette fois, la valeur de retour n'est pas forcément un nombre : cela peut être une chaîne de caractères ou toute autre chose que l'utilisateur a envie d'écrire.

Voilà pour les box, c'est fini !

• Les constantes sont des variables destinées à ne pas changer de valeur.

• For each permet d'itérer sur chaque valeur d'une liste, d'un tableau.

• MsgBox et InputBox sont des fenêtres de dialogue pour capter l'attention de l'utilisateur.

Jusqu'à maintenant je vous ai obligés (grrr !) à rester sur la console. C'est moche, d'accord, mais comprenez-moi : vous avez uniquement eu besoin de deux fonctions jusqu'à maintenant : Console.ReadLine() pour l'entrée et Console.WriteLine() pour la sortie. Ici, vous n'aurez plus besoin de l'objet Console, donc les Console. on oublie !

Recréons un nouveau projet, Windows Forms cette fois-ci. Admirez le superbe résultat visible à la figure suivante.

Sur notre gauche nous retrouvons le panneau que je vous ai présenté tout au début de ce tutoriel : la boîte à outils. Cette boîte contient donc des outils, outils que nous allons déposer sur notre feuille. J'appelle feuille la petite fenêtre avec rien dedans au centre de votre écran, c'est un peu comme une feuille de papier sur laquelle vous allez dessiner.

Cette "feuille de papier" est appelée feuille de style ou fenêtre de design. Elle est uniquement dédiée à construire la partie "graphique" de votre futur programme.

Tout d'abord, les avantages par rapport à la console sont immenses : c'est plus beau, c'est agréable de travailler dessus, c'est fonctionnel, mais surtout, si vous vous amusez à lancer votre projet vide, sans aucune ligne de code ajoutée, votre fenêtre se lance et reste là. Elle restera jusqu'à ce que vous appuyiez sur la croix rouge en haut à droite.

Vous l'avez donc compris, si on écrit quelque chose dedans, ça reste ! Mais ce ne sera pas aussi simple que la console. Il faudra passer par nos outils pour écrire et interagir avec l'utilisateur. Il faudra donc bien les connaître pour savoir lequel utiliser dans quelles situations.

Le Label, par exemple, nous servira principalement à écrire du texte dans cette interface ; la Textbox, à demander à l'utilisateur d'écrire du texte ; le bouton, à déclencher un évènement.

Retournons à notre feuille :

Rien qu'elle, vous pouvez déjà la manipuler : quand vous cliquez dessus, des carrés blancs apparaissent sur les bords (voir figure suivante), ils vont nous permettre d'agrandir ou réduire la fenêtre, comme n'importe quelle autre fenêtre Windows.

Une fois cette fenêtre à la hauteur de vos espérances, nous allons apprendre à ajouter des objets dedans, ces objets sont appelés des contrôles. Pour ce faire, je vais vous laisser vous amuser avec les objets : prenez-les en cliquant dessus, puis faites-les glisser jusqu'à la fenêtre sans relâcher le clic.

Laissez libre cours à votre imagination, essayez tous les objets que vous voulez ! Regardez ce que j'obtiens à la figure suivante

Stop ! pourquoi vouloir savoir courir avant de savoir marcher ? On va l'apprendre dans le prochain chapitre. Mais ce n'est pas une raison pour fermer ce chapitre et aller tout de suite au suivant ! :colere2:

En attendant vous pouvez déjà lancer ce projet, votre fenêtre apparaîtra. Bon, rien ne se passe quand vous appuyez sur les boutons, pourquoi ?

Eh bien, nous n'avons pas encore codé d'événements ! Ça ne saurait tarder… :p

Je vais quand même vous expliquer une dernière petite chose.

Cliquez dans projet > propriétés de [nom de votre projet]. Une fenêtre semblable à la figure suivante devrait apparaître.

J'explique pourquoi elle va nous être utile. Elle permet tout d'abord de choisir un nom et une icône pour votre application (mais bon ce n'est pas la priorité), mais elle servira surtout à choisir sur quelle fenêtre votre projet va démarrer. Très utile lorsqu'on en aura plusieurs.

Les autres options sont plus techniques, et pas nécessaires actuellement.

• On crée un projet Windows Forms pour pouvoir utiliser l'interface graphique.

• Les contrôles sont disponibles dans la boîte à outils, ils nous permettent de concevoir notre interface.

• La feuille de style (design) est la fenêtre dans laquelle on conçoit l'interface graphique.

Je pense que vous avez sûrement déjà vu la fenêtre contenant les propriétés (voir figure suivante).

La chose magnifique est que nous sommes sous Visual Basic Express, un module du grand IDE qu'est Visual Studio. Et cet IDE va vous permettre :

• D'avoir les messages d'erreur écrits en français la plupart du temps ;

• De résoudre les erreurs sans se poser de questions ;

• D'avoir la description de toutes les propriétés des objets ;

• D'avoir la description de toutes les fonctions ;

• D'avoir un système de debug magique ;

• Et j'en passe…

Bref, Visual Basic Express va vous mâcher énormément le travail. Tout ça pour vous dire : côté propriétés, nous allons être grandement aidés, tout sera très intuitif, un vrai plaisir.

Donc revenons à nos moutons : qu'est ce qu'une propriété sur un objet VB ? Attention, ici je parle des objets graphiques que nous voyons (boutons, labels, textbox…).

Eh bien, ces propriétés sont toutes la partie design et fonctionnelle de l'objet : vous voulez cacher l'objet, agissez sur la propriété Visible ; vous voulez le désactiver, la propriété Enable est là pour ça ; l'agrandir, lui faire afficher autre chose, le changer de couleur, le déplacer, le tagger… agissez sur ses propriétés.

Les propriétés nous seront accessibles côté feuille design, mais aussi côté feuille de code VB, on agit d'un côté ou de l'autre. Très utile lorsque vous voulez faire apparaître ou disparaître un objet dynamiquement, l'activer ou le désactiver, etc.

Si vous voulez le placer, lui attribuer un nom, et le définir comme vous voulez : agissez côté design, ensuite si vous voulez le déplacer pendant l'exécution, les propriétés seront modifiées côté VB.

Oh, excusez-moi, pour ouvrir le code, allons dans notre fenêtre de solutions, vous devez voir :

• Une icône myproject, elle correspond aux propriétés du projet entier, que je vous ai expliqué ;

• Le second est form1.vb, c'est ce fichier qui nous intéresse.

Cliquez droit sur form1.vb, vous avez :

• Le concepteur de vues pour le côté design ;

• Et… afficher le code ! Voilà comment afficher le code.

Alors, vous savez désormais à quoi ça sert, mais comment se servir de ces magnifiques choses ?

Eh bien, côté visuel, pas trop de mal : ouvrez la fenêtre des propriétés. Si vous ne savez plus comment on fait, appuyez sur la touche F4 de votre clavier.

Bon, votre fenêtre est ouverte. La figure suivante représente ce qu'il y a dans la partie supérieure.

Le mot en gras est le nom de votre contrôle (que j'appelle également objet), ce nom est défini dans la propriété (name), à noter qu'il n'est pas possible d'accéder côté VB aux propriétés entre parenthèses.

Cette propriété est fondamentale, comme elle correspond au nom de l'objet (ou à son ID), c'est ce nom qui sera utilisé côté VB pour y accéder et le modifier. Utilisez un nom explicite !

Je vous explique ma manière de procéder : mes contrôles sont toujours en MAJUSCULES.
Ils contiennent un préfixe en fonction de leur type :

• BT pour les boutons ;

• LBL pour les labels ;

• TXT pour les textbox ;

• LNK pour les labels links ;

• RB pour les boutons radio ;

• CHK pour les checkbox ;

• Et j'en passe…

Je ne vous oblige absolument pas, mais je vous le conseille quand même. Après ce préfixe je place un underscore « _ », puis la fonction rapide de l'objet. Exemple pour ici : BT_ENVOI est le bouton pour envoyer.

Bon, après notre nom, nous avons le type d'objet dont il s'agit, c'est un button.

Dans le reste de cette fenêtre (voir figure suivante), vous voyez la liste des propriétés de l'objet. Cliquez sur la case correspondante pour lui assigner une propriété. Dans le cas de mon bouton, vous le voyez à droite, j'ai modifié sa propriété font, qui veut dire en anglais « police » , j'ai changé sa size (autrement dit sa taille), et j'ai modifié également sa propriété Text, pour lui changer son nom.

Pour qu'on travaille tous sur la même chose, on va tous créer la fenêtre visible à la figure suivante.

Donc j'ai un bouton appelé « BT_ENVOI », et une TextBox, que vous trouvez également sur le côté pour placer vos objets et qui s'appelle TXT_RECOIT. Et c'est parti pour l'aventure !

Nous allons donc modifier les propriétés des objets côté VB.

Vous vous souvenez du Sub Main() quand nous étions en console ?

Ici, c'est à peu près pareil, sauf que ça s'appelle des événements (j'expliquerai plus tard, pas de panique), et notre événement utilisé ici s'appelle form_load ; c'est, comme son nom l'indique, l'événement pénétré lorsque la fenêtre se lance (plus exactement durant son chargement).

Donc, pour le créer, il y a deux manières : l'écrire, mais comme vous ne connaissez pas les syntaxes des événements on ne va pas vous prendre la tête pour le moment, ou le générer automatiquement grâce à notre IDE.

Peut-être l'avez vous déjà fait par erreur : double-cliquez sur n'importe quel point de la fenêtre que vous créez (pas un contrôle surtout !).

Vous atterrissez côté code VB…

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

    End Sub

End Class

… avec ce magnifique code. Alors, pour le moment, comprenez juste que ce sub sera pénétré au chargement de la fenêtre, j'expliquerai plus tard comment ça fonctionne. Donc on va écrire dedans.

Alors, comment attribuer les propriétés ? Eh bien, c'est très simple : il faut tout d'abord dire sur quelle fenêtre on travaille, ici (et dans la majorité des cas) c'est la fenêtre actuelle appelée Me en VB (un peu comme le this en JavaScript ou en C++).

Donc nous avons Me, il faut le lier au reste, utilisons donc le caractère « . » : nous allons donc accéder aux objets et contrôles de cette fenêtre. Ici une liste s'affiche à nous, c'est tout ce que l'on peut utiliser avec l'objet Me(autrement dit la fenêtre). Spécifions autre chose : nous voulons accéder à notre textbox, donc on tape son nom : « TXT_RECOIT ». À peine la partie « TXT » écrite, notre formidable IDE nous donne déjà le reste, comme le montre la figure suivante.

Un petit TAB nous permet de compléter automatiquement le mot (réflexe que vous prendrez par la suite pour coder de plus en plus rapidement), continuons notre avancement, je veux changer le texte présent dans la textbox, donc accédons à la propriété text, pareil que précédemment, il nous affiche déjà le reste.

Nous voilà donc sur la propriété text, nous avons deux choix : attribuer sa valeur ou l'utiliser ; pour l'utiliser le signe « = » se place avant, et pour l'assigner, après.

Assigner est utile pour entrer des valeurs, utiliser sa valeur est pratique pour des cas comme les textbox, et récupérer ce que l'utilisateur a entré.

Nous allons donc l'assigner, et attribuons-lui une valeur texte, voici un exemple de la ligne de code :

Me.TXT_RECOIT.Text = "Salut"

Voilà, lançons le programme pour essayer : un salut s'est affiché dans la textbox (voir figure suivante) !

Nous avons réussi notre premier accès à une propriété côté VB.

Pourquoi s'arrêter là ? alignons ce texte !
Tapons donc Me.TXT_RECOIT.Tex, et là l'autocomplétion me propose… textalign !

Pourquoi s'en priver ? J'écris donc ma propriété textalign, un « = » pour lui assigner une propriété, et là notre magnifique IDE fait encore tout le travail (voir figure suivante) !

Centré, à gauche ou à droite ? Double-cliquez sur votre choix (j'ai choisi centré dans cet exemple). Au nouveau test de notre application, vous obtenez la figure suivante.

C'est magique, c'est le VB, c'est tout !

Voici un petit mot qui va changer votre vie : With (autrement dit en français : « avec »).

Oui, bon, il va changer votre vie, mais comment ?

Eh bien, il va vous arriver de vouloir assigner beaucoup de propriétés à un contrôle ou alors tout simplement définir toutes les composantes d'envoi d'e-mail, de connection réseau, d'impression…

Bon, restons dans le cas basique : j'ai un bouton pour lequel je veux changer la couleur, le texte, la position, la taille…

Avec ce que je vous ai expliqué, vous allez écrire en toute logique ceci :

Me.MonboutonPrefere.ForeColor = Color.Red
Me.MonboutonPrefere.Text = "Mon nouveau texte"
Me.MonboutonPrefere.Left = 10
Me.MonboutonPrefere.Top = 10
Me.MonboutonPrefere.Height = 50
Me.MonboutonPrefere.Width = 50

Bon, avec ce code, votre bouton aurait bien évidemment changé de position, de couleur, de texte, etc.

Mais c'est un peu lourd comme notation, n'est-ce pas ?

Eh bien, le mot With va rendre tout ça plus lisible (enfin, plus lisible, ça dépend des goûts et habitudes de chacun…).

Donc le code ci-dessus avec notre petit With (et son End With respectif) donnerait :

With Me.MonboutonPrefere
            .ForeColor = Color.Red
            .Text = "Mon nouveau texte"
            .Left = 10
            .Top = 10
            .Height = 50
            .Width = 50
        End With

Eh oui, le With a fait disparaître tous les Me.MonBoutonPrefere devant chaque propriété.

Vous pouvez bien sûr assigner des propriétés à d'autres objets que le bouton durant le With. Un MonLabel.Text = "Test" aurait bien sûr été accepté. Mais je ne vous le conseille tout de même pas, le With n'aurait plus son intérêt.

Eh bien, j'espère que ce mot vous aidera ! Bonne chance pour la suite.

• Le Form_Load est désormais appelé lors du chargement du programme.

• Il faut bien veiller à accéder à la bonne propriété de chaque objet. Apprenez à connaître les objets en expérimentant ou en lisant la documentation.

• Le mot-clé With permet de se substituer à l'objet auquel on veut accéder, et ce jusqu'au End With.

Alors, un événement s'écrit comme un Sub ; par exemple, l'évènement form_load :

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

Observez bien sa définition : nous avons tout d'abord le Private Sub (sachez que le private ne nous intéresse pas pour le moment, je l'expliquerai plus tard en annexes). Nous avons donc cette définition que nous connaissons bien, puis le nom du Sub, appelé ici form1_load.

Tout simplement parce que la fenêtre s'appelle form1, et l'événement, load. ;)

Bien sûr, mais je vous conseille de vous habituer à ces noms, ils sont plus pratiques, ce sont ceux que l'assistant (assistant que nous avons utilisé en double-cliquant sur la fenêtre) qui les crée automatiquement.

Continuons, nous avons entre parenthèses les arguments de ce Sub, ces arguments sont indispensables ! Vous ne pouvez pas les supprimer ! Ce sont des arguments que la fenêtre passera automatiquement à ce Sub lorsqu'il sera appelé, ils nous seront inutiles pour le moment, mais plus tard vous en verrez l'utilité.

Handles MyBase.Load

Voilà notre salut ! Cette fin d'instruction avec ce mot-clé : Handles. Ce mot-clé peut se traduire par « écoute », suivi de l'événement écouté. Ici il écoute le chargement de la fenêtre.

Donc si vous avez bien compris, je résume : ce Sub sera pénétré lors du chargement de la fenêtre, et maintenant nous savons pourquoi : un événement attend que le chargement de la fenêtre s'effectue !

Eh bien, attelons-nous de suite à la tâche !

Vous voulez peut-être réagir à d'autres occasions qu'au chargement de cette fenêtre, pourquoi ne pas réagir au clic du bouton ?

Allons-y ! Comme pour générer l'événement form_load, double-cliquons sur notre bouton !

Automatiquement l'IDE me crée :

Private Sub BT_ENVOI_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_ENVOI.Click

End Sub

Comme pour le form_load, plaçons-y les instructions voulues ; fainéant de nature, je déplace simplement celles que nous avions écrites dans le form_load :

Private Sub BT_ENVOI_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_ENVOI.Click
        Me.TXT_RECOIT.Text = "Salut"
        Me.TXT_RECOIT.TextAlign = HorizontalAlignment.Center
End Sub

Testons voir : avant, rien, après le clic, le message s'affiche. Nous avons réussi !

Vous l'aurez compris, le double-clic sur un objet côté design crée son événement le plus courant ; pour un bouton : le clic, pour une textbox : le changement de texte, etc.

Mais pourquoi se limiter à cela puisqu'il existe des dizaines d'événements différents pour chaque objet ?
Allons réagir manuellement à tous ces événements !

Créons donc nos événements !

Enfin modifions-les, plutôt ! Eh oui, je vous l'ai dit, je suis fainéant, pourquoi les créer puisqu'un assistant le fait pour nous ? Enfin, puisqu'il fait la moitié du travail.

Double-cliquons donc sur la fenêtre, l'événement form_load se crée (s'il n'y était pas). Intéressons-nous au Handles, supprimons le .load de la fin, plaçons-nous sur la fin du mot MyBase et écrivons un point (« . »). Voici la liste d'événements de l'objet fenêtre qui s'ouvre, comme à la figure suivante.

Eh bien, choisissons l'événement MouseClick, qui (je pense que vous l'avez compris) se déclenche lors du clic de la souris sur la fenêtre.

Et renommons ce Sub. Eh oui, c'est bien beau d'avoir un nouvel événement, mais il est toujours appelé en tant que form_load, si vous ne changez pas ce nom vous allez très vite ne plus penser qu'il réagit au clic de la souris, prenez donc l'habitude dès maintenant de le renommer. Personnellement pour moi ce sera : form1_MouseClick.

Replaçons maintenant le code que nous avons mis dans l'événement du clic sur le bouton dans ce nouvel événement. Essayons, effectivement lors du clic de la souris sur la fenêtre (pas le bouton) le texte s'affiche ! Encore réussi !

Amusez-vous avec ces événements, essayez-en, soyez amis avec. :p

Nous passons à un mini-TP pour utiliser les événements et ce que nous avons vu précédemment.

Cahier des charges

Bon, voici mes consignes : je voudrais que vous créiez un programme qui va calculer le coût de revient d'un voyage en voiture.

Il prendra en compte :

• La consommation de la voiture (l/100 km) ;

• Le nombre de kilomètres ;

• Le prix de l'essence (en euros).

L'utilisateur entrera ces informations dans des textbox, et l'appui sur un bouton affichera le résultat.

Je ne sais pas quoi vous dire de plus !
Non, n'insistez pas, vous n'aurez pas la fonction qui calcule ce coût, c'est à vous de faire un peu marcher vos méninges, c'est aussi ça la programmation !

Et je veux que ce programme réagisse aussi aux utilisateurs qui s'amusent à entrer n'importe quoi.

Bonne chance !

Correction

J'espère que vous avez trouvé par vous-mêmes, je vous avais tout expliqué ! Bon, je vous montre !

Avant toute chose, regardez la figure suivante. Elle vous montre mon résultat final. À gauche le programme initial, à droite une fois le calcul effectué.

Bon, l'explication des objets : j'ai placé trois textbox, une pour chaque valeur à entrer.
Leurs noms sont respectivement TXT_CONSOMMATION, TXT_NBKM, TXT_PRIXESS.

Puis des labels pour expliquer à quoi elles correspondent. Je n'ai pas donné de noms particuliers aux labels, puisque je n'agirai pas dessus pendant le programme, alors autant laisser comme ils sont.

Ensuite je leur ai attribué une propriété text, pour afficher le texte que vous voyez. Idem pour le titre, sauf que j'ai modifié sa propriété font.size pour le grossir.

Côté bouton, son nom est BT_CALCUL, j'y ai écrit le texte « Calculer ».

Il reste deux labels : un écrit en rouge, qui est là pour les erreurs : j'ai caché ce label en utilisant la propriété visible = false, je ne le ferai apparaître que lors des erreurs.

Le dernier est celui qui contiendra le résultat, j'ai nommé… LBL_COUT.

Voilà pour ce qui est du design, passons au VB !

Public Class Form1

    Private Sub BT_CALCUL_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_CALCUL.Click
        If Verification() Then
            Me.LBL_COUT.Text = "Le cout du voyage sera de " & Calcul(Me.TXT_CONSOMMATION.Text, Me.TXT_NBKM.Text, Me.TXT_PRIXESS.Text) & "?"
        Else
            Me.LBL_ERR.Visible = True
        End If
    End Sub

    ''' <summary>
    ''' Vérifie les trois textbox de la page, regarde si elles sont remplies et si des nombres ont été entrés
    ''' </summary>
    ''' <returns>Vrai si pas d'erreur, faux si une erreur</returns>
    ''' <remarks></remarks>
    Function Verification() As Boolean
        Dim Bon As Boolean = True
        If Me.TXT_CONSOMMATION.Text Is Nothing Or Not IsNumeric(Me.TXT_CONSOMMATION.Text) Then
            Bon = False
        End If
        If Me.TXT_NBKM.Text Is Nothing Or Not IsNumeric(Me.TXT_NBKM.Text) Then
            Bon = False
        End If
        If Me.TXT_PRIXESS.Text Is Nothing Or Not IsNumeric(Me.TXT_PRIXESS.Text) Then
            Bon = False
        End If
        Return Bon
    End Function

    ''' <summary>
    ''' Calcule le prix d'un voyage en fonction de la consommation, du prix de l'essence, et du nombre de kilomètres
    ''' </summary>
    ''' <param name="Consommation">Consommation</param>
    ''' <param name="NbKm">Distance parcourue</param>
    ''' <param name="PrixEss">Prix du kérosène</param>
    ''' <returns>Le coût en double</returns>
    ''' <remarks></remarks>
    Function Calcul(ByVal Consommation As Double, ByVal NbKm As Double, ByVal PrixEss As Double) As Double
        Dim Cout As Double

        Cout = ((NbKm / 100) * Consommation) * PrixEss

        Return Cout
    End Function

End Class

Examinons notre événement : l'appui sur le bouton. Événement que j'ai créé grâce à l'assistant, en double-cliquant dessus.

Dans cet événement, j'utilise ma fonction Verification() ; si le résultat est vrai, j'utilise ma fonction calcul() en lui passant comme arguments les valeurs des trois textbox, et j'écris le résultat sous la forme « Le coût du voyage sera de XXX ».

Si la fonction Verification() renvoie faux, j'affiche le message d'erreur.

Passons donc aux fonctions.
La fonction Verification() : cette fonction est spécifique à ce programme, je ne pourrai pas l'utiliser ailleurs, pourquoi ? Tout simplement parce que j'accède à des objets qui sont sur cette feuille uniquement :

Dim Bon As Boolean = True
If Me.TXT_CONSOMMATION.Text Is Nothing Or Not IsNumeric(Me.TXT_CONSOMMATION.Text) Then
     Bon = False
End If

Ce code crée un booléen à true au début, il vérifie si le texte entré is nothing, donc est nul, ou not isnumeric(), donc n'est pas un numérique.

Si l'une de ces deux conditions est vérfiée (autrement dit crée une erreur lors de l'entrée des caractères), le booléen passe à false. Ce booléen est finalement retourné.

Passons à la fonction calcul(), fonction qui effectue uniquement le calcul nécessaire, cette fonction pourra être réutilisée puisqu'elle a une forme universelle. Je m'explique : on lui passe les valeurs nécessaire et elle effectue le calcul, ce n'est pas elle qui va chercher les valeurs dans les textbox, donc on peut l'utiliser pour lui donner d'autres valeurs.

Voici la ligne essentielle :

Cout = ((NbKm / 100) * Consommation) * PrixEss

Eh bien, parce que le type integer ne prend pas en compte les virgules et donc dans un programme comme celui-ci le double est nécessaire.

Voilà, j'espère que ce TP n'était pas trop dur !

Si vous n'avez pas le même code que moi, pas de panique ! Il y a une infinité de possibilités pour arriver au même résultat sans faire les mêmes choses.

Vous pourriez faire évoluer ce programme, par exemple :

• Gérer un message d'erreur pour chaque textbox ;

• Personnaliser le message d'erreur (vide ou mauvaise valeur) ;

• Créer un bouton « Effacer » qui remet à 0 toutes les valeurs et cache les messages d'erreur.

Dites-vous que ce programme est déjà très bien, il vous apprend à interagir avec les contrôles, utiliser les fonctions, arguments, retours et réactions à une possible erreur. Vous avancez vite !

• Le mot-clé Handles permet d'écouter les événements.

• Les événements peuvent être écoutés sur des objets différents : fenêtre principale, composant graphique, pointeur de souris, etc.

• Chaque événement écouté appelle une fonction.

Créons d'abord un nouveau projet (gardez le TP « voyage en voiture » dans un coin, ça pourrait toujours vous servir :p ), qui va ressembler à la figure suivante.

Je vous donne les noms des composants que j'ai utilisés :

• Les checkbox (à gauche) :

  • CHK_1

  • CHK_2

  • CHK_4

  • CHK_8

• Les boutons radio (au centre) :

  • RB_1

  • RB_2

  • RB_3

  • RB_4

• Les boutons radio (à droite) :

  • RB_ROUGE

  • RB_VERT

  • RB_BLEU

  • RB_JAUNE

• Bouton BT_1

• Bouton BT_2

• Bouton BT_3

• Textbox TXT_CHK

• Textbox TXT_RBNB

• Textbox TXT_RBCOL

Vous n'êtes évidemment pas obligés de travailler avec les mêmes noms que moi, mais je vous le conseille, ce sera plus facile pour vous de vous y retrouver.

Si vous testez ce petit programme, vous pouvez cliquer sur les cases, elles s'allument bien ; seulement, problème du côté des boutons radio : cliquer sur n'importe lequel d'entre eux en décoche un autre même si ce dernier n'est pas dans la même colonne… Eh oui, l'IDE n'est pas intelligent, il ne sait pas ce que nous voulons faire.

Comment faire ?

Eh bien, retournez sur votre IDE et cherchez le contrôle groupbox. Entourez grâce à deux groupbox vos deux colonnes de boutons radio, et allez dans les propriétés des deux groupbox que vous venez de créer pour retirer le texte qu'elles contiennent : elles seront invisibles.

Une fois cela fait, retestez le programme. Vous devriez obtenir la figure suivante.

On peut sélectionner un bouton dans chaque colonne. :)

Bon, le côté design fonctionne, on va passer à l'accès aux propriétés.

Allons donc du côté du code VB en double-cliquant sur BT_1, ce qui créera notre événement de clic sur le bouton.

Dans cet événement je vais vous demander de faire la somme des checkbox cochées. Donc la propriété qui régit l'état d'une checkbox est…

Checked ! (siii !)

Bon, écrivons donc ce code…

Me.CHK_1.Checked

… pour récupérer l'état de la première checkbox. Cette propriété est définie par true ou false. C'est donc un booléen, vous avez dû vous en rendre compte lorsque vous avez inscrit cette ligne, l'IDE vous a affiché une infobulle.

Nous allons donc facilement pouvoir faire une boucle if :

if Me.CHK_1.Checked then

Cette boucle sera pénétrée si la case 1 est cochée.

Donc, vous avez toutes les cartes en main. Écrivez dans la textbox TXT_CHK la somme des cases cochées.

Private Sub BT_1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_1.Click
        Dim Somme As Integer = 0
        If Me.CHK_1.Checked Then
            Somme = Somme + 1
        End If
        If Me.CHK_2.Checked Then
            Somme = Somme + 2
        End If
        If Me.CHK_4.Checked Then
            Somme = Somme + 4
        End If
        If Me.CHK_8.Checked Then
            Somme = Somme + 8
        End If
        Me.TXT_CHK.Text = Somme
    End Sub

Et voilà le code permettant de faire cela.

Ce n'était pas sorcier !

Alors, à vos claviers ! Écrivez dans la seconde textbox quel bouton a été coché et dans la dernière la couleur sélectionnée !

Je vous laisse quand même réfléchir !

Solution

Public Class Form1

    Private Sub BT_1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_1.Click
        Dim Somme As Integer = 0
        If Me.CHK_1.Checked Then
            Somme = Somme + 1
        End If
        If Me.CHK_2.Checked Then
            Somme = Somme + 2
        End If
        If Me.CHK_4.Checked Then
            Somme = Somme + 4
        End If
        If Me.CHK_8.Checked Then
            Somme = Somme + 8
        End If
        Me.TXT_CHK.Text = Somme
    End Sub

    Private Sub BT_2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_2.Click
        If Me.RB_1.Checked Then
            Me.TXT_RBNB.Text = Me.RB_1.Text
        End If
        If Me.RB_2.Checked Then
            Me.TXT_RBNB.Text = Me.RB_2.Text
        End If
        If Me.RB_3.Checked Then
            Me.TXT_RBNB.Text = Me.RB_3.Text
        End If
        If Me.RB_4.Checked Then
            Me.TXT_RBNB.Text = Me.RB_4.Text
        End If
    End Sub

    Private Sub BT_3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_3.Click
        If Me.RB_BLEU.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_BLEU.Text
            Me.BackColor = Color.Blue
        End If
        If Me.RB_JAUNE.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_JAUNE.Text
            Me.BackColor = Color.Yellow
        End If
        If Me.RB_ROUGE.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_ROUGE.Text
            Me.BackColor = Color.Red
        End If
        If Me.RB_VERT.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_VERT.Text
            Me.BackColor = Color.Green
        End If
    End Sub
End Class

Ce code est lourd puisqu'il vérifie toutes les checkbox une par une… De plus, je n'ai mis aucun commentaire. Mais bon il fonctionne et vous avez réussi à accéder et réagir aux checkbox et boutons radio. Essayez donc de le simplifier à coup de IIF !

Petit plus : la couleur (voir figure suivante). Vous auriez dû vous douter que je ne mettais pas des couleurs juste comme ça >_ , et la propriété, vous auriez pu la trouver par vous-mêmes !

Private Sub BT_3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_3.Click
        If Me.RB_BLEU.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_BLEU.Text
            Me.BackColor = Color.Blue
        End If
        If Me.RB_JAUNE.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_JAUNE.Text
            Me.BackColor = Color.Yellow
        End If
        If Me.RB_ROUGE.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_ROUGE.Text
            Me.BackColor = Color.Red
        End If
        If Me.RB_VERT.Checked Then
            Me.TXT_RBCOL.Text = Me.RB_VERT.Text
            Me.BackColor = Color.Green
        End If
    End Sub

Et l'IDE vous donne automatiquement la liste des couleurs disponibles quand vous écrivez le signe égal « = », il faut juste connaître les noms anglais.

Bon, vous savez désormais accéder aux checkbox et aux boutons radio, et les utiliser !

Bon, attaquons les combobox (aussi appelées DropDownList), que vous retrouvez souvent. Il s'agit de boîtes déroulantes. Nous allons apprendre à les remplir et à réagir avec.

Créez donc la fenêtre visible à la figure suivante : une combobox nommée CB_CHOIX, et une textbox appelée TXT_CHOIX.

Cette fois, au lieu d'utiliser un bouton pour déclencher l'événement, nous allons utiliser l'événement propre de la combobox. Cet événement se déclenche lors du changement de sélection.

Tout d'abord il faut attribuer des valeurs à la combobox, deux choix s'offrent à nous : la manuelle (en dur dans le code) ou l'automatique (grâce à l'assistant de l'IDE). Je vais d'abord vous expliquer l'automatique, puis la manuelle qui offre beaucoup plus de possibilités.

Méthode assistée

Lors du clic sur la combobox (dans l'IDE), elle apparaît sélectionnée et une petite flèche apparaît en haut à droite de cette sélection, comme à la figure suivante.

Cliquez maintenant sur Modifier les éléments pour lui en attribuer.

Méthode manuelle

La seconde méthode nous amène côté VB, double-cliquez sur la fenêtre pour créer l'événement onload.

Une technique est de créer un tableau contenant les valeurs et de « lier » ce tableau à la combobox : créons tout d'abord notre tableau…

Dim MonTableau(9) As Integer
 For i As Integer = 0 To 9
     MonTableau(i) = i + 1
 Next

… rempli ici avec des valeurs allant de 1 à 10.

L'instruction pour lier cette combobox (également valable pour les listbox et autres) est :

Me.CB_CHOIX.DataSource = MonTableau

Donc si l'on écrit tout ça dans le Main(), on obtient une liste déroulante avec des nombres allant de 1 à 10.

Nous allons écrire la valeur récupérée dans la textbox lors du changement de choix dans la combobox, la propriété utilisée pour récupérer la valeur sélectionnée est SelectedValue (je vous laisse faire cette modification).

Private Sub CB_CHOIX_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CB_CHOIX.SelectedIndexChanged
        Me.TXT_CHOIX.Text = Me.CB_CHOIX.SelectedValue
    End Sub

Et voilà !

Après le test, nous voyons que tout fonctionne, nous avons réussi à accéder à une combobox et à la remplir !

Bon, pour vérifier vos connaissances sur les accès aux propriétés et l'utilisation de nouveaux contrôles, je vais vous demander de réaliser un petit programme contenant une progressbar et une trackbar.

Le déplacement de la trackbar par l'utilisateur se répercutera sur le remplissage de la progressbar : si la trackbar est au milieu, la progressbar aussi.

Ce petit TP vous apprendra a trouver par vous-mêmes les propriétés utiles des contrôles. Il va falloir se faire à cette pratique, c'est 50 % du travail d'un développeur : trouver comment faire ce qu'il souhaite sans que personne ne lui montre. Ne vous inquiétez pas, l'IDE vous expliquera l'utilité de chaque propriété.

Bonne chance !

Résultat

La figure suivante vous montre le résultat.

Alors, une seule ligne côté VB à ajouter dans l'événement de la trackbar :

Private Sub TKB_IN_Scroll(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TKB_IN.Scroll
        Me.PGB_OUT.Value = Me.TKB_IN.Value
    End Sub

Eh oui ! La propriété à utiliser était value. Vous avez dû avoir des surprises aux premiers tests, du genre la progressbar ne va pas jusqu'au bout alors que le trackbar y est…

Alors, comment résoudre ce problème, pour ceux qui n'ont pas trouvé ?

Eh bien regardez un peu du côté de la propriété Maximum de ces deux contrôles. Si elle n'est pas la même, ça risque de ne pas aller. ^^ Autre chose : je vous conseille de mettre la tickfrequency (autrement dit, le pas) de la trackbar à 0, plus de « tirets » et donc la progressbar est mise à jour en temps réel.

Eh bien, pas trop dur ! :p

• Les checkbox sont utiles pour les choix multiples.

• Les boutons radio permettent un choix unique dans une liste.

• Les combobox sont utiles pour choisir une valeur dans une liste déroulante.

Créons notre premier timer : double-cliquons donc sur son contrôle pour le voir se placer en bas de notre fenêtre design. Essayez de construire le reste de l'application comme à la figure suivante.

Donc, nous avons deux boutons : un « Démarrer » nommé BT_DEMAR, un « RAZ » nommé… BT_RAZ. Une progressbar : PGB_TIM, et un timer (non visible à l'image) nommé TIM_TIM.

J'explique ce que notre programme va faire : lors de l'appui sur le bouton « Démarrer », la progressbar va progresser jusqu'au bout de manière linéaire et à une certaine vitesse. À l'appui sur RAZ, elle va retourner à 0.

Le timer contient deux propriétés essentielles : enabled, comme pour tous les autres contrôles, détermine s'il est activé ou non, et la propriété interval (ce n'est pas une marque de cigarettes, non) détermine l'intervalle entre deux actions du timer(exprimée en ms).

Mettons donc pour ce TP 20 ms d'intervalle.

À chaque fois que ce temps sera écoulé, l'événement du timer, nommé tick, se déclenchera. Pour créer cet événement sur l'assistant, double-cliquez sur le timer, en bas. Faites de même pour les événements des deux boutons.

Nous avons donc créé trois événements dans notre code : le timer et les deux boutons.

Je pense que vous êtes capables de faire cet exercice seuls, avec tout ce que vous savez, mais je vais quand même vous le corriger.

Public Class Form1
    Private Sub BT_DEMAR_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_DEMAR.Click
        'Si le bouton « Démarrer » est enfoncé, on active le timer, on désactive ce bouton et on active RAZ
        Me.TIM_TIM.Enabled = True
        Me.BT_DEMAR.Enabled = False
        Me.BT_RAZ.Enabled = True
    End Sub

    Private Sub TIM_TIM_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TIM_TIM.Tick
        'Si la progressbar est arrivée au bout, on désactive le timer, on réactive le bouton « Démarrer »
        If Me.PGB_TIM.Value = 100 Then
            Me.TIM_TIM.Enabled = False
            Me.BT_DEMAR.Enabled = True
        Else
            'Augmente de 1 la progressbar
            Me.PGB_TIM.Value = Me.PGB_TIM.Value + 1
        End If
    End Sub

    Private Sub BT_RAZ_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_RAZ.Click
        'Si le bouton « RAZ » est enfoncé, on remet la progressbar à 0, on désactive le timer, 
        'on active le bouton « Démarrer » et on désactive le bouton « RAZ »
        Me.PGB_TIM.Value = 0
        Me.TIM_TIM.Enabled = False
        Me.BT_DEMAR.Enabled = True
        Me.BT_RAZ.Enabled = False
    End Sub
End Class

J'ai fait l'effort de commenter le code pour une fois. :p

Bon, je pense que ce n'était pas si dur que cela, vous voyez que je me sers de l'événement du timer, donc déclenché toutes les 20 ms dans notre cas pour ajouter 1 à la value de la progressbar. Si la value arrive à 100, on l'arrête.

Je pense que vous avez compris que si je diminue l'intervalle la progressbar avancera plus vite.

Petit TP : la banderole lumineuse ! Je sais, le nom n'est pas très imaginatif…

Le but de ce TP va être d'allumer différents boutons radio (une dizaine) au rythme du timer, les faire défiler en gros. J'ai pris des boutons radio et pas des checkbox, parce que les boutons radio n'ont pas besoin d'être décochés, ils le sont automatiquement lorsqu'un autre est coché.

Donc un bouton « Démarrer la banderole » et « Arrêter la banderole » seront nécessaires.

Et petit plus pour les rapides : une barre pour faire varier la vitesse de ce défilement.

Attention, ce TP n'est pas aussi facile qu'il en a l'air !
Essayez de trouver une méthode pour pouvoir gérer aussi bien 10 boutons que 50.

Petite astuce : il va falloir faire un tableau… mais de quoi ? That's the question.

À vos claviers !

Solution

Mon programme ressemble à la figure suivante.

Il y a bien les 10 boutons radio.

Maintenant le code :

Public Class Form1
    Private Sub TIM_TIM_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TIM_TIM.Tick
        Dim Tourne As Boolean = True
        Dim Bouton As Integer = 0

        'Rassemble tous les boutons radio dans un tableau
        Dim RB(9) As RadioButton
        RB(0) = Me.RB_1
        RB(1) = Me.RB_2
        RB(2) = Me.RB_3
        RB(3) = Me.RB_4
        RB(4) = Me.RB_5
        RB(5) = Me.RB_6
        RB(6) = Me.RB_7
        RB(7) = Me.RB_8
        RB(8) = Me.RB_9
        RB(9) = Me.RB_10

        While Tourne
            'Si on est arrivé au bout du tableau, on sort de cette boucle
            If Bouton = 10 Then
                Tourne = False
            Else
                'Si le bouton actuellement parcouru est activé
                If RB(Bouton).Checked Then
                    'Et si ce n'est pas le dernier
                    If RB(Bouton) IsNot RB(9) Then
                        'on active celui d’après et on sort de la boucle
                        RB(Bouton + 1).Checked = True
                        Tourne = False
                    Else
                        'Sinon on reprend au premier
                        Me.RB_1.Checked = True
                    End If
                End If
                'On incrémente le compteur
                Bouton = Bouton + 1
            End If
        End While
    End Sub

    Private Sub BT_PLAY_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_PLAY.Click
        Me.TIM_TIM.Enabled = True
        Me.TIM_TIM.Interval = 501 - Me.TKB_VIT.Value * 50
    End Sub

    Private Sub BT_STOP_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_STOP.Click
        Me.TIM_TIM.Enabled = False
    End Sub

    Private Sub TKB_VIT_Scroll(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TKB_VIT.Scroll
        Me.TIM_TIM.Interval = 501 - Me.TKB_VIT.Value * 50
    End Sub
End Class

Alors je vais expliquer le principal :

Vous voyez que dans l'événement tick du timer j'ai créé un tableau, mais ce n'est pas un tableau de string ou de integer, non c'est un tableau de… boutons radio (Dim RB(9) As RadioButton) !

C'est pour ça que j'ai dit que ce TP était difficile, en cherchant un peu vous auriez pu avoir l'idée, ensuite la mettre en pratique aurait été faisable…

Bon, ce n'est pas grave, vous le saurez maintenant. Donc ce tableau de boutons radio, je le remplis avec mes boutons !

Et donc si vous avez compris, la boucle en dessous est un petit algorithme qui parcourt ces boutons et qui retourne au premier une fois arrivé au dernier.

Passons maintenant au changement de vitesse : Me.TIM_TIM.Interval = 501 - Me.TKB_VIT.Value * 50. Mais pourquoi ? Tout d'abord ma progressbar a un Minimum de 1 et un Maximum de 10.
Donc, à 1 : 501 - 1 * 50 = 451 et à 10 : 501 - 10 * 50 = 1.

La vitesse change donc bien en fonction de cette barre.

Parce que 500 - 10 * 50 = 0, et l'interval d'un timer ne doit jamais être égal à 0 !

Pour finir ce chapitre, je tiens à dire que l'amélioration de ce TP peut être effectuée en de multiples points. Tout d'abord, le code lors du Tick du timer est beaucoup trop lourd, il faut au contraire qu'il soit le plus petit possible pour ne pas demander trop de mémoire au processeur. Donc les déclarations sont à effectuer au Load.
Et profitez-en pour factoriser ce petit algorithme qui fait défiler les boutons radio. ;)

• Les timers nous permettent de déclencher des événements en fonction du temps.

• L’événement appelé à chaque fois que le timer est écoulé est Tick.

• Le temps entre chaque Tick est défini avec la propriété Interval.

Vous devez voir dans votre boîte à outils un sous-menu Menus et barres d'outils, semblable à la figure suivante. Comme vous pouvez le constater, ces objets nous permettront de créer : des menus (1), une barre d'outils (2), une barre de statut (3) et un menu contextuel (4) (menu que vous voyez s'afficher lors du clic droit sur la souris).

Passons tout de suite au menu le plus intéressant : la barre de menus (1) !

Création graphique

Comme je vous l'ai dit, L'IDE va grandement nous mâcher le travail : un assistant est fourni avec pour créer ces menus. Prenez l'objet MenuStrip et insérez-le sur votre feuille (feuille vide de préférence), comme à la figure suivante.

Vous voyez donc que ce menu se place automatiquement en haut de votre feuille. Vous ne le voulez pas en haut ? Vous êtes pénibles ! Pas de problème, une propriété permet de choisir la position dans la feuille de ce menu (gauche, droite, etc.), ou un superbe objet : le ToolStripContainer.

Cette propriété est Dock, et comme notre IDE est gentil, il nous offre la possibilité de paramétrer cette propriété en cliquant sur la petite flèche en haut à droite de notre menu, comme à la figure suivante.

Bon, passons au remplissage de ce menu !

Comme vous le voyez, lorsqu'il est sélectionné, le menu vous affiche un petit « Tapez ici » (non, ne sortez pas votre marteau !), comme quoi c'est on ne peut plus facile !

La première « ligne » correspond aux menus principaux (comme Fichier, Édition…). Écrivez donc le nom de votre premier menu (pour moi ce sera Fichier :p ). Vous devez voir lors de l'écriture de ce premier menu deux cases supplémentaires (qui sont également masochistes apparemment), celle du dessous correspond au premier sous-menu de notre premier menu (Fichier -> Nouveau par exemple), la seconde est celle qui nous permet de créer un second menu.

Ne grillons pas les étapes, remplissons déjà notre premier menu !

Pour moi ce sera Reset, et celui en dessous, Quitter.

Eh bien, ces cases permettent de créer des sous-menus qui vous offrent plusieurs choix.

Comme vous allez le voir, la possibilité de créer notre menu entièrement personnalisé est bien réelle !

Bon, je crée un second menu (voir figure suivante), faites de même.

Puis, pour finir un petit label au centre de la feuille : LBL_TEXTE.

Événements

Maintenant, attaquons la gestion des événements !

Ces événements seront créés grâce à l'assistant Visual Studio comme le clic sur un bouton : un double-clic sur le sous-menu que vous voulez gérer, le code s'ajoute automatiquement :

Private Sub BonjourToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BonjourToolStripMenuItem.Click

End Sub

Faites cela pour tous les sous-menus (sinon à quoi ça sert de les créer :p ).

Oui bien sûr, si vous en trouvez l'utilité !

Bon, voilà donc le code dûment rempli :

Public Class Form1

    Private Sub ResetToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ResetToolStripMenuItem.Click
        Me.LBL_TEXTE.Text = ""
    End Sub

    Private Sub QuitterToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles QuitterToolStripMenuItem.Click
        End
    End Sub

    Private Sub BonjourToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BonjourToolStripMenuItem.Click
        Me.LBL_TEXTE.Text = "Bonjour !"
    End Sub

    Private Sub AuRevoirToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles AuRevoirToolStripMenuItem.Click
        Me.LBL_TEXTE.Text = "Au revoir."
    End Sub

    Private Sub CiaoToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CiaoToolStripMenuItem.Click
        Me.LBL_TEXTE.Text = "Ciao."
    End Sub

    Private Sub ByeByeToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ByeByeToolStripMenuItem.Click
        Me.LBL_TEXTE.Text = "Bye bye."
    End Sub

    Private Sub AstalavistaBabyToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles AstalavistaBabyToolStripMenuItem.Click
        Me.LBL_TEXTE.Text = "Astalavista baby !"
    End Sub

End Class

Eh oui, tant de lignes pour si peu ! Je pense que vous avez compris l'utilité ce que doit faire le programme : lors du clic sur un sous-menu de Afficher, il affiche ce texte, lors du clic sur Reset, il efface, et lors du clic sur Quitter, il quitte le programme (le End effectuant cette action).

Bon, vous vous souvenez des MsgBox ?

Eh bien, elles vont nous être utiles ici : nous allons mettre une confirmation de sortie du programme.

Je pense que vous êtes capables de le faire par vous-mêmes, mais bon, je suis trop aimable :

If MsgBox("Souhaitez-vous vraiment quitter ce magnifique programme ?", 36, "Quitter") = MsgBoxResult.Yes Then
   End
End If

Vous ne vous en souvenez pas ? Je vous redonne le tableau :

Et voilà votre programme qui affiche ce que vous voulez et qui vous demande une confirmation de fermeture, comme le montre la figure suivante.

Je viens de vous montrer un menu classique avec du texte comme contrôle, mais vous en voulez sûrement plus. Eh bien, c'est parti : nous allons créer des combobox (listes déroulantes) et des textbox.

Eh bien oui ! Vous ne devez pas en voir souvent, mais ça peut être utile !

Donc, pour avoir accès à ces contrôles supplémentaires, il faut cliquer sur la petite flèche disponible à côté du « Tapez ici » (voir figure suivante).

Vous voyez que s'offrent à vous les contrôles tant désirés ! Eh bien, personnalisons un peu notre menu pour arriver à la figure suivante.

Sachant que dans la combobox Message prédéfini j'ai remis les messages d'avant (vous devez vous servir de la propriété collection de cette combobox, du côté design, pour en assigner les choix ou alors passer par le code VB, au choix).

Schématiquement :

• Fichier

  • Reset

  • Quitter

• Affichage

  • Message prédéfini

    • Combobox

      • Bonjour !

      • Au revoir.

      • Ciao.

      • Bye bye.

      • Astalavista baby !

  • Message personnalisé

    • Textbox

    • Écrire

Ce qui est assez gênant avec cet assistant, c'est que les noms qui sont entrés automatiquement sont assez coton à repérer ; avec une textbox, une combobox, ça passe, mais au-delà, aïe ! Alors prenez l'habitude de les renommer : un tour sur les propriétés et on change : CB_MENU et TXT_MENU.

Bon, ensuite on utilise notre fidèle assistant pour créer les événements correspondants : sur le clic du bouton Écrire et lors du changement de la combobox.

Si vous avez utilisé l'assistant pour créer l'événement de la combobox, lorsqu'elle est dans un menu, l'événement est le Clic, il faut le changer :

Private Sub CB_MENU_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CB_MENU.SelectedIndexChanged

Supprimez les événements relatifs aux anciens sous-menus (Bonjour…), mais gardez ceux correspondant aux sous-menus Reset et Quitter.

Écrivons maintenant notre code : côté combobox, on veut afficher le texte correspondant à l'item de la combobox (je vous ai donné la solution là :p ), eh oui, l'événement SelectedItem sera utilisé, le SelectedValue n'étant pas disponible dans cette façon d'utiliser la combobox.

Ce qui nous donne :

Private Sub CB_MENU_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CB_MENU.SelectedIndexChanged
        Me.LBL_TEXTE.Text = Me.CB_MENU.SelectedItem
    End Sub

Bon, pour notre bouton Écrire, ce n'est pas sorcier : on récupère la valeur de la textbox et on l'affiche ; voilà le tout :

Public Class Form1

    Private Sub ResetToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ResetToolStripMenuItem.Click
        'Efface le label
        Me.LBL_TEXTE.Text = ""
    End Sub

    Private Sub QuitterToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles QuitterToolStripMenuItem.Click
        'Fermeture avec confirmation
        If MsgBox("Souhaitez-vous vraiment quitter ce magnifique programme ?", 36, "Quitter") = MsgBoxResult.Yes Then
            End
        End If
    End Sub

    Private Sub CB_MENU_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CB_MENU.SelectedIndexChanged
        'Écrit le texte de la combobox lors du changement d'index
        Me.LBL_TEXTE.Text = Me.CB_MENU.SelectedItem
    End Sub

    Private Sub EcrireToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles EcrireToolStripMenuItem.Click
        'Écrit le texte de la textbox lors de l'appui sur « Écrire »
        Me.LBL_TEXTE.Text = Me.TXT_MENU.Text
    End Sub
End Class

Et voici le rendu final à la figure suivante.

Comme vous voyez, le VB est assez facile à utiliser dans différentes situations puisque les propriétés ne changent pas. Bon, maintenant que vous savez ça, on ne se repose pas sur ses lauriers, on avance. ^^

Au tour de la barre de statut. Il s'agit de la barre qui vous indique… le statut de l'application. À quoi va nous servir cette barre ? Eh bien à afficher le statut de votre application par exemple, ou alors tout simplement à mettre des boutons dessus ! :p Je vais vous montrer une manière d'utiliser à bon escient cette barre, après, à vous de faire ce que vous voulez et de trifouiller toutes ses propriétés !

Créons déjà ladite barre : toujours dans le menu Menus et barres d'outils, vous choisissez StatusStrip. Vous l'intégrez à la feuille, elle se place en bas (normal), vous pouvez changer en agissant encore une fois sur la propriété Dock. Ajoutez deux contrôles : un label et une progressbar. La progressbar est accessible, comme pour la combobox de la partie précédente, avec la petite flèche. Renommez-les : LBL_STATUT, PGB_STATUT.

Nous allons nous servir de la progressbar comme indication d'avancement. Évidemment, ici, afficher un label n'est pas sorcier, notre ordinateur ne va pas réfléchir plus d'une milliseconde (oui, même sous Windows 3.1). Nous allons donc simuler une pause.

Recréons donc un petit timer pour simuler le temps d'attente (TIM_STATUT) et utilisons le même procédé que lors du chapitre sur les timers. Nous allons donc faire progresser la barre et afficher dans le label le statut. C'est un exercice que vous pouvez évidemment faire.

Voici donc une solution :

Public Class Form1

    Private Sub ResetToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ResetToolStripMenuItem.Click
        'Efface le label
        PauseFactice()
        Me.LBL_TEXTE.Text = ""

    End Sub

    Private Sub QuitterToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles QuitterToolStripMenuItem.Click
        'Fermeture avec confirmation
        If MsgBox("Souhaitez-vous vraiment quitter ce magnifique programme ?", 36, "Quitter") = MsgBoxResult.Yes Then
            End
        End If
    End Sub

    Private Sub CB_MENU_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CB_MENU.SelectedIndexChanged
        'Écrit le texte de la combobox lors du changement d'index
        PauseFactice()
        Me.LBL_TEXTE.Text = Me.CB_MENU.SelectedItem

    End Sub

    Private Sub EcrireToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles EcrireToolStripMenuItem.Click
        'Écrit le texte de la textbox lors de l'appui sur « Écrire »
        PauseFactice()
        Me.LBL_TEXTE.Text = Me.TXT_MENU.Text

    End Sub

    Private Sub PauseFactice()
        LBL_STATUT.Text = "Chargement ..."
        PGB_STATUT.Value = 0
        TIM_STATUT.Enabled = True
    End Sub

    Private Sub TIM_STATUT_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TIM_STATUT.Tick
        'Si la progressbar est arrivée au bout, on désactive le timer
        If Me.PGB_STATUT.Value = 100 Then
            Me.TIM_STATUT.Enabled = False
            LBL_STATUT.Text = "Prêt"
        Else
            'Augmente de 1 la progressbar
            Me.PGB_STATUT.Value = Me.PGB_STATUT.Value + 1
        End If
    End Sub

End Class

Bon, pour ce code, je ne me suis pas trop fatigué : j'ai copié le code du chapitre sur les timers. La « pause » n'est pas effectuée donc le texte s'affiche pendant la progression. C'est un exemple, vous pourrez utiliser les barres de chargement en situation réelle plus tard. L'idéal aurait été de placer un sémaphore (un flag), le tout avec une boucle While. Le rendu se trouve à la figure suivante.

Alors ce code n'est pas dur à comprendre : j'ai mélangé le code de progression avec le code existant, en ajoutant des repères grâce au label : le « Chargement…» et le « Prêt ». Comme d'habitude, essayez de modifier ce code pour le rendre plus efficace et comme vous le souhaitez.

Alors, le menu contextuel est, comme je vous l'ai expliqué, le menu visible lors du clic droit. Nous allons créer un contextmenu, toujours dans la suite de notre programme qui va déplacer le label qui nous sert à afficher le texte.

Donc, toujours dans le menu de la boîte à outils : Menus et barres d'outils, vous prenez le ContextMenuStrip et vous l'intégrez à la feuille. Une fois cela fait, créez un élément contenant le texte : « Déplacer le label ici ». Ensuite, comme à l'accoutumée, on crée son événement correspondant. Dans cet événement, nous allons récupérer la position du curseur et changer la propriété location du label :

Me.LBL_TEXTE.Location = Control.MousePosition

Control.MousePosition est la propriété de position de la souris (Control). Eh oui, même la souris a des propriétés, vous en rêviez, n'est-ce pas ?

Et donc voilà, une fois tout le code bien agencé :

Public Class Form1

    Private Sub ResetToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ResetToolStripMenuItem.Click
        'Efface le label
        PauseFactice()
        Me.LBL_TEXTE.Text = ""

    End Sub

    Private Sub QuitterToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles QuitterToolStripMenuItem.Click
        'Fermeture avec confirmation
        If MsgBox("Souhaitez-vous vraiment quitter ce magnifique programme ?", 36, "Quitter") = MsgBoxResult.Yes Then
            End
        End If
    End Sub

    Private Sub CB_MENU_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CB_MENU.SelectedIndexChanged
        'Écrit le texte de la combobox lors du changement d'index
        PauseFactice()
        Me.LBL_TEXTE.Text = Me.CB_MENU.SelectedItem

    End Sub

    Private Sub EcrireToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles EcrireToolStripMenuItem.Click
        'Écrit le texte de la textbox lors de l'appui sur « Écrire »
        PauseFactice()
        Me.LBL_TEXTE.Text = Me.TXT_MENU.Text

    End Sub

    Private Sub PauseFactice()
        LBL_STATUT.Text = "Chargement ..."
        PGB_STATUT.Value = 0
        TIM_STATUT.Enabled = True
    End Sub

    Private Sub TIM_STATUT_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TIM_STATUT.Tick
        'Si la progressbar est arrivée au bout, on désactive le timer
        If Me.PGB_STATUT.Value = 100 Then
            Me.TIM_STATUT.Enabled = False
            LBL_STATUT.Text = "Prêt"
        Else
            'Augmente de 1 la progressbar
            Me.PGB_STATUT.Value = Me.PGB_STATUT.Value + 1
        End If
    End Sub

    Private Sub DéplacerLeLabelIciToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles DéplacerLeLabelIciToolStripMenuItem.Click
        'lors d'un clic droit et du choix de déplacement du label, on place le label aux positions de la souris.
        Me.LBL_TEXTE.Location = Control.MousePosition
    End Sub
End Class

Lors d'un clic et de la sélection, le label bouge. Ce programme était là pour vous montrer les utilisations des différents menus, il est bien évidemment inutile (donc indispensable) !

• Il existe des menus contextuels, des barres de menus, des barres d'outils…

• Le menu contextuel apparaît lors du clic droit de la souris.

• Les menus sont réservés aux applications volumineuses et nécessitant une grande interaction avec l'utilisateur.

Vous allez voir, avec ce que j'ai expliqué jusqu'à maintenant, vous allez pouvoir faire quelque chose de sympa, que nous améliorerons plus tard !

Mais avant toute chose, voici un contrôle qui va nous être indispensable pendant ce TP : WebBrowser. Pour ceux qui sont nuls en anglais, ça veut dire « navigateur web ». Ce contrôle va nous permettre de créer notre navigateur : vous lui entrez une adresse et il affiche ce qu'il y a dans la page. Il utilise le même moteur web qu'Internet Explorer. Le menu contextuel est déjà géré par ce contrôle ainsi que le téléchargement de fichiers. Vous l'avez compris, nous allons créer l'interface.

WebBrowser est disponible dans les « contrôles communs ». Pour ce qui est des propriétés à utiliser pour naviguer, etc., eh bien à vous de trouver !

Ce ne sera pas sorcier, vous avez l'IDE qui vous affiche la liste des fonctions et propriétés disponibles sur le contrôle, après à vous de trouver celle qui sera à utiliser et de chercher comment l'utiliser en suivant la syntaxe donnée.

Il va falloir chercher un peu, c'est sûr, mais vous devrez le faire pour vos propres programmes, alors autant commencer tout de suite.

Pour ce qui est de l'interface, nous allons commencer doucement, je ne vais pas vous demander l'impossible : une barre d'adresse avec son bouton « Envoyer », « Précédent », « Suivant » , « Arrêter », « Rafraîchir », le statut de la page (terminé, en chargement, etc.), le menu « Fichier », et « Quitter ».

Un dernier conseil : la méthode URL du WebBrowser sera sûrement utile. :p Bonne chance !

J'espère que vous avez passé au moins quelques minutes à chercher. Nous allons progresser ensemble, voici donc mes premières ébauches, ce que je vous ai demandé de faire :

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Les deux lignes suivantes peuvent être remplacées par Me.WB_NAVIGATEUR.Navigate("http://www.google.fr")
        Me.TXT_ADRESSE.Text = "http://www.google.fr"
        'Simule un clic en passant comme argument nothing (null)
        Me.BT_ADRESSE_Click(Nothing, Nothing)

        'Au démarrage, pas de possibilité de « Précédent »,  « Suivant », « Stop »
        Me.BT_SUIVANT.Enabled = False
        Me.BT_PRECEDENT.Enabled = False
        Me.BT_STOP.Enabled = False
    End Sub

    'Lorsque le chargement est fini
    Private Sub WB_NAVIGATEUR_DocumentCompleted(ByVal sender As System.Object, ByVal e As System.Windows.Forms.WebBrowserDocumentCompletedEventArgs) Handles WB_NAVIGATEUR.DocumentCompleted
        'Affiche le nouveau statut, désactive le bouton « Stop »
        Me.LBL_STATUT.Text = WB_NAVIGATEUR.StatusText
        Me.BT_STOP.Enabled = False
        'On récupère l'adresse de la page et on l'affiche
        Me.TXT_ADRESSE.Text = Me.WB_NAVIGATEUR.Url.ToString
    End Sub

    'Lorsque le chargement commence
    Private Sub WB_NAVIGATEUR_Navigating(ByVal sender As System.Object, ByVal e As System.Windows.Forms.WebBrowserNavigatingEventArgs) Handles WB_NAVIGATEUR.Navigating
        'On active le bouton « Stop »
        Me.BT_STOP.Enabled = True
        'On met le statut à jour
        Me.LBL_STATUT.Text = WB_NAVIGATEUR.StatusText

        If Me.WB_NAVIGATEUR.CanGoForward Then
            Me.BT_SUIVANT.Enabled = True
        Else
            Me.BT_SUIVANT.Enabled = False
        End If
        If Me.WB_NAVIGATEUR.CanGoBack Then
            Me.BT_PRECEDENT.Enabled = True
        Else
            Me.BT_PRECEDENT.Enabled = False
        End If
    End Sub

#Region "Boutons de navigation"

    Private Sub BT_ADRESSE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_ADRESSE.Click
        'S'il existe une adresse, on y va
        If Not Me.TXT_ADRESSE Is Nothing Then
            Me.WB_NAVIGATEUR.Navigate(TXT_ADRESSE.Text)
        End If
    End Sub

    Private Sub BT_PRECEDENT_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_PRECEDENT.Click
        'Va à la page précédente
        Me.WB_NAVIGATEUR.GoBack()
    End Sub

    Private Sub BT_SUIVANT_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_SUIVANT.Click
        'Va à la page suivante
        Me.WB_NAVIGATEUR.GoForward()
    End Sub

    Private Sub BT_STOP_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_STOP.Click
        'Désactive le bouton « Stop » et arrête le chargement du navigateur
        Me.BT_STOP.Enabled = False
        Me.WB_NAVIGATEUR.Stop()
    End Sub

    Private Sub BT_REFRESH_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_REFRESH.Click
        'Rafraîchit le navigateur
        Me.WB_NAVIGATEUR.Refresh()
    End Sub

#End Region

    Private Sub QuitterToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles QuitterToolStripMenuItem.Click
        If MsgBox("Souhaitez-vous vraiment quitter ce magnifique programme ?", 36, "Quitter") = MsgBoxResult.Yes Then
            End
        End If
    End Sub
End Class

Pas de panique, votre code marche parfaitement sans, ça sert seulement à créer une zone rétractable où l'on peut mettre les fonctions dont on est sûr du résultat pour plus de lisibilité.

Revenons à nos moutons, la partie design. La figure suivante représente ce que j'ai obtenu.

Vous l'avez compris, je ne me suis pas foulé côté visuel ; nous rendrons tout cela plus beau plus tard. Alors, quelques explications du code.

Les instructions directement liées au WebBrowser sont nombreuses, vous auriez dû les trouver avec un peu de patience, les plus pressés d'entre vous auront craqué et seront passés directement à cette partie je pense. :p

Je vais vous les lister avec mes noms d'objets (donc WB_NAVIGATEUR pour le WebBrowser) :

• WB_NAVIGATEUR.StatusText : récupère le statut du navigateur ;

• Me.WB_NAVIGATEUR.Url.ToString : récupère l'adresse actuellement parcourue par le navigateur ;

• Me.WB_NAVIGATEUR.CanGoForward : renvoie un booléen pour dire si le navigateur a une page suivante (si vous avez fait précédent auparavant) ;

• Me.WB_NAVIGATEUR.CanGoBack : pareil qu'au-dessus, mais pour dire si le navigateur peut faire précédent ;

• Me.WB_NAVIGATEUR.Navigate(TXT_ADRESSE.Text) : le navigateur va à l'adresse de la page passée en argument (ici le texte de TXT_ADRESSE) ;

• Me.WB_NAVIGATEUR.GoBack() : le navigateur va à la page précédente ;

• Me.WB_NAVIGATEUR.GoForward() : navigue vers la page suivante ;

• Me.WB_NAVIGATEUR.Stop() : arrête le chargement d'une page ;

• Me.WB_NAVIGATEUR.Refresh() : rafraîchit la page.

Comme vous l'avez remarqué dans le code, j'ai deux événements concernant le navigateur : un qui se déclenche quand la page commence à se charger (Handles WB_NAVIGATEUR.Navigating), et le second, celui d'origine du WebBrowser : quand la page s'est totalement chargée (Handles WB_NAVIGATEUR.DocumentCompleted).

J'utilise ces deux événements pour activer ou non le bouton « Stop », changer le statut de la page, mettre à jour la nouvelle adresse, activer ou non les boutons « Précédent », « Suivant ».

J'ai utilisé cette forme pour vous montrer comment nous allons améliorer ce programme en exploitant au mieux les événements de notre contrôle (eh oui, les fonctions c'est bien beau, mais les événements, c'est magnifique :p ).

Bon, je ne sais pas si vous avez prêté attention à tous les événements que nous offre ce petit WebBrowser… En voici quelques-uns qui vont nous être fort utiles :

• Handles WB_NAVIGATEUR.StatusTextChanged ;

• Handles WB_NAVIGATEUR.CanGoBackChanged ;

• Handles WB_NAVIGATEUR.CanGoForwardChanged ;

• Handles WB_NAVIGATEUR.ProgressChanged.

Nous allons donc abondamment utiliser le petit « e ». Vous vous souvenez, ce petit argument dont j'ai parlé il y a quelques chapitres. Eh bien, on va désormais l'utiliser. Il correspond à un objet qui va nous être utile, qui correspondra à différentes choses suivant le Handles : par exemple pour le Handles ProgressChanged il pourra nous fournir l'état d'avancement de la page, pour le cas du StatusTextChanged, le texte de statut, ainsi de suite…

Améliorons notre navigateur en nous servant de ces événements pour activer ou désactiver les boutons « Précédent » et « Suivant » en fonction de la possibilité ou non d'avancer ou reculer dans l'historique, de mettre une barre de progression, un texte de progression, etc.

Ce qui nous donne, seulement pour la gestion des événements du navigateur :

#Region "Evènements du WBroser"

    'À chaque changement d'état, on met à jour les boutons
    Sub WB_NAVIGATEUR_CanGoForwardChanged(ByVal sender As Object, ByVal e As EventArgs) Handles WB_NAVIGATEUR.CanGoForwardChanged
        If Me.WB_NAVIGATEUR.CanGoForward Then
            Me.BT_SUIVANT.Enabled = True
        Else
            Me.BT_SUIVANT.Enabled = False
        End If
    End Sub

    'À chaque changement d'état, on met à jour les boutons
    Sub WB_NAVIGATEUR_CanGoBackChanged(ByVal sender As Object, ByVal e As EventArgs) Handles WB_NAVIGATEUR.CanGoBackChanged
        If Me.WB_NAVIGATEUR.CanGoBack Then
            Me.BT_PRECEDENT.Enabled = True
        Else
            Me.BT_PRECEDENT.Enabled = False
        End If
    End Sub

    'Au changement de statut de la page
    Sub WB_NAVIGATEUR_StatutTextChanged(ByVal sender As Object, ByVal e As EventArgs) Handles WB_NAVIGATEUR.StatusTextChanged
        'On met le statut à jour
        Me.LBL_STATUT.Text = WB_NAVIGATEUR.StatusText
    End Sub

    'Au changement de progression de la page
    Sub WB_NAVIGATEUR_ProgressChanged(ByVal sender As Object, ByVal e As WebBrowserProgressChangedEventArgs) Handles WB_NAVIGATEUR.ProgressChanged
        Me.PGB_STATUT.Maximum = e.MaximumProgress
        Me.PGB_STATUT.Value = e.CurrentProgress
    End Sub

    'Lorsque le chargement est fini
    Private Sub WB_NAVIGATEUR_DocumentCompleted(ByVal sender As System.Object, ByVal e As System.Windows.Forms.WebBrowserDocumentCompletedEventArgs) Handles WB_NAVIGATEUR.DocumentCompleted
        'on désactive le bouton « Stop »
        Me.BT_STOP.Enabled = False
        'on cache la barre de progression
        Me.PGB_STATUT.Visible = False
        'on récupère l'adresse de la page et on l'affiche
        Me.TXT_ADRESSE.Text = Me.WB_NAVIGATEUR.Url.ToString
    End Sub

    'Lorsque le chargement commence
    Private Sub WB_NAVIGATEUR_Navigating(ByVal sender As System.Object, ByVal e As System.Windows.Forms.WebBrowserNavigatingEventArgs) Handles WB_NAVIGATEUR.Navigating
        'On active le bouton « Stop »
        Me.BT_STOP.Enabled = True
        'Au début du chargement, on affiche la barre de progression
        Me.PGB_STATUT.Visible = True
    End Sub
#End Region

Bon, ce code, si vous avez pris la peine d'essayer de le comprendre, fait ce que j'ai dit plus haut en s'aidant du e dans un cas pour l'instant : faire avancer la progressbar. Alors comment ai-je fait pour réaliser cette prouesse ?

Eh bien si vous avez tapé « e. » dans l'événement du changement de progression, votre IDE vous fournit les fonctions, objets et propriétés pouvant être utilisés. Vous voyez deux lignes qui s'écartent du lot :

• CurrentProgress ;

• MaximumProgress.

En mettant le curseur dessus, votre IDE vous explique que ces valeurs renvoient chacune un Long (donc un nombre que nous allons pouvoir exploiter), mais à quoi correspond-il ? Eh bien la réponse est déjà grandement fournie dans le nom :p , mais bon, en dessous c'est marqué : le MaximumProgress nous renvoie le nombre de bytes à télécharger pour avoir la page et le CurrentProgress, le nombre de bytes actuellement téléchargés.

Ensuite, il ne faut pas sortir de Saint-Cyr pour savoir ce qu'il faut faire : on attribue le nombre de bytes à télécharger en tant que maximum pour la progressbar, et on met comme valeur le nombre de bytes actuellement téléchargés.

Et on obtient notre premier événement dans lequel on exploite les arguments transmis par e.

Si, en remplaçant StatusTextChanged par ProgressChanged dans ce code :

Sub WB_NAVIGATEUR_StatutTextChanged(ByVal sender As Object, ByVal e As EventArgs) Handles WB_NAVIGATEUR.StatusTextChanged

… une erreur inconnue au bataillon est apparue, pas de panique ! Certains événements utiliseront, comme ici, e as EventArgs (ou system.EventArgs), alors que d'autres utiliseront des e de type spécifique : WebBrowserProgressChangedEventArgs (dans le cas du Handles ProgressChanged). Et c'est également pour cette raison que dans certains événements des propriétés supplémentaires s'offriront à notre e, simplement car celui-ci n'est pas du même type…

Bon, cette partie est très importante car ce petit e sera utilisé très souvent dans vos programmes, lorsque vous réagirez avec des objets, c'est ce e qui gèrera les retours d'événements.

Je vous l'accorde, tel quel, notre programme ne donne pas vraiment envie. Nous allons donc l'améliorer un peu visuellement. J'ai décidé d'utiliser des icônes et pictogrammes sous licence creative commons for non commercial use. Je vais vous les montrer ici, mais le pack complet (plus de 1000 pictos ) est disponible ici.

Le premier sera pour le bouton d'envoi, le second pour le rafraîchissement de page, ensuite le « Stop », « Suivant », puis « Précédent ». Vous êtes bien évidemment libres d'en choisir d'autres.

Nous allons donc intégrer une image à nos boutons, pour ça il faut agir sur la propriété… Image ! Lorsque vous allez vouloir choisir une image, une fenêtre vous propose deux choix : utiliser une ressource locale ou un fichier de ressources, la différence : le fichier de ressources rassemble toutes les ressources : images, sons, etc., alors que les ressources externes ne seront pas intégrées à la compilation du projet. Les ressources externes sont donc bonnes pour les tests.

Nous allons tout de suite utiliser le fichier de ressources. Cliquez donc sur le petit Importer en bas et choisissez vos images. Attribuez les bonnes images aux bons boutons (ce serait bête d'avoir un précédent avec une icône de suivant). Pour un plus beau rendu, mettez la propriété FlatStyle à Flat, et dans FlatAppearance, bordersize à 0.

Après, à vous de toucher un peu les propriétés de la page, des éléments comme vous le sentez pour les adapter à vos goûts. La figure suivante vous présente mon résultat final.

Pas de moqueries, je ne suis pas graphiste. Je vais quand même vous donner mon image d'arrière-plan (si certains osent la prendre ^^ ).

Comme vous le voyez, j'ai changé la couleur de certains contrôles, modifié les styles, etc.

Cette partie sur le design n'avait pas la prétention de faire de vous des pros du design, mais juste de vous faire découvrir une autre facette du développement d'un programme.

Bon, nous voilà avec une base de navigateur, gardez-la de côté, un prochain chapitre consacré à son amélioration viendra quand j'aurai apporté de nouveaux concepts et de nouvelles connaissances.

• On utilise la navigation web avec le composant WebBrowser.

• Ce composant peut vous permettre de télécharger le texte ou le code source d'une page.

• Pour gérer le WebBrowser, il faut utiliser ses événements.

Nous allons commencer par ajouter des fenêtres supplémentaires, puis nous apprendrons à les faire communiquer entre elles ! Créons tout de suite un nouveau projet de test Windows Forms avec le nom que vous souhaitez (pour moi ce sera FenetresSupplementaires).

On se retrouve comme à l'accoutumée avec notre fenêtre form1 gisant au beau milieu de notre feuille de design.

Vu que nous allons travailler avec plusieurs fenêtres, les noms de fenêtres vont être maintenant très importants.

Renommons donc cette fenêtre principale. Appelons-la Main (lorsque vous créerez un programme, je vous suggère de nommer cette première fenêtre avec le nom du programme).

Pour ce faire, cliquons une fois sur elle dans la fenêtre design pour avoir accès à ses propriétés. Dans la valeur Name, inscrivez donc Main, faites de même pour la valeur Text.

Puis renommons la feuille contenant cette fenêtre que nous voyons dans la fenêtre de solutions. Faites-un clic droit sur Form1.vb, puis renommez-la : inscrivez à la place Main.vb (voir figure suivante).

Voilà, vous venez de renommer entièrement votre fenêtre. Il faudra faire de même avec les supplémentaires.

Ajoutons une seconde fenêtre maintenant. Faites un clic droit sur le nom de votre projet (pour moi : FenetresSupplementaires), déplacez votre souris sur le menu Ajouter qui nous donnera accès à Nouvel élément et cliquez dessus. Une fenêtre proposant différents types d'éléments à ajouter à votre projet apparaît. Nous voulons une fenêtre, il va donc falloir sélectionner Windows Form (retenez bien cette manipulation, elle va nous permettre d'ajouter d'autres types d'éléments à notre projet). Pensez à renommer cette fenêtre, essayez de trouver un nom adapté à sa fonction. Vu que notre projet est là pour l'apprentissage et n'a aucune fonction particulière à remplir, je vais lui donner comme nom Secondaire.

Vous voici avec votre seconde fenêtre Secondaire qui s'est automatiquement ouverte. Comme vous avez pu le constater, les modifications de renommage que nous avons effectuées sur la fenêtre Main ont été automatiquement effectuées sur cette deuxième fenêtre (voir figure suivante).

Vous voilà avec votre première deuxième fenêtre (dur à suivre :) ). Allons nous amuser avec elle !

Vous vous souvenez que je vous ai toujours appris à assigner des propriétés à vos contrôles en commençant la ligne par Me. : c'est dans ce chapitre que vous allez vous rendre compte de son utilité.

Créons tout de suite un contrôle sur notre seconde fenêtre, un bouton Fermer par exemple.

Oui, on va effectuer simplement un programme avec un bouton qui l'ouvre et un bouton permettant de la fermer. Donc, je crée mon bouton Fermer, identifié BT_FERMER. Me voilà donc avec seulement ce bouton dans ma fenêtre secondaire (voir figure suivante).

Créons donc un bouton Ouvrir identifié BT_OUVRIR sur la fenêtre principale (Main). Vous pouvez y accéder soit grâce au système d'onglets si vous ne l'avez pas fermée, soit grâce à la fenêtre de solutions en double-cliquant sur son nom.

Sur notre seconde fenêtre comme sur la première, si nous voulons accéder à des propriétés, il va falloir utiliser le Me. dans la page de code correspondante. En parlant d'elle, allons-y, créons l'événement BT_FERMER_Click en double-cliquant sur le bouton.

La fonction permettant de fermer une fenêtre individuelle est Close().

Oui, End permet de fermer le programme, dans notre cas nous voulons fermer la fenêtre seule, il faut donc utiliser la fonction Close().

Maintenant l'objet sur lequel cette fonction va être exécutée est important. La feuille de code dans laquelle je me trouve actuellement correspond à la fenêtre secondaire. En utilisant le préfixe Me., l'objet de cette fenêtre sera automatiquement pris en compte. Si vous avez suivi, notre fonction va se retrouver sous cette forme :

Private Sub BT_FERMER_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_FERMER.Click
    Me.Close()
End Sub

Et donc avec cette méthode nous sommes certains que c'est cette fenêtre qui va être affectée par le Close() et donc fermée.

Retournons dans la fenêtre Main et double-cliquons sur le bouton Ouvrir pour créer son événement correspondant.

Et insérons dans cet événement le code nécessaire pour ouvrir une autre fenêtre qui est… la fonction Show().

Alors, si vous avez suivi mon monologue sur les objets, sur quel objet va-t-il falloir appliquer cette fonction ?

Eh bien, c'est sur l'objet de la fenêtre supplémentaire. Autrement dit l'objet Secondaire.

Ce qui nous donne :

Private Sub BT_OUVRIR_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_OUVRIR.Click
    Secondaire.Show()
End Sub

L'utilisation du préfixe Me. force l'utilisation de la fenêtre actuelle comme objet. Vous ne voulez pas afficher une fenêtre déjà ouverte ?

Si je teste, tout fonctionne : lors du clic sur Ouvrir, la seconde fenêtre s'ouvre, lors du clic sur Fermer, la seconde fenêtre se ferme.

Eh bien, vous avez déjà réussi à faire apparaître votre nouvelle fenêtre, puis à la fermer.

Non, non. Le concept de parent et d'enfant est aussi utilisé en informatique.

Je vais justement vous l'exposer sommairement ici.

Programmation orientée objet

La notion de parent/enfant est à l'origine utilisée en programmation orientée objet (abrégée en POO).

La POO est un style de programmation de plus en plus répandu. Certains langages ne sont pas orientés objet, d'autres le sont totalement. Notre langage, VB .NET utilise énormément la notion d'orienté objet.

Eh bien, si vous voulez avoir plus de détails concernant la POO, je vous renvoie sur le tutoriel sur le C++ du Site Du Zero qui explique très bien le concept d'objet (réservé aux plus curieux d'entre vous).

Pour faire simple : on a introduit la notion d'objet pour pouvoir gérer plus facilement les gros programmes. Par exemple, dans nos programmes, les fenêtres sont toutes des objets bien distincts. Lorsque nous voudrons agir sur une fenêtre en particulier, il nous suffira de manipuler son objet.

Eh bien maintenant que je vous ai fait peur avec les objets :diable: , je vais vous parler des relations parent/enfant qui s'appliquent sur les objets.

L'héritage

Cette notion a été introduite avec la notion d'héritage.

Mais moi je vous parle de l'héritage en informatique. C'est un concept qui s'applique aux objets.

Imaginez que vous ayez un objet de type Instrument (eh oui, un objet peut être n'importe quoi du moment que vous le codez), cet objet va avoir des variables et des fonctions qui lui seront spécifiques (les notes qu'il est capable de jouer, la fonction Joue, etc.).

Si je crée un autre objet de type Guitare, vous voyez tout de suite qu'une guitare est un instrument, donc au lieu de recréer toutes les fonctions et variables qui existaient pour l'objet Instrument, je vais faire hériter ma Guitare de Instrument.

Regardez le schéma à la figure suivante.

Donc, chaque rectangle est un objet. Vous voyez l'objet Instrument, l'objet Guitare et l'objet Piano.
L'objet Guitare et l'objet Piano héritent tous les deux de l'objet Instrument.

Donc, la Guitare aura en plus de ses possibilités originelles (qui sont NbCordes et Vibrato()) celles de Instrument(qui sont Notes et Joue()). Pareil côté Piano.

Parent/enfant

Si je détruis l'objet Instrument, les objets qui en héritent (autrement dit Guitare et Piano) seront également détruits. Dans ce cas, Instrument est le parent, et Guitare et Piano sont les enfants.

J'en viens donc à notre problème actuel : les fenêtres.

Lorsque je lance mon programme, la première fenêtre, ici le Main, est considérée comme la fenêtre parent, et donc toutes les fenêtres supplémentaires créées seront ses enfants.
Si vous avez suivi ce que j'ai expliqué, si je ferme la fenêtre Main, les autres fenêtres se fermeront également.

Donc il va falloir faire bien attention à ça dans nos programmes. Ne pas fermer la fenêtre principale !

Eh bien il vous suffit d'effectuer un Visible = false sur cette dernière (j'ai dit que ce n'est pas bien, mais ici vous êtes obligés). Mais attention avec ça, ce n'est pas le tout de cacher la fenêtre et de ne jamais pouvoir la réafficher.

Bon, avec toutes ces nouvelles notions, nous allons pouvoir attaquer la communication entre fenêtres.

Bon, après cette lourde partie théorique, attelons-nous à faire communiquer nos fenêtres entre elles.

Eh bien, vous avez vu comment déclarer des variables. Vous ne voulez pas aller modifier les variables de la fenêtre d'à côté ? Écrire dans une textbox présente sur une autre fenêtre ?

Et puis même si vous n'avez pas envie, je vais quand même vous l'expliquer.

Manipulation de contrôles

Commençons par manipuler les contrôles, le plus facile.

Créons un label dans notre fenêtre principale nommée LBL_MAIN et un dans la fenêtre secondaire nommée LBL_SECOND. Enlevez-leur leurs textes pour ne laisser que du blanc.

Nous allons écrire un message dans le label de la fenêtre secondaire à son ouverture, mais à partir de la feuille de code de la fenêtre principale. Puis inversement lors de la fermeture de la fenêtre secondaire.

Si vous avez bien appréhendé toutes les notions d'objets, vous devriez être capables de le faire cela par vous-mêmes.

Pour manipuler un contrôle d'une autre fenêtre, il suffit d'inscrire le nom de la fenêtre souhaitée à la place du préfixe Me..

Soit, pour les deux événements présents sur les deux fenêtres :

Fenêtre Main :

Public Class Main

    Private Sub BT_OUVRIR_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_OUVRIR.Click
        Secondaire.Show()
        Secondaire.LBL_SECOND.Text = "J'ai réussi !"
    End Sub

End Class

Fenêtre Secondaire :

Public Class Secondaire

    Private Sub BT_FERMER_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_FERMER.Click
        Main.LBL_MAIN.Text = "De ce côté également"
        Me.Close()
    End Sub

End Class

Et le résultat à la figure suivante.

Nous avons réussi à manipuler des contrôles distants !

Manipulation des variables

Attaquons-nous donc tout de suite aux variables. Une petite précision supplémentaire va être requise pour cette partie.

Pour le moment nous déclarons nos variables avec un Dim à l'intérieur d'une fonction ou alors directement dans les arguments de la fonction. Nos variables avaient donc une « durée de vie » limitée. Une fois la fonction terminée, toutes les variables déclarées à l'intérieur cessaient d'exister.

Nous allons donc créer des variables globales de manière à ce qu'elles soient accessibles de partout.

Pour déclarer une variable globale, il faut placer son instruction de déclaration juste après l'ouverture du module.

Si elles sont créées comme je vous l'ai appris (Dim X as Integer), ces variables sont accessibles uniquement à partir de la fenêtre les ayant créées. Pour pouvoir y accéder depuis ailleurs, il va falloir les rendre publiques. Je vais donc vous apprendre un nouveau mot (programmatique) : Public.

Donc, si vous voulez des variables accessibles de « l'extérieur », il va falloir les déclarer ainsi.

On reprend donc le code de notre fenêtre secondaire en ajoutant cette variable globale et en assignant au label sa valeur lors du chargement de la fenêtre.

Public Class Secondaire

    Public MonString As String = ""

    Private Sub Secondaire_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Me.LBL_SECOND.Text = MonString
    End Sub

    Private Sub BT_FERMER_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_FERMER.Click
        Main.LBL_MAIN.Text = "De ce côté également"
        Me.Close()
    End Sub

End Class

Et voici le code de la fenêtre Main dans lequel j'accède à la variable MonString. J'ai volontairement retiré la ligne où je modifiais directement le label.

Public Class Main

    Private Sub BT_OUVRIR_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_OUVRIR.Click
        Secondaire.MonString = "Je crois que ça marche"
        Secondaire.Show()
    End Sub

End Class

Le résultat se trouve à la figure suivante.

Et voilà, votre première variable globale publique, et vous y avez déjà accédé à partir d'un autre objet !

• On crée une nouvelle fenêtre au projet en effectuant un clic droit, puis Ajouter.

• Une nouvelle fenêtre signifie un nouveau fichier.

• On peut faire interagir les fenêtres entre elles pour leur envoyer ou recevoir des variables.

Nous allons commencer par une rapide introduction sur les fichiers. Je suppose que pour nombre d'entre vous c'est un concept acquis, mais pour d'autres il va falloir quelques éclaircissements.

Amis Windowsiens, vous pouvez apercevoir dans votre poste de travail des lecteurs et des disques durs. Dans le(s) disque(s) dur(s), vous pouvez naviguer suivant un système d'arborescence : le disque dur contient des dossiers, ces dossiers contiennent des fichiers (récursif : les disques durs peuvent contenir des fichiers et les dossiers d'autres dossiers).

Résumons : le disque dur contient toutes vos données ; le dossier permet de gérer, organiser et hiérarchiser votre disque dur ; les fichiers quant à eux contiennent des données pures et dures.

Les fichiers : des 0 et des 1

Les fichiers contiennent des données donc. Ces données sont représentées (côté machine de votre PC) par des 0 et des 1 (des bits), le système binaire qu'ils appellent ça. :lol:
Nous, pauvres petits mortels ne comprendrions rien à ce langage propre à la machine, c'est pourquoi des codages ont été mis en place pour convertir ces groupements de 0 et de 1 (généralement groupés par 8, ce qui donne 8 bits, autrement appelé un octet).

Donc individuellement, vous vous apercevez que ces 0 et ces 1 ne sont pas reconnaissables, on ne peut rien en tirer. Mais une fois en groupe, ces petits bits peuvent être transcrits différemment en fonction du codage.

Exemples :

Alors, les cases dans chaque ligne de ce tableau ont la même valeur, seulement le codage utilisé n'est pas le même.

Le nombre décimal résultant de ces 0 et ces 1, vous le connaissez, pour peu que vous soyez allés à l'école primaire. En revanche, j'ai été méchant, j'ai ajouté une colonne avec à l'intérieur un nombre hexadécimal.

Sans m'étendre sur le sujet, le système hexadécimal est de base 16 (où le décimal est de base 10), il a été inventé par des informaticiens principalement pour des informaticiens. Il permet de transcrire rapidement des nombres binaires (car un groupement de 4 chiffres en binaire correspond à un chiffre hexadécimal).

Ça vient, ça vient. Donc vous avez compris que les données sont stockées sous forme de 0 et de 1, que des codages existent pour les transcrire en quelque chose de compréhensible par un humain. Pour le moment on se retrouve avec des nombres. Maintenant découvrons comment ils deviennent des caractères grâce à la norme ASCII.

La norme ASCII

La norme ASCII est la norme de codage de caractères standardisée. Autrement dit on l'utilise désormais dans tous les systèmes d'exploitation. Ici, c'est un groupement de 8 bits qui est converti en un caractère grâce à une table ASCII.

Exemple : la première suite de bits du tableau plus haut (01100011) correspond au caractère « c ».

Bref, je ne vous demande pas d'apprendre la table ASCII par cœur, notre IDE se chargera d'effectuer les codages tout seul. Tout ça pour vous sensibiliser un peu quant à la taille de vos fichiers. Windows a l'habitude de noter les tailles en ko (kilooctets) pour les petits fichiers, jusqu'aux Mo (mégaoctets), voire aux Go (gigaoctets) : 1 ko = 1024 octets, 1 Mo = 1 048 576 octets et 1 Go = 1 073 741 824 octets.

Donc 1024 caractères équivaudront à 1 ko.

Je vous ai peut être fait peur avec mes notions se rapprochant de la machine, mais ne vous inquiétez pas, c'était un peu de culture générale.

Microsoft, au travers de son framework (qui est une bibliothèque contenant des centaines de classes, fonctions, objets) a développé tous les outils nécessaires pour travailler facilement sur les fichiers, comme le montre la figure suivante.

Ce namespace (un namespace est une sorte de dossier contenant des classes et fonctions spécifiques) est le namespace IO. Comme vous le voyez sur le schéma, ces namespaces permettent d'organiser le contenu du framework.

Eh bien, IO correspond à « Input Output ». En français : « Entrée Sortie ».

Ce namespace ne va pas contenir que les fonctions et objets pour manipuler les fichiers, il va nous permettre également d'effectuer de la communication inter-processus, de la communication série et de la compression. Mais n'allons pas trop vite.

Donc ce namespace fait lui-même partie du namespace System (comme dans votre ordinateur, on a plusieurs niveaux de dossiers pour mieux classer vos fichiers, eh bien ici c'est pareil avec les namespaces et les objets et fonctions).

Et dans ce namespace se situe la classe FileStream qui va nous permettre de créer un objet de type FileStream et de le manipuler. La classe File quant à elle ne nous permettra pas de créer un objet, mais seulement de manipuler notre FileStream. Vous allez très vite comprendre.

Une petite information supplémentaire avant de passer à la pratique : nous allons devoir créer un objet et le manipuler ; pour cela nous allons découvrir un nouveau mot récurrent en programmation : New.

Créez un nouveau projet et rendez-vous dans l'événement du form load (je ne vous explique plus la démarche, vous êtes grands), je vous attends. Donc créons notre objet et entrons-le dans une variable.

Très bonne question, on va créer un objet permettant de manipuler les fichiers, ce serait malpropre de l'insérer dans un Integer, voire un String… Eh bien, j'ai dit que nous allions créer un objet FileStream, pourquoi ne pas l'entrer dans une variable de type FileStream ?

J'ai donc créé mon objet et je l'ai entré dans une variable :

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Création d'un objet de type FileStream
        Dim MonFichier As IO.FileStream = New IO.FileStream("Zero.txt", IO.FileMode.OpenOrCreate)

    End Sub

End Class

Plein de choses à vous expliquer en une seule ligne, j'aime ça ! Vous reconnaissez tous le Dim MonFichier As IO.FileStream, une simple déclaration de variable de type FileStream.

Je l'ai expliqué, on est dans le namespace IO, il faut donc faire IO. avant de pouvoir accéder aux membres du namespace.

Bon, déjà une chose de faite, continuons : = New IO.FileStream permet d'assigner une valeur à notre variable dès la déclaration, ça aussi nous l'avons vu. Le mot-clé New, j'ai dit qu'il servait à créer un nouvel objet (ici de type FileStream).

Instanciation de notre premier objet

Eh bien pas exactement. Lorsque nous instancions un objet (le mot instanciation fait peur, mais il signifie juste que nous créons un nouvel objet grâce à New), la classe utilisée pour déclarer l'objet va faire appel à son constructeur. Le mot « constructeur » est spécifique à la POO, nous reviendrons dessus plus tard. Le fait est que ce constructeur est appelé et parfois ce constructeur nécessite des arguments.

Dans notre cas, le constructeur de FileStream accepte plein de « combinaisons » d'arguments possibles (ce que l'on appelle la surcharge, j'expliquerai aussi plus tard).

J'ai choisi les plus simples : le Pathdu fichier (en String) avec lequel nous allons travailler, et un argument qui va nous permettre de déterminer comment ouvrir ou créer le fichier (de type IO.FileMode).

Le Path

Je vais faire une rapide parenthèse sur le Path. Tout d'abord le mot « path » signifie le chemin du fichier.
Ce chemin (je préfère parler de Path) peut être de deux types :

• Absolu : le chemin n'a pas de référence, mais n'est pas exportable (ex : C:\Windows\System32… est un chemin absolu) ;

• Relatif : le chemin prend comme point de repère le dossier d'exécution de notre programme (ex : Zero.txt sera placé dans le même dossier que le programme que nous créons).

Il est donc préférable d'utiliser des chemins relatifs dans nos programmes, à moins que vous ne soyez certains de l'emplacement des fichiers que vous voulez manipuler.

FileMode

Dans notre cas, j'ai inscrit un Path relatif, le fichier Zero.txt sera créé s'il n'existe pas, sinon il sera ouvert. Et tout cela grâce à l'argument IO.FileMode.OpenOrCreate.

Cet argument peut prendre quelques autres valeurs :

Comme vous le voyez, l'argument que j'ai utilisé, FileMode.OpenOrCreate (aussi remplaçable par le chiffre 4), permet d'adapter notre programme. Imaginez en utilisant l'argument FileMode.CreateNew, le premier lancement du programme se déroulera bien, mais lors du second lancement une erreur se produira parce que le fichier existe déjà. À moins que vous ne gériez toutes ces éventualités. Mais nous sommes des Zéros, allons au plus simple.

Résumé

Résumons ce que cette instruction a fait : on a ouvert le fichier Zero.txt (créé s'il n'existait pas) et on l'a dans la variable MonFichier.

Programme de base

Bon continuons, créons une petite interface basique permettant de lire et écrire dans le fichier. J'aimerais donc que vous créiez quelque chose qui ressemble à la figure suivante.

Alors, pour ce qui est des noms des contrôles, je pense que vous êtes grands maintenant, ils ne vont plus poser problème.
Mes deux textbox (TXT_LECTURE, TXT_ECRITURE) ont la propriété Multilineà true, celle du haut a ReadOnlyà true.
Des boutons (BT_LIRE, BT_CLEARLIRE, BT_ECRIRE, BT_CLEARECRIRE et BT_CLEAR tout en bas) et une checkbox (CHK_DEBUT).

Voilà pour ce qui est du design. Pour le code je vais vous montrer le mien et on va détailler le tout. Attention, je reprends pas mal de concepts abordés avant, tout en en intégrant des nouveaux, accrochez-vous !

Imports System.IO

Public Class Form1

    Dim MonFichier As IO.FileStream

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Création d'un objet de type FileStream 
        MonFichier = New IO.FileStream("Zero.txt", IO.FileMode.OpenOrCreate)
    End Sub

    Private Sub Form1_FormClosing(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.FormClosing
        'Libère la mémoire
        MonFichier.Dispose()
    End Sub

#Region "Gestion des boutons"

    Private Sub BT_LIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_LIRE.Click

        If MonFichier.CanRead() Then
            'Crée un tableau de Byte
            Dim Contenu(1024) As Byte
            'Lit 1024 bytes et les entre dans le tableau
            MonFichier.Position = 0
            MonFichier.Read(Contenu, 0, 1024)
            'L'affiche
            Me.TXT_LECTURE.Text = ""
            For Each Lettre As Byte In Contenu
                Me.TXT_LECTURE.Text += Chr(Lettre)
            Next
        End If

    End Sub

    Private Sub BT_ECRIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_ECRIRE.Click
        If MonFichier.CanWrite Then
            Dim Contenu(1024) As Byte
            Dim Compteur As Integer = 0
            'Parcours la textbox
            For Each Lettre As Char In Me.TXT_ECRITURE.Text.ToCharArray
                'Convertit une lettre en sa valeur ASCII et l'entre dans compteur
                Contenu(Compteur) = Asc(Lettre)
                Compteur += 1
            Next
            'Écrit dans le fichier
            If Me.CHK_DEBUT.Checked Then
                MonFichier.Position = 0
            End If
            MonFichier.Write(Contenu, 0, Compteur)
        End If
    End Sub

    Private Sub BT_CLEARLIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_CLEARLIRE.Click
        Me.TXT_LECTURE.Text = ""
    End Sub

    Private Sub BT_CLEARECRIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_CLEARECRIRE.Click
        Me.TXT_ECRITURE.Text = ""
    End Sub

    Private Sub BT_CLEAR_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_CLEAR.Click
        'Je ferme le fichier actuel
        MonFichier.Dispose()
        'Je le réouvre en écrasant ses données
        MonFichier = New IO.FileStream("Zero.txt", FileMode.Create)
    End Sub

#End Region

End Class

Explications

Bien, bien, vous voilà avec des codes de plus en plus complexes. Prenons le problème par étapes. Tout d'abord nous avons les boutons de vidage des textbox qui ne sont pas sorciers, une simple instruction pour remplacer leur contenu.

Alors commençons à étudier le voyage de notre fichier. Je déclare en variable globale le fichier, de façon à ce qu'il soit accessible dans toutes les fonctions. Lors du Load, j'ouvre mon fichier comme nous l'avons vu dans la partie d'avant.

Et, chose importante, j'ai réagi à l'événement FormClosing(traduisible par « fenêtre en cours de fermeture », à ne pas confondre avec FormClosed: « fenêtre fermée »). Lorsque cet événement se produit, je Dispose()le fichier.

La fonction Dispose() permet de vider les ressources mémoire que prenait le fichier. En résumé, cela le ferme.

Donc, fichier ouvert et chargé à l'ouverture du programme, fermé à la fermeture. Parfait !
Travaillons.

Nous arrivons aux deux boutons Lire et Ecrire.

L'écriture

Bien, commençons par l'écriture (on ne va pas lire avant d'avoir écrit :lol: ).

Private Sub BT_ECRIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_ECRIRE.Click
        If MonFichier.CanWrite Then
            Dim Contenu(1024) As Byte
            Dim Compteur As Integer = 0
            'Parcours la textbox
            For Each Lettre As Char In Me.TXT_ECRITURE.Text.ToCharArray
                'Convertit une lettre en sa valeur ASCII et l'entre dans compteur
                Contenu(Compteur) = Asc(Lettre)
                Compteur += 1
            Next
            'Écrit dans le fichier
            If Me.CHK_DEBUT.Checked Then
                MonFichier.Position = 0
            End If
            MonFichier.Write(Contenu, 0, Compteur)
        End If
    End Sub

• Alors, première instruction, déjà une nouvelle chose : MonFichier.CanWrite.
  C'est une propriété de l'objet. Elle nous informe sur la possibilité d'écriture dans notre fichier. Si c'est true, c'est parfait, on continue (ces petites vérifications sont souvent inutiles, mais il ne coûte rien de les faire et elles peuvent parfois éviter des erreurs, pensez aussi à gérer les cas d'erreurs).

• Je crée ensuite un tableau de Byte, 1025 cases (je prévois grand !). Sachant que chaque byte (je n'ai pas expliqué, mais un byte est aussi de 8 bits dans notre cas, soit… un octet, soit… un caractère !) peut contenir un caractère, nous avons une possibilité d'écriture de 1025 caractères.

• Un petit compteur, il va nous servir après.

• Puis un For Each grâce auquel je parcours tous les caractères contenus dans ma textbox : Me.TXT_ECRITURE.Text.ToCharArray. La fonction ToCharArray permet, comme son nom anglais l'indique, de convertir en tableau de Char. Pour chaque caractère donc, ce caractère est entré dans la variable Lettre.

• Je rentre chaque lettre dans mon tableau de Byte. Mais attention, les Byte et les Char ne sont pas homogènes, il faut passer par une fonction qui va récupérer la valeur binaire de notre caractère (transformation ASCII => 8 Bits grâce à la fonction Asc()) de façon à pouvoir l'inscrire dans le Byte.

• Vient ensuite l'incrémentation du compteur pour pouvoir écrire chaque caractère dans une case différente.

• Ensuite, si la case est cochée on déplace le curseur au début du fichier. Je vais parler des curseurs juste après.

• Puis on écrit le contenu de notre tableau en indiquant combien de Byte écrire (avec compteur).

Eh bien, je sais qu'il y a pas mal de notions d'un coup. Reprenez le tout lentement en essayant de comprendre chaque ligne individuellement.

Les curseurs

Petit aparté sur les curseurs.

Alors je viens de parler de curseur dans notre fichier, mais qu'est-ce que cela ?

Non, n'y pensez même pas, ce n'est pas un curseur de souris qui bouge dans notre fichier, mais c'est comparable :
Un curseur doit être représenté mentalement. C'est un petit charriot qui avance dans notre fichier. Lorsqu'on lui demande de lire ou d'écrire, ce petit charriot va se déplacer de caractère en caractère et l'écrire (ou le lire). Donc lorsqu'on lit un fichier entier, le curseur se retrouve tout à la fin. Si on ne lit que la moitié, à la moitié.

Regardez le schéma présenté à la figure suivante.

Bref, tout ça pour dire que ce petit charriot ne bouge pas tout seul si on ne lui en donne pas l'ordre. Si je lis mon fichier, le curseur va se retrouver à la fin, lors d'une écriture sans bouger le curseur, l'écriture s'effectuera au début.

Pareil pour la lecture, si le curseur est à la fin et qu'on demande une lecture, il n'y aura rien à lire. Donc la propriété Positionpermet de spécifier l'index de ce curseur. Ici je le replace au début à chaque fois (0).

Mais attention, si je reprends l'écriture au début, le curseur ne s'occupe pas de ce qu'il y a avant, lorsqu'il va rencontrer un caractère déjà écrit dans le fichier il va purement et simplement le remplacer.

Faites bien attention donc et représentez-vous mentalement le trajet du curseur dans votre fichier pendant votre programme.

La lecture

Reprenons l'événement qui s'effectue lors du clic sur le bouton Lire :

Private Sub BT_LIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_LIRE.Click

        If MonFichier.CanRead() Then
            'Crée un tableau de Byte
            Dim Contenu(1024) As Byte
            'Lit 1024 bytes et les entre dans le tableau
            MonFichier.Position = 0
            MonFichier.Read(Contenu, 0, 1024)
            'L'affiche
            Me.TXT_LECTURE.Text = ""
            For Each Lettre As Byte In Contenu
                Me.TXT_LECTURE.Text += Chr(Lettre)
            Next
        End If

    End Sub

• Première ligne, le même principe que pour l'écriture, on effectue un petite vérification pour savoir si l'on peut effectuer notre lecture.

• On crée un tableau de Byte (comme l'écriture : 1025 cases).

• On place le curseur à la position 0 (début de mon fichier).

• On lit sur 1024 bytes (si le curseur rencontre la fin du fichier, la lecture s'arrête), et on place ce qui a été lu dans le tableau de Byte déclaré juste avant.

• Puis un traditionnel For Each afin de parcourir toutes les cases de ce tableau de Byte.

• On effectue une conversion Numerique => Caractère (soit Byte => ASCII grâce à la fonction Chr()), sinon vous ne liriez que des chiffres dans votre résultat ! On place le tout dans la textbox (grâce à += on ajoute les caractères à la suite).

Eh bien voilà, cela nous donne la figure suivante en résultat de tests.

J'en profite pour vous dire que les caractères permettant de matérialiser le retour à la ligne sont contenus dans la chaîne que vous récupérez de votre textbox, donc lorsqu'on demande une écriture de tout son contenu, le caractère est également écrit dans le fichier, le retour à la ligne s'effectue donc également dans le fichier sans manipulations supplémentaires.

Déjà une bonne chose de faite, ne partez pas ! On va apprendre de nouvelles fonctions et manipulations sur nos nouveaux amis les fichiers dans la partie suivante.

• On utilise le namespace IO pour effectuer des opérations d'entrée-sortie sur les fichiers.

• Il faut bien penser au curseur qui avance en même temps que la lecture ou l'écriture dans un fichier.

• On peut utiliser des formats absolus ou relatifs pour les chemins des fichiers. Les chemins absolus ne sont pas fiables pour un programme destiné à être mis sur d'autres postes.

La technique que je vous ai montrée utilise le principe du stream. Autrement dit, du flux. Dans le principe : le fichier est intégralement ouvert et inséré dans un objet de type Stream. Pendant le temps que le stream est ouvert (fichier ouvert par le programme), son écriture par une autre instance (un autre programme) est impossible.

Cette technique comporte des avantages et des inconvénients : on peut être certain que le fichier ne sera pas modifié pendant le déroulement du programme, mais par contre il est bloqué et donc plusieurs programmes ne peuvent pas travailler dessus en même temps.

Bref, je parie que vous voulez une autre technique.

La classe File vient à votre secours !

La classe File

Cette classe est préimplémentée dans le framework. On va créer le même programme de lecture/écriture que précédemment avec cette classe. La même interface donc, mais le code va légèrement changer :

Imports System.IO

Public Class Form1

    Const PATHFICHIER As String = "Zero.txt"    

    Private Sub BT_CLEARLIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_CLEARLIRE.Click
        Me.TXT_LECTURE.Text = ""
    End Sub

    Private Sub BT_CLEARECRIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_CLEARECRIRE.Click
        Me.TXT_ECRITURE.Text = ""
    End Sub

    Private Sub BT_CLEAR_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_CLEAR.Click
        File.WriteAllText(PATHFICHIER , "")
    End Sub

    Private Sub BT_LIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_LIRE.Click
        Me.TXT_LECTURE.Text = File.ReadAllText(PATHFICHIER)
    End Sub

    Private Sub BT_ECRIRE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_ECRIRE.Click
        If Me.CHK_DEBUT.Checked Then
	    'Depuis le début
            File.WriteAllText(PATHFICHIER , Me.TXT_ECRITURE.Text)
        Else
	    'À la suite
            File.AppendAllText(PATHFICHIER , Me.TXT_ECRITURE.Text)
        End If

    End Sub
End Class

Eh bien oui, si on veut. La classe File a les outils nécessaires pour effectuer les actions dont nous avions besoin.

Eh bien, je vous aurais montré qu'on aurait pu le faire ainsi, auriez-vous réellement pris le temps de comprendre tout ce qui a été introduit au chapitre précédent ? (Les objets, le stream, les conversions de caractères).

Bon, cette classe nous permet de lire/écrire rapidement dans nos fichiers. Examinons quand même ces lignes.

Tout d'abord la déclaration d'une variable constante pour spécifier le Path que je vais utiliser pendant tout le programme : Const PATHFICHIER As String = "Zero.txt". Path relatif bien évidemment.

File.WriteAllText(PATHFICHIER , Me.TXT_ECRITURE.Text) : la méthode WriteAllText de la classe File permet d'écrire du texte dans un fichier en redémarrant du début. Donc effacement du contenu précédent (ce que j'ai utilisé pour l'effacement du fichier).

File.AppendAllText(PATHFICHIER , Me.TXT_ECRITURE.Text) : la méthode AppendAllText, quant à elle, écrit à la suite du fichier, donc je l'ai utilisée lorsque la checkbox est cochée.

Il nous reste finalement la lecture : Me.TXT_LECTURE.Text = File.ReadAllText(PATHFICHIER). Une fonction qui cette fois-ci lit depuis le début et entre le tout dans un String, que j'affiche directement via ma textbox.

Quelle simplification quand même ! Je vous rassure, par la suite nous utiliserons cette classe, nous nous concentrerons plus sur le fonctionnel des fichiers que sur comment effectuer nos manipulations dessus.

Découvrons d'autres manipulations

Bien, tout d'abord le légendaire Move, autrement dit le déplacement du fichier.

File.Move(Source as string, Destination as string)

Vous pouvez bien évidemment utiliser des chemins relatifs, absolus, ou mélanger les deux. :D
Cette méthode est également utilisée pour renommer les fichiers, il suffit simplement d'effectuer le Move avec deux noms différents, mais sur le même Path.

La copie

File.Copy(Source as string, Destination as string)

Même principe que la méthode précédente, vous n'avez cependant pas le droit d'attribuer le même nom à la source et à la destination.

La vérification de la présence du fichier

File.Exists(Fichier as string)

Fonction très importante ! Lorsque l'on va effectuer des manipulations, toujours vérifier la présence du fichier avant d'effectuer une action dessus ! Vous ne voulez pas vous retrouver avec une grosse erreur qui tache ! Renvoie un Boolean : True si présence du fichier, False dans le cas contraire.

Cette fois, pas de stream ou autres, la classe Directory est la seule dans le namespace IO (directory : répertoire).

Fonctions de modification

On va commencer par la fonction à utiliser avant toute chose :

La vérification

Directory.Exists(Path As String)

Renvoie un booléen encore une fois, bien évidemment très important ! On l'utilisera systématiquement !

La création de dossiers

Directory.CreateDirectory(Path As String)

Alors, cette méthode est assez magique. Elle va créer entièrement le Path spécifié. Je m'explique.
Parlons en chemin relatif : il n'y a actuellement aucun dossier dans le répertoire d'exécution de votre programme. Si en argument de la méthode je passe Dossier1/SousDossier1/SousSousDossier1, il y aura trois dossiers de créés, suivant l'arborescence suivante : le dossier Dossier1 sera créé directement dans le répertoire, le dossier SousDossier1 sera créé dans Dossier1, et finalement le dossier SousSousDossier1 sera créé dans SousDossier1. Le tout pour dire à quel point cette méthode peut se révéler pratique.

La suppression

Directory.Delete(Path As String, Recursif As Boolean)

Alors, ici nous avons un second argument en plus du chemin du dossier à supprimer ; il correspond à la récursivité. Si vous activez la récursivité, les dossiers et fichiers « en dessous » (dans l'arborescence des fichiers) du chemin que vous avez indiqué seront également supprimés ; sinon, si la récursivité n'est pas activée et que vous tentez de supprimer un dossier qui n'est pas vide, une erreur surviendra.
En résumé : la récursivité supprime le répertoire plus l'intégralité de son contenu !

Le légendaire Move

Directory.Move(PathSource As String, PathDest As String)

Même principe que pour les fichiers, avec les répertoires cette fois-ci : déplace le dossier et son contenu vers le nouveau Path.

Fonctions d'exploration

Bien, vous savez maintenant manipuler les fichiers et les répertoires, mais il va falloir associer les deux pour pouvoir rendre vos programmes exportables et adaptables aux environnements.

Nous allons donc apprendre à chercher dans un dossier spécifié les sous-dossiers et les fichiers qu'il contient.
Bref, cela va nous permettre de pouvoir nous représenter notre arborescence. Nous allons également créer un petit programme permettant de représenter l'arborescence de notre disque.

Commençons donc avec les fonctions.

Rechercher tous les dossiers contenus dans le dossier spécifié

Directory.GetDirectories(Path as String)

Renvoie un tableau de string contenant le Path de tous les dossiers qui sont contenus dans le dossier spécifié.

Rechercher tous les fichiers contenus dans un dossier spécifié

Directory.GetFiles(Path as String)

Comme pour au-dessus, même remarque, le Path renvoyé correspond à celui que vous avez passé en argument. Renvoie les fichiers avec leur extension.

Un rapide bout de code permet de lister les fichiers présents en utilisant cette fonction :

For Each Fichier As String In Directory.GetFiles("c:/")
            MsgBox(Fichier)
        Next

Tout d'abord, explorons notre arborescence avec une commande toute faite dans notre invite de commande Windows. La commande shell (commande spécifique à Windows) s'appelle Tree. Elle donne un résultat similaire à la figure suivante.

Vous n'avez pas besoin d'utiliser cette commande, c'est pour vous montrer l'arborescence du dossier dans lequel nous allons faire notre mini-TP.

Nous allons donc retrouver notre arborescence de manière à se retrouver avec le même schéma, le tout grâce à un algorithme.
Je vous ai déjà parlé du principe d'un algorithme. Eh bien, nous allons devoir en trouver un pour pouvoir effectuer ce listage.
Nous récupérerons les informations et les afficherons dans un TreeView (ça vous donnera l'occasion de découvrir un nouveau contrôle), spécifiquement conçu pour effectuer des arborescences (avec des parents et des enfants).

Pour résumer, dans le TreeView : un dossier correspondra à un nœud principal (on peut cliquer dessus pour le « déplier »), et un fichier sera un nœud simple, pas de possibilité de le « déplier ».

C'est un programme très basique, sa base pourra être utilisée dans d'autres programmes qui nécessitent une exploration des répertoires.

Donc, passons à l'algorithme. Je ne suis pas là pour vous apprendre les rudiments et normes de l'algorithmie, j'aimerais juste un peu de logique de votre part, peu importe comment vous vous représentez ce qu'il va y avoir à faire (schéma, texte, dessin…).

Le tout est de comprendre ce qu'on va devoir effectuer comme action et appeler comme fonctions.

Un algorithme version texte tout simple

Parcourir le répertoire, pour chaque dossier ajouter un nœud principal, pour chaque fichier ajouter un nœud simple.
Répéter cette action pour chaque répertoire

(Attention, cet algorithme ne respecte pas les normes de l'algorithmie, si vous voulez en savoir plus, de très bon tutos existent sur le SdZ.)

Maintenant il va falloir l'adapter pour le rentrer dans notre code.

Imports System.IO

Public Class Form1

    Const RepertoireALister As String = "."

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Définit le premier nœud
        Me.TV_ARBORESCENCE.TopNode = Me.TV_ARBORESCENCE.Nodes.Add(RepertoireALister, RepertoireALister)

        'Arborescence du premier nœud
        For Each Repertoire As String In Directory.GetDirectories(RepertoireALister)
            Me.TV_ARBORESCENCE.TopNode.Nodes.Add(Repertoire, Path.GetFileName(Repertoire))
            'Récursif
            ListeArborescenceDossier(Repertoire, Me.TV_ARBORESCENCE.TopNode)
        Next
        'Fichiers du premier nœud
        For Each Fichier As String In Directory.GetFiles(RepertoireALister)
            Me.TV_ARBORESCENCE.TopNode.Nodes.Add(Path.GetFileName(Fichier))
        Next
    End Sub

    Sub ListeArborescenceDossier(ByVal RepertoireActuel As String, ByVal NodeActuel As TreeNode)
        'Recupère le node dans lequel on est
        Dim Node As TreeNode = NodeActuel.Nodes(RepertoireActuel)
        'Répertoires de ce nœud
        For Each Repertoire As String In Directory.GetDirectories(RepertoireActuel)
            Node.Nodes.Add(Repertoire, Path.GetFileName(Repertoire))
            'Récursif
            ListeArborescenceDossier(Repertoire, Node)
        Next
        'Fichiers de ce nœud
        For Each Fichier As String In Directory.GetFiles(RepertoireActuel)
            Node.Nodes.Add(Path.GetFileName(Fichier))
        Next
    End Sub

End Class

Expliquons un peu le tout. Tout d'abord « node » en anglais signifie « nœud ».
Le répertoire que je dois explorer en constante, vous pouviez bien évidemment créer une textbox demandant à l'utilisateur quel dossier lister. Le Path que j'ai utilisé est « . », cela signifie le dossier courant, c'est un PathPath relatif.

Vient le Load, je crée d'office un TopNode, autrement dit « le nœud le plus haut », le nœud principal de notre Treeview. J'en profite pour créer un nœud avec : Me.TV_ARBORESCENCE.Nodes.Add(). En premier argument de cette fonction, la « clé » pour identifier le nœud dans le Treeview (cette clé doit avoir un nom unique), et en second le texte qui sera affiché sur mon nœud.

Ensuite, la petite boucle que je vous ai montrée plus haut : je parcours tout les répertoires dans le répertoire à lister, j'ajoute chacun en tant que nœud principal avec comme clé leur Path entier (exemple : ./Dossier1/SousDossier1) donc un nom qui est unique, et en texte le nom du dossier simplement. Nom de dossier que j'ai récupéré en utilisant la classe Path qui donne des méthodes et fonctions pour manipuler les chemins. J'ai utilisé la fonction GetFileName qui renvoie le nom du fichier ou le nom d'un dossier contenu dans un Path.

Puis j'appelle une méthode que je vous exposerai juste après.

Quand il n'y a plus de dossiers on passe aux fichiers, sur le même principe sauf que ces nœuds n'auront pas de nœuds enfants, donc ne seront pas dépliables.

La méthode que j'ai mise juste après, eh bien c'est elle qui va nous permettre d'effectuer la récursivité de notre algorithme à travers tous les sous-dossiers.

Sans elle, on aurait seulement le niveau 0 de notre arborescence de listé (les dossiers et fichiers du répertoire principal) et pas plus loin.

Eh bien, pour ce qui est de la fonction, elle effectue exactement la même chose que ce que je viens d'expliquer, mais où le nom du répertoire et le nœud dans lequel on se trouve actuellement sont passés en paramètres de façon à permettre de la rappeler dynamiquement et pour qu'elle puisse s'adapter aux différents niveaux de l'arborescence.

Et voici le résultat à la figure suivante.

Je tiens juste à vous conseiller d'essayer de comprendre le fonctionnement de ce programme étape par étape (commencez par un seul niveau d'arborescence), vous allez comprendre la démarche qu'il effectue et ce sera un premier et grand pas vers des notions de programmation plus complexes que nous allons aborder dans la partie 3 de ce tutoriel.

Autre conseil pour vous éclaircir le programme : créez des variables intermédiaires dans lesquelles vous vous habituerez à trouver le bon type de variable à employer, les méthodes disponibles sur ce type, pour finalement arriver à tout rassembler, tout en le laissant clair à vos yeux.

Bien, passons aux fichiers de configuration. Peut-être que certains d'entre vous ont déjà vu les fichiers de configuration standard de Windows : les fichiers .ini. Ils ont été utilisés par Windows pour définir les paramètres de configuration. Ce sont de simples fichiers contenant du texte, mais au lieu d'avoir l'extension basique de texte .txt, ils ont une extension .ini.

Petite parenthèse sur les extensions : elles ne définissent pas obligatoirement le contenu du fichier, les fichiers .jpg contiennent habituellement des images et ont l'habitude d'être ouverts par des logiciels de dessin ou de visualisation d'images, mais ils peuvent très bien contenir du texte et être ouverts avec le bloc-notes.

Les fichiers .ini contiennent donc du texte, mais formaté d'une certaine manière ; nous allons étudier ce formatage ici.

Exemple de mon fichier Win.ini

; for 16-bit app support
[fonts]
[extensions]
[mci extensions]
[files]
[Mail]
MAPI=1
[MCI Extensions.BAK]
3g2=MPEGVideo
3gp=MPEGVideo
3gp2=MPEGVideo
3gpp=MPEGVideo
aac=MPEGVideo
adt=MPEGVideo
adts=MPEGVideo
m2t=MPEGVideo
m2ts=MPEGVideo
m2v=MPEGVideo
m4a=MPEGVideo
m4v=MPEGVideo
mod=MPEGVideo
mov=MPEGVideo
mp4=MPEGVideo
mp4v=MPEGVideo
mts=MPEGVideo
ts=MPEGVideo
tts=MPEGVideo

Explications

Le contenu d'un fichier de configuration .ini contient trois types de lignes :

• Les lignes commençant par « ; » sont des commentaires, elles ne sont pas prises en compte pendant le traitement du fichier.

• Les lignes où il y a des crochets : « [ » et « ] » définissent une nouvelle section. Cela permet d'organiser un minimum notre fichier .ini.

• Finalement les lignes de clé, les plus importantes, elles contiennent les variables que nous stockons. Par exemple MAPI=1 signifie que la variable (ou clé) MAPI est égale à 1.

Bon, vous voyez maintenant le principe d'un fichier de configuration. À quoi diable va-t-il nous servir ? Eh bien simplement à garder des paramètres du programme même s'il y a eu un arrêt de ce dernier.

Bien, vous voilà donc avec une petite norme à respecter pour stocker vos informations de configuration (ça ne fait pas de mal de temps en temps).

Nous allons passer à un TP conséquent et qui va vous demander de réviser vos notions sur les fichiers. C'est juste après.

• File et Directory sont des objets destinés à contenir respectivement des fichiers et des répertoires.

• Vous pouvez récupérer les fichiers d'un répertoire par la commande Directory.GetFiles().

C'est parti pour le cahier des charges ! En premier lieu je vais vous décrire ce que notre programme sera susceptible de faire.

Tout d'abord ce programme est un programme d'auto-backup, autrement dit de sauvegarde automatique. Ce programme sera capable de sauvegarder périodiquement un ou des dossiers que nous spécifierons dans une liste.

Pour commencer nous n'allons pas chercher bien loin : nous allons juste créer un répertoire dans lequel nous entasserons nos sauvegardes (répertoire spécifié par l'utilisateur). Essayez de ranger et de trier les différentes sauvegardes, pourquoi pas avec la date et l'heure.

Je laisse libre cours à votre imagination, à vous de voir si une seconde fenêtre est préférable pour spécifier la configuration, etc.

En parlant de configuration, après nos deux chapitres sur les fichiers, j'aimerais que vous sauvegardiez les paramètres de configuration de ce petit programme dans un fichier .ini. Je vous laisse également choisir la structure qu'aura ce fichier, les choses que vous allez avoir à y insérer, etc.

Pour le choix des dossiers, je ne vous en avais pas parlé avant, mais un petit module très pratique existe : le FolderBrowserDialog.

Dans la boîte à outils, section boîtes de dialogue. Ce module ouvre une boîte de dialogue, demandant à l'utilisateur de sélectionner un dossier. Il a également la possibilité d'en créer un par la même occasion. Vous pouvez récupérer le dossier sélectionné avec FolderBrowserDialog.SelectedPath où FolderBrowserDialogest le nom de votre contrôle.

Pour ce qui est de la liste des dossiers à sauvegarder, vous pouvez les insérer dans une listbox ou une textbox multilignes, au choix.

Pour le reste, je vous laisser agrémenter au choix et selon vos goûts.

Je dois dire que vous avez toutes les compétences et les méthodes de réflexion (savoir trouver les propriétés qui vous seront utiles) requises. Essayez de ne pas vous décourager trop rapidement et de ne pas aller trop vite à la correction.

Eh bien, amis Zéros, au travail !

Commençons par mon interface (voir figure suivante) et par les fonctionnalités que mon programme contient.

Comme vous le voyez, j'ai une listbox qui me permet de lister les répertoires dont je veux la sauvegarde. Vient ensuite un bouton d'ajout et de suppression des répertoires, l'ajout se fait par FolderBrowserDialog, la suppression par lignes sélectionnées dans la listbox. Ensuite, un petit menu de configuration dans lequel on spécifie le dossier où placer les sauvegardes. Lors du clic sur la textbox un FolderBrowserDialog s'ouvre et c'est sa sélection qui remplira la textbox. Après se trouvent des NumericUpDown(un contrôle) permettant de spécifier un nombre avec le clavier ou grâce à des boutons haut et bas. Puis un bouton pour enregistrer la configuration et un second pour effectuer une sauvegarde manuelle.

Je vais vous montrer le code tout de suite, on développera ensuite section par section.

Imports System.IO

Public Class ZBackup

    'Définit les constantes
    Const FichierIni As String = "Zbackup.ini"
    Const LignesFichierIni As Integer = 6
    Const CleSavePath As String = "SavePath"
    Const CleTempSave As String = "TempSave"
    Const CleNbSaves As String = "NbSaves"
    Const ClePaths As String = "Paths"

    Private Sub ZBackup_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        'Configure le timer
        Me.TIM_SAVE.Interval = Me.NUM_SAVETIME.Value * 3600000 'Convertir une heure une milisecondes
        Me.TIM_SAVE.Enabled = True

        'Recupère la configuration enregistrée
        If RecupereInfosFichierIni() Then
            'Effectue d'office une sauvegarde
            Sauvegarde()
        End If

    End Sub

#Region "Interface"

    Private Sub TXT_SAVEPATH_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TXT_SAVEPATH.Click

        'Ajoute la ligne seulement si un dossier a été sélectionné dans le dialogue
        If Me.BD_DOSSIER.ShowDialog() Then
            Me.TXT_SAVEPATH.Text = Me.BD_DOSSIER.SelectedPath
        End If

    End Sub

    Private Sub BT_AJOUT_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_AJOUT.Click

        'Ajoute la ligne seulement si un dossier a été sélectionné dans le dialogue
        If Me.BD_DOSSIER.ShowDialog Then
            Me.LB_PATHSASAVE.Items.Add(Me.BD_DOSSIER.SelectedPath)
        End If

    End Sub

    Private Sub BT_SUPPR_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_SUPPR.Click

        'Vérifie si une ligne est sélectionnée dans la listbox
        If Not Me.LB_PATHSASAVE.SelectedItem Is Nothing Then
            Me.LB_PATHSASAVE.Items.Remove(Me.LB_PATHSASAVE.SelectedItem)
        Else
            MsgBox("Selectionnez un path à supprimer")
        End If

    End Sub

    Private Sub BT_SAVECFG_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_SAVECFG.Click
        SauvegardeFichierIni()
    End Sub

    Private Sub TIM_SAVE_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TIM_SAVE.Tick
        'Sauvegarde avec le timer
        Sauvegarde()
    End Sub

    Private Sub BT_MANUSAVE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_MANUSAVE.Click
        'Sauvegarde manuelle
        Sauvegarde()
    End Sub

#End Region

#Region "FichierIni"

    Sub SauvegardeFichierIni()
        'Vérification sur le path de sauvegarde
        If Me.TXT_SAVEPATH.Text = "" Then
            MsgBox("Veuillez selectionner un path de sauvegarde")
        ElseIf Not Directory.Exists(Me.TXT_SAVEPATH.Text) Then
            MsgBox("Path de sauvegarde invalide")
        Else
            'La fonction recrée le fichier quoi qu'il arrive
            File.WriteAllLines(FichierIni, CreeStructureFichierIni(Me.TXT_SAVEPATH.Text, Me.NUM_SAVETIME.Value, Me.NUM_NBSAVE.Value, Me.LB_PATHSASAVE.Items))
        End If
    End Sub

    Function CreeStructureFichierIni(ByVal SavePath As String, ByVal TempsSave As Integer, ByVal Nbsaves As Integer, ByVal PathsASave As ListBox.ObjectCollection) As String()

        'Crée un tableau du nombre de lignes requises
        Dim FichierIni(LignesFichierIni + PathsASave.Count) As String
        'Remplit la structure du fichier ini
        FichierIni(0) = ";Fichier de configuration du Zbackup"
        FichierIni(1) = "[configuration]"
        FichierIni(2) = CleSavePath & "=" & SavePath
        FichierIni(3) = CleTempSave & "=" & TempsSave
        FichierIni(4) = CleNbSaves & "=" & Nbsaves
        FichierIni(5) = ""
        FichierIni(6) = "[paths]"
        'Remplit dynamiquement les paths souhaités
        Dim Compteur As Integer = LignesFichierIni
        For Each Path As String In PathsASave
            Compteur += 1
            FichierIni(Compteur) = ClePaths & Compteur - LignesFichierIni & "=" & Path
        Next

        Return FichierIni

    End Function

    Function RecupereCleFichierIni(ByVal Cle As String) As String

        For Each Ligne As String In File.ReadAllLines(FichierIni)
            'Découpe la ligne au niveau de « = » (s'il existe), 
            'compare la première partie de la ligne (soit la clé)
            If Ligne.Split("=")(0) = Cle Then
                'Recupère la seconde partie de la ligne (soit la valeur)
                Return Ligne.Split("=")(1)
            End If
        Next
        'Sinon ne retourne rien
        Return ""

    End Function

    Function RecupereInfosFichierIni() As Boolean

        'Vérification de la présence du .ini
        If File.Exists(FichierIni) Then
            'Récuperation
            Dim SavePath As String = RecupereCleFichierIni(CleSavePath)
            Dim TempSAve As String = RecupereCleFichierIni(CleTempSave)
            Dim NbSaves As String = RecupereCleFichierIni(CleNbSaves)
            Dim Paths(100) As String
            Dim i As Integer = 0 '0 car le premier path est à 1 et on incrémente avant
            Do
                i += 1
                Paths(i - 1) = RecupereCleFichierIni(ClePaths & i)
            Loop While Paths(i - 1) <> ""
            'Donc nombre de paths valides : i-1

            'Vérification
            If (SavePath <> "") And (TempSAve <> "") And (NbSaves <> "") And (i - 1 > 0) Then
                'Attribution
                Me.TXT_SAVEPATH.Text = SavePath
                Me.NUM_NBSAVE.Value = NbSaves
                Me.NUM_SAVETIME.Value = TempSAve
                'Nettoie le LB, puis le remplit
                Me.LB_PATHSASAVE.Items.Clear()
                For j As Integer = 0 To i - 1
                    Me.LB_PATHSASAVE.Items.Add(Paths(j))
                Next
            Else
                'Sinon notification
                MsgBox("Le fichier " & FichierIni & " est corrompu, utilisation des paramètres par défaut")
                Return False
            End If
        Else
            'Sinon notification
            MsgBox("Le fichier " & FichierIni & " n'a pas été trouvé, utilisation des paramètres par défaut")
            Return False
        End If

        Return True

    End Function

#End Region

#Region "Sauvegarde"

    Sub Sauvegarde()

        'Vérifie les paramètres
        If Directory.Exists(Me.TXT_SAVEPATH.Text) Then
            'Vérifie le nombre de sauvegardes
            'Supprime la plus vieille si limite atteinte
            NettoieNbSaves()

            'Si le dernier caractère de la chaîne est un « \ », on le supprime
            If Me.TXT_SAVEPATH.Text.EndsWith("\") Then
                Me.TXT_SAVEPATH.Text.Trim("\")
            End If
            'Crée le dossier de sauvegarde avec un nom spécifié
            'Supprime les « / » et « : » de la date et de l'heure
            Dim DossierSave As String = Me.TXT_SAVEPATH.Text & "\Sauvegarde du " & Date.Now.ToShortDateString.Replace("/", "-") & " a " & Date.Now.ToShortTimeString.Replace(":", "-")
            If Not Directory.Exists(DossierSave) Then 's'il existe deux sauvegardes dans la même minute, on ne la fait pas
                Directory.CreateDirectory(DossierSave)
                'Pour chaque path demandé, copie son dossier
                For Each PathASave As String In Me.LB_PATHSASAVE.Items
                    If Directory.Exists(PathASave) Then
                        CopieDossier(New DirectoryInfo(PathASave), New DirectoryInfo(DossierSave & "\" & Path.GetFileName(PathASave)))
                    End If
                Next
            End If
        Else
            MsgBox("Sauvegarde échouée : le path de sauvegarde est invalide, veuillez le redéfinir")
        End If

    End Sub

    Sub NettoieNbSaves()

        Dim Compteur As Integer = 1
        For Each Repertoire As String In Directory.GetDirectories(Me.TXT_SAVEPATH.Text)
            'Si le répertoire est un répertoire de sauvegarde
            If Path.GetFileName(Repertoire).Contains("Sauvegarde") Then
                'Incrémentation du compteur
                Compteur += 1
            End If
        Next

        If Compteur > Me.NUM_NBSAVE.Value Then
            'Détermination du plus ancien
            Dim PlusAncien As DirectoryInfo
            Dim DatePlusAncienne As Date = Date.Now
            For Each Repertoire As String In Directory.GetDirectories(Me.TXT_SAVEPATH.Text)
                'Si le répertoire est un répertoire de sauvegarde
                If Path.GetFileName(Repertoire).Contains("Sauvegarde") Then
                    'Si le répertoire est plus ancien que le précédent
                    If (Directory.GetCreationTime(Repertoire) < DatePlusAncienne) Then
                        'On le place en plus ancien
                        DatePlusAncienne = Directory.GetCreationTime(Repertoire)
                        PlusAncien = New DirectoryInfo(Repertoire)
                    End If
                End If
            Next

            'Supprime le plus vieux
            If PlusAncien.Exists Then
                PlusAncien.Delete(True)
            End If
        End If

    End Sub

    Sub CopieDossier(ByVal DossierSource As DirectoryInfo, ByVal DossierDesination As DirectoryInfo)

        'Crée le dossier
        DossierDesination.Create()

        'Copie les fichiers
        For Each Fichier As FileInfo In DossierSource.GetFiles()
            Fichier.CopyTo(Path.Combine(DossierDesination.FullName, Fichier.Name))
        Next

        'Recommence pour les sous-répertoires
        For Each SousRepertoire As DirectoryInfo In DossierSource.GetDirectories()
            CopieDossier(SousRepertoire, DossierDesination.CreateSubdirectory(SousRepertoire.Name))
        Next

    End Sub

#End Region

End Class

Eh bien, ça devient volumineux !

Comme vous pouvez le voir dès la première ligne, j'ai essayé de rendre le programme « flexible ». Autrement dit, il me suffit de changer les constantes pour changer le nom du fichier ini par exemple, c'est cette constante qui est utilisée à chaque fois qu'une fonction demande le nom de ce fichier.

Trois grandes sections se distinguent :

• L'interface, contenant la réaction aux boutons, etc.

• Le fichier ini, contenant tout ce qui touche à la configuration.

• Finalement, la sauvegarde.

Une rapide vue d'ensemble du fonctionnement :

• Récupération de la configuration :

• Si elle n'existe pas, création du fichier ini ;

• Si elle est corrompue, recréation du fichier ini.

• À chaque tick de timer (timer configuré sur le temps souhaité entre deux sauvegardes), on effectue la sauvegarde ;

• Avec le bouton de sauvegarde manuelle, la même action est réalisée ;

• La sauvegarde consiste à créer un dossier sous la forme Sauvegarde du DD-MM-AAAA a HH-MM ;

• Puis copie l'intégralité des dossiers en respectant leur arborescence.

L'interface

Voilà donc, commençons par l'analyse la plus simple : celle de l'interface.

Première information : l'ouverture de la FolderBrowserDialog lors du clic sur la textbox.
Eh bien, rien de sorcier, l'événement Click de la textbox !

Private Sub TXT_SAVEPATH_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TXT_SAVEPATH.Click

        'Ajoute la ligne seulement si un dossier a été sélectionné dans le dialogue
        If Me.BD_DOSSIER.ShowDialog() Then
            Me.TXT_SAVEPATH.Text = Me.BD_DOSSIER.SelectedPath
        End If

    End Sub

Lors du clic, on se sert du contrôle BD_DOSSIER qui est mon FolserBrowserDialog. Vu que c'est une boîte de dialogue, c'est la fonction ShowDialog qui est appelée. Puis on récupère la sélection avec la propriété SelectedPath.

Le bouton d'ajout a le même principe, mais il agit sur la listbox, sur le même principe que le treeview que nous avons étudié auparavant ; il faut créer, non plus des Nodes, mais des Items.

Me.LB_PATHSASAVE.Items.Add(Me.BD_DOSSIER.SelectedPath)

C'est dans le membre Items que les fonctions spécifiques à ces objets sont trouvables. La méthode Add() permet d'ajouter un item, avec comme valeur le dossier sélectionné.

Pour la suppression :

'Vérifie si une ligne est sélectionnée dans la listbox
        If Not Me.LB_PATHSASAVE.SelectedItem Is Nothing Then
            Me.LB_PATHSASAVE.Items.Remove(Me.LB_PATHSASAVE.SelectedItem)
        Else
            MsgBox("Selectionnez un path à supprimer")
        End If

Vous vous apercevez qu'une vérification est faite pour voir si une ligne est sélectionnée avec If Not Me.LB_PATHSASAVE.SelectedItem Is Nothing Then . Vous vous apercevez que je n'utilise pas le symbole « <> » pour dire différent, mais not… is nothing. C'est une autre notation plus littérale, tout dépend des goûts de chacun.
Ensuite on supprime avec Items.Remove en passant comme paramètre la ligne sélectionnée.

Pour les autres boutons, la sauvegarde des paramètres appelle la méthode SauvegardeFichierIni(), que nous allons étudier. Le timer et la sauvegarde manuelle appellent la méthode Sauvegarde(), que nous allons aussi étudier.

Sauvegarde en fichier .ini

Attaquons tout de suite la sauvegarde.

Pour ce qui est de cette sauvegarde, je vérifie la présence d'un dossier dans la textbox et si ce dossier est valide. Ensuite j'appelle la fonction File.WriteAllLines(FichierIni, CreeStructureFichierIni(Me.TXT_SAVEPATH.Text, Me.NUM_SAVETIME.Value, Me.NUM_NBSAVE.Value, Me.LB_PATHSASAVE.Items)) qui s'occupe de créer un fichier et d'entrer dedans un tableau de String (une case de tableau pour une ligne).
En premier paramètre, le fichier de destination, c'est notre constante avec le nom du fichier ini. Le second, autrement dit le tableau de String, c'est une fonction que nous allons étudier tout de suite :

Function CreeStructureFichierIni(ByVal SavePath As String, ByVal TempsSave As Integer, ByVal Nbsaves As Integer, ByVal PathsASave As ListBox.ObjectCollection) As String()

        'Crée un tableau du nombre de lignes requises
        Dim FichierIni(LignesFichierIni + PathsASave.Count) As String
        'Remplit la structure du fichier ini
        FichierIni(0) = ";Fichier de configuration du Zbackup"
        FichierIni(1) = "[configuration]"
        FichierIni(2) = CleSavePath & "=" & SavePath
        FichierIni(3) = CleTempSave & "=" & TempsSave
        FichierIni(4) = CleNbSaves & "=" & Nbsaves
        FichierIni(5) = ""
        FichierIni(6) = "[paths]"
        'Remplit dynamiquement les paths souhaités
        Dim Compteur As Integer = LignesFichierIni
        For Each Path As String In PathsASave
            Compteur += 1
            FichierIni(Compteur) = ClePaths & Compteur - LignesFichierIni & "=" & Path
        Next

        Return FichierIni

    End Function

Les valeurs passées en paramètres auraient pu être remplacées par des récupérations directement à l'intérieur de la fonction. Bref, un tableau est créé avec comme taille le nombre de lignes initiales plus le nombre de chemins à insérer. Pour les premières lignes, j'écris manuellement dedans les premières clés. Ce qui nous donne dans le fichier ini une fois créé :

;Fichier de configuration du Zbackup
[configuration]
SavePath=C:\Save
TempSave=1
NbSaves=3

[paths]
Paths1=C:\ASave

Deux sections donc : une configuration, une autre paths.
La section configuration contient le répertoire où sauvegarder, le temps entre deux sauvegardes et le nombre de sauvegardes maximal.
La section paths contient les différents chemins, tous avec un numéro différent. Les techniques peuvent différer, il aurait été possible de mettre tous les chemins sur la même ligne, séparés par des « ; ».

Bref, la création du fichier n'est pas sorcier, le tableau de variables FichierIni() est renvoyé et est écrit dans le fichier.

Maintenant que vous avez vu comment le remplir, voyons comment récupérer les valeurs.

Donc pour cela une petite fonction à laquelle on passe en paramètre la clé à récupérer.

Function RecupereCleFichierIni(ByVal Cle As String) As String

        For Each Ligne As String In File.ReadAllLines(FichierIni)
            'Découpe la ligne au niveau de « = » (s'il existe), 
            'Compare la première partie de la ligne (soit la clé)
            If Ligne.Split("=")(0) = Cle Then
                'Recupère la seconde partie de la ligne (soit la valeur)
                Return Ligne.Split("=")(1)
            End If
        Next
        'Sinon ne retourne rien
        Return ""

    End Function

Principe de cette fonction : on parcourt toutes les lignes du fichier ini, chaque ligne est découpée grâce à la fonction Split().
La fonction Split() s'applique sur une chaîne de caractères, elle permet de « découper » cette chaîne à chaque occurrence du caractère ou de la chaîne passée en argument. Voici un exemple : pour une chaîne de caractères sous la forme Cle1=Valeur1, un Split("=") donnera un tableau de String sous la forme :
Tableau(0) = Cle1
Tableau(1) = Valeur1

Donc un test bête et méchant sur le tableau(0) qui est retourné avec la clé souhaitée nous indique la ligne contenant cette clé. Une fois cette ligne atteinte, le tableau(1), celui contenant la valeur, est retourné.
Si la clé n'est pas trouvée, on retourne "".

Il fallait y penser.

Sauvegarde

Attaquons maintenant le principe de la sauvegarde.

La méthode Sauvegarde() effectue diverses vérifications sur la présence des dossiers, elle crée le dossier dans lequel la sauvegarde va être placée et lance la méthode CopieDossier() que voici :

Sub CopieDossier(ByVal DossierSource As DirectoryInfo, ByVal DossierDesination As DirectoryInfo)

        'Crée le dossier
        DossierDesination.Create()

        'Copie les fichiers
        For Each Fichier As FileInfo In DossierSource.GetFiles()
            Fichier.CopyTo(Path.Combine(DossierDesination.FullName, Fichier.Name))
        Next

        'Recommence pour les sous-répertoires
        For Each SousRepertoire As DirectoryInfo In DossierSource.GetDirectories()
            CopieDossier(SousRepertoire, DossierDesination.CreateSubdirectory(SousRepertoire.Name))
        Next

    End Sub

Cette méthode prend comme arguments des variables de type DirectoryInfo. Ce ne sont pas des variables communes : ce sont des objets. Il faut donc les instancier avec un New.

Lors de l'appel de la ligne avec CopieDossier(New DirectoryInfo(PathASave), New DirectoryInfo(DossierSave & "\" & Path.GetFileName(PathASave))), j'instancie deux objets avec comme paramètres les chemins des dossiers voulus.

Une fois dans la méthode de copie, un dossier est tout d'abord créé, les fichiers contenus y sont copiés également, puis cette action est répétée pour tous ses sous-répertoires. De la même manière que le treeview du chapitre précédent.

Il y a finalement la méthode de nettoyage des sauvegardes (si on ne demande qu'un certain nombre de sauvegardes). Elle parcourt les répertoires créés, récupère la date de création de chacun, identifie le plus vieux et le supprime en utilisant la récursivité de la méthode Directory.Delete.

Eh bien voilà, le code est décortiqué.

Allons un peu plus loin.

Bien, procédons à un récapitulatif des fonctions que vous allez pouvoir utiliser dans vos futurs programmes pour créer et gérer un fichier .ini, je ne pense pas revenir dessus par la suite, autant tout résumer tout de suite.

La création

Tout d'abord pour la création du fichier ini.

Deux manières de procéder : la création manuelle en utilisant une fonction du genre :

Function CreeStructureFichierIni(ByVal SavePath As String, ByVal TempsSave As Integer, ByVal Nbsaves As Integer, ByVal PathsASave As ListBox.ObjectCollection) As String()

        'Crée un tableau du nombre de lignes requises
        Dim FichierIni(LignesFichierIni + PathsASave.Count) As String
        'Remplit la structure du fichier ini
        FichierIni(0) = ";Fichier de configuration du Zbackup"
        FichierIni(1) = "[configuration]"
        FichierIni(2) = CleSavePath & "=" & SavePath
        FichierIni(3) = CleTempSave & "=" & TempsSave
        FichierIni(4) = CleNbSaves & "=" & Nbsaves
        FichierIni(5) = ""
        Return FichierIni

    End Function

Cette fonction est appelée manuelle, car vous voyez que chaque ligne doit être écrite côté programmatique.
Très pratique et très visuel pour le programmeur, mais beaucoup moins agréable lorsque vous avez 100 clés de configuration à entrer.

Une autre méthode consiste à passer un tableau à deux dimensions de String, deux colonnes et autant de lignes que de clés.
La première colonne contenant les clés, la seconde les valeurs.

Un rapide algorithme vous construit le même tableau de lignes que vous écrirez dans votre fichier avec WriteAllLines().

Function CreeStructureFichierIni(ByVal ClesValeurs(, ) As String) As String()
		
	Dim Ligne(10) As String
	'Par exemple ClesValeurs a deux dimensions sous la forme : (1, 10)
        'On divise la taille par 2, car elle correspond à l'ensemble des cellules et on a  2 colonnes, donc cellules / 2 = nbligne
	For i As Integer = 0 To te.Length / 2 
            Ligne(i) = ClesValeurs(0,i) & "=" & ClesValeurs(1,i)
        Next

    End Function

Mais ce genre d’algorithme est à faire par vos soins, il n'est pas très compliqué, mais demande un léger travail de recherche.

La récupération de valeurs

Passons tout de suite à la récupération des valeurs.

Ma fonction faite dans ce TP devrait amplement suffir :

Function RecupereCleFichierIni(ByVal Cle As String) As String

        For Each Ligne As String In File.ReadAllLines(FichierIni)
            'Découpe la ligne au niveau de « = »  (s'il existe), 
            'compare la première partie de la ligne (soit la clé)
            If Ligne.Split("=")(0) = Cle Then
                'Recupère la seconde partie de la ligne (soit la valeur)
                Return Ligne.Split("=")(1)
            End If
        Next
        'Sinon ne retourne rien
        Return ""

    End Function

On passe la clé souhaitée en argument, on récupère sa valeur.

Eh bien, je pense que vous avez les éléments en main pour créer les fichiers ini de tous nos prochains TP ! :diable:

Bon, je ne vais pas continuer l'évolution, car le code me suffit amplement ainsi.

Cette petite idée de TP m'est venue lors d'un après-midi de programmation. J'ai l'habitude de sauvegarder régulièrement mon travail, mais après une fausse manip tout mon projet s'est retrouvé irrécupérable, impossible de faire machine arrière. Ce petit programme effectuant des sauvegardes périodiques du travail aurait pu m'éviter cette erreur.

Bien, passons aux améliorations possibles.

Tout d'abord une sauvegarde plus propre et moins lourde.

Eh bien je suppose que vous avez déjà entendu parler de la compression zip. Elle convertit des dossiers et des fichiers en un seul fichier zip. On dit alors que nos fichiers sont compressés sous zip.

Je ne vais pas vous aider plus sur cette voie, car elle est réservée à ceux qui souhaitent effectuer un peu de recherche. Je vais juste vous donner quelques voies.

La première étant l'utilisation du namespace Compressioncontenu dans IO. Assez difficile à utiliser à mon avis, très fastidieux à mettre en place.

La seconde étant l'utilisation de l'utilitaire 7zip, utilitaire open source et gratuit.
Voici sa fiche Clubic : 7zip.

Cet utilitaire dispose d'une interface graphique, mais aussi d'une utilisation en lignes de commande.

Les commandes (arguments) possibles avec l'exécutable 7z.exe sont visibles à la figure suivante.

Cette manipulation est réservée aux plus expérimentés d'entre vous, il va falloir combiner commandes et chemins de fichiers dans une fonction VB nommée Shell() permettant l'éxécution de programmes shell.

Exemple : si votre 7z.exe est dans le dossier de votre programme, il faudra utiliser Shell("7z.exe a MonArchive.zip MonFichierAZipper").

Je vous laisse explorer cette voie qui semble prometteuse.

Reste ensuite comme améliorations possibles un écran supplémentaire listant les sauvegardes effectuées et la possibilité de restaurer l'une d'entre elle.

Également : une exécution de ce programme en arrière-plan, voire en tant que service.

Pour l'arrière-plan, il faudra déjà s'employer à rendre la forme principale à Visible = false.
Puis créer une icône contextuelle, un contrôle tout fait existe, cherchez dans votre boîte à outils.
Puis récupérer l'événement correspondant au clic ou au double-clic sur cette icône pour faire repasser votre forme à Visible = true.

Finalement le lancement au démarrage : il faut créer un raccourci de votre programme ou placer votre programme dans le dossier
C:\Users\@VOTREUSER@\AppData\Roaming\Microsoft\Windows\Start Menu\Programs.

Que d'améliorations possibles ! En y passant un peu de temps votre programme peut devenir une véritable sauvegarde périodique de vos données vitales, tout en restant discret et rapide. Et puis lors de notre partie concernant le réseau, une sauvegarde sur un FTP ou un serveur sera envisageable.

Voilà amis Zéros, bonne chance !

Je suppose qu'arrivés à cette partie vous vous demandez pourquoi vous changeriez de méthode de programmation. C'est vrai après tout, celle que nous utilisions fonctionnait très bien jusqu'à maintenant, alors pourquoi ne pas continuer ?

La méthodologie de programmation que nous avons vue jusqu'à présent est très bonne, nous avons même vu quels genres de programmes nous étions capables de réaliser en suivant ce concept. Mais d'un autre côté… il y a plein de choses qui sont impossibles ou très difficilement réalisables en programmant de cette façon.

Vous imaginez créer un jeu comme ça ? Même le plus basique des jeux de rôles vous prendrait des heures de travail pour un résultat que la POO vous apporterait sur un plateau.

Bref, je m'égare, je vais essayer de vous expliquer plus en détail ce qu'est le fabuleux monde de l'orienté objet.

Mesdames, Messieurs, Sa Majesté POO

Je rappelle pour ceux qui ont tendance à sauter des chapitres entiers : POO = programmation orientée objet.

Jusqu'à maintenant nous avons fait de la programmation procédurale. Pour faire simple, ce principe se base sur les procédures et fonctions. Vous avez remarqué que pendant tous nos TPs chaque « action » à effectuer était souvent décomposée en un sous-ensemble de fonctions et procédures (Sub). C'est cela la programmation procédurale.

Comme vous le voyez sur le schéma présent à la figure suivante, ces fonction s'imbriquent les unes aux autres. Pour le moment, aucun problème. Mais lorsque nous attaquerons de gros projets, cette structure va devenir un véritable capharnaüm .

C'est pourquoi Alan Kay se décida à révolutionner la façon de programmer en élaborant la programmation orientée objet. Comme son nom l'indique, nous allons créer des objets. Mais tout d'abord qu'est-ce qu'un objet programmatiquement parlant ?

Nos nouveaux amis : les objets

Dans la vie de tous les jours, vous voyez ce qu'est un objet ? Eh bien en programmation, le concept reste le même. Je m'explique.

Nous allons créer des objets qui vont nous permettre de rassembler des groupes de procédures ou fonctions appartenant à la même famille. En gros, si nous voulons contrôler une voiture, nous pouvons, avec nos connaissances actuelles, créer des dizaines de fonctions pour faire avancer, reculer, tourner, freiner notre voiture. Mais si nous en voulons une seconde nous allons être obligés de recommencer.

Avec le concept d'objet, nous programmons des fonctions qui seront liées à l'objet Voiture ; après peu importe que l'on décide d'en faire 1 ou 100, il n'y aura pas à recommencer. Imaginez un gâteau. Nous allons coder le « moule » du gâteau. Une fois créé, il sera capable de nous fabriquer des dizaines de gâteaux.

Vous avez utilisé pas mal d'objets jusqu'à maintenant, comme la classe File par exemple. Le moule de File nous a permis de créer des dizaines de File et de les manipuler séparément.

Retournons à notre voiture. Notre moule, en Visual Basic, se nomme la classe. La classe contient un constructeur (ce qui se produit lorsque l'on crée notre objet, en l'occurence notre voiture) et il y a la possibilité de mettre un destructeur (je pense que vous avez compris son utilité).

Ces méthodes seront présentes dans le fichier de la classe. On peut également ajouter beaucoup d'autres fonctions ou Sub à notre classe. Une fonction pour faire avancer notre voiture, une autre pour la faire reculer, nous pouvons également déclarer des variables qui seront utilisables seulement par cette classe.

Ce qu'il va bien falloir comprendre et essayer d'appréhender, c'est ce qui se passe en interne, dans la classe, et ce qui va se passer à l'extérieur.

Dans une classe, il y a une partie considérée comme privée, qui ne sera accessible que par elle-même. Cette partie contient des fonctions ou des variables, pour faire avancer la voiture. Il va falloir un énorme travail en interne pour qu'au final on ait juste à « appuyer sur une touche » pour que la voiture bouge.

Vient ensuite la partie publique, ce qui sera visible par le reste du programme. Sur notre voiture, la fonction Avancer sera publique, on pourra l'appeler de l'extérieur sous la forme MaVoiture.Avancer (où MaVoiture est la voiture créée avec le moule auparavant).

Eh bien, en faisant ça, c'est le principe fondamental de l'orienté objet auquel vous vous attaquez : l'encapsulation. L'encapsulation est le terme employé pour dire : « ce que la classe fait en interne, c'est du domaine du privé ».

Pour la voiture, le moteur, la boîte de vitesses, etc., bref tout ce qui la fait fonctionner en « interne », ne doit pas être accessible à l'utilisateur, sinon il n'y a plus aucun intérêt. L'utilisateur doit seulement avoir accès aux pédales et au levier de vitesses.

Les fonctions se passant en interne sont les attributs, celles visibles depuis l'extérieur sont les méthodes.

Il existe d'autre mots « préfixes » que nous pourrons employer avant nos déclarations. Il y a Shared, Protected… Mais pour le moment intéressons-nous uniquement à Private et Public.

Je comprends tout à fait que cette notion d'objet soit très dure à appréhender, je ne vais donc pas vous brusquer pour le moment. Je vais juste vous expliquer comment nous allons créer nos objets. Personnellement je crée un nouveau fichier par objet, mais si vos objets sont petits, vous pouvez les rassembler en un seul.

Une déclaration de classe (notre moule) s'effectue avec :

Public Class MaClasse

End Class

Vous voyez que même sur la déclaration de la classe on peut spécifier « publique » ou « privée ». Notre classe doit créer des objets qui seront accessibles depuis tout le programme, laissons-la en publique.

Je vous expliquerai plus tard dans quels cas de figure le Private sera de mise pour déclarer une classe.

Notre classe va contenir des variables et des fonctions qu'elle poura utiliser. Des membres et des attributs en langage technique. Pour les créer ce sera comme ce que nous avons vu jusqu'à présent. Un préfixe d'accessibilité (public, private…), un Dim pour les variables, Sub pour les fonctions ne renvoyant rien et Function pour les fonctions.

Le constructeur

Le constructeur est la méthode qui va être appelée à l'instanciation de l'objet ; au moment où nous ferons = New MaClasse, ce seront des arguments que l'on pourra spécifier de cette manière :

= New MaClasse(ArgumentConstructeur1, ArgumentConstructeur2)

Comme une fonction qui demande des arguments, le constructeur réagira de la même manière. Il récupèrera les informations passées en arguments et en fera ce qu'il veut, les attribuer à des membres privés par exemple. Je vous expliquerai bientôt comment le coder et l'utiliser.

Le destructeur

Le destructeur est particulier, il est surtout utilisé pour libérer les ressources mémoire allouées à l'objet juste avant sa destruction. Lorsque nous utiliserons les bases de données par exemple, il faudra se servir du destructeur pour fermer et libérer la connexion si elle a été établie pour cette classe.

Bref, voici ce qui explique son utilité : les variables qui sont créées pour la classe sont automatiquement libérées de la mémoire quand elles « meurent ».

L'objet sera détruit si la valeur Nothing lui est affectée ou s'il arrive à la fin de sa portée (fin d'une fonction dans laquelle il a été créé) par exemple, comme pour les variables normales.

• La programmation orientée objet est basée sur le concept de classes.

• Les accessibilités permettent au programmeur de ne pas accéder aux membres d'une classe qu'il ne doit pas modifier.

Pour commencer notre entrée dans le monde des classes, je vous propose d'attaquer tout de suite sur un petit thème. Pourquoi pas Mario ? Nous allons essayer de faire bouger Mario pour commencer.

Logiquement, puisque nous sommes sur la partie traitant de la POO, notre Mario sera… un objet !

La classe

Créons tout de suite notre « moule » de Mario.

Créez donc un nouveau projet, toujours Windows Forms. Ajoutez ensuite un nouvel élément, comme ce que nous avons fait pour une fenêtre, mais cette fois choisissez Classe, comme le montre la figure suivante.

Nommez tout de suite ce fichier, « Mario » par exemple. Nous voilà donc avec notre classe totalement vide, juste la déclaration de début et de fin.

L'interface

Retournons dans notre fenêtre et ajoutons-y quelques contrôles pour pouvoir commencer (voir figure suivante).

Donc j'ai juste ajouté un petit panel dans lequel j'ai spécifié une taille de 20 x 20, ainsi qu'une couleur de fond rouge. J'ai ajouté en bas un petit bouton qui va nous permettre de déplacer ce panel. Pour le moment uniquement vers la droite.

Vous vous doutez que coder l'événement qui va permettre au bouton de déplacer ce panel ne va pas être sorcier : quelques location à définir et le tour est joué. Oui, mais nous allons définir une classe qui va pouvoir s'adapter à d'autres situations (eh oui, vous pourrez utiliser vos classes dans d'autres programmes.)

Réfléchissons un peu

Pour le moment je vous ne demande pas de créer une classe vous-mêmes, nous n'avons pas encore vu comment faire, nous allons le faire ensemble. Je vous demande juste d'essayer de trouver comment rendre cet objet adaptable.

Mario doit être capable de se déplacer par « cases ». Pour le moment la taille de la case est définie par la taille du panel. Donc si mon panel devient de 50 x 50, une case sera égale à 50 x 50 (les cases sont dans votre imagination, mais vous pouvez placer des lignes de manière à faire une grille). Notre classe ne pourra pas agir directement sur notre panel, c'est toujours le code qui l'a appelé qui va devoir le modifier, notre classe va donc devoir nous renvoyer des coordonnées. Les coordonnées de la nouvelle position de Mario.

Donc si vous avez suivi ma (fastidieuse) réflexion, nous allons devoir travailler avec des variables de type Point, nous aurions pu nous envoyer des Int contenant la position en X et en Y, mais la variable Point rassemble le tout. Nous allons aussi devoir passer à la classe la taille de notre panel, pour qu'elle puisse travailler dynamiquement, quelle que soit la taille de notre Mario.

Bon, trêve de commentaires, allons-y.

Notre classe

Dans notre fichier de classe il va falloir tout d'abord définir un constructeur. Rendez-vous dans le fichier Mario.vb (la classe) et insérez la déclaration du constructeur (avec New). On se place dans le Class Mario et on inscrit :

Sub New()

    End Sub

Voilà notre premier constructeur. Il ne demande aucun argument. Nous ferions tout de même bien de spécifier à la classe la position originelle de notre Mario et sa taille. Pour cela commençons par déclarer des variables en privé, car elles ne seront accessibles qu'à partir de la classe.

Juste en dessous de Public Class Mario, déclarez :

Private _CoordonneesActuelles As Point
    Private _Taille As Size

J'ai donc les coordonnées actuelles de notre Mario de type Point, et la taille de type Size.

C'est une vieille habitude, lorsque je déclare des membres ou des attributs privés, je les précède d'un underscore, mais vous n'êtes pas obligés de faire comme moi.

Ces variables sont déclarées en Global, elles seront donc accessibles partout dans la classe.

Changeons notre constructeur de manière à demander en arguments ces valeurs :

Sub New(ByVal PositionOriginelle As Point, ByVal TailleMario As Size)
        _CoordonneesActuelles = New Point(PositionOriginelle)
        _Taille = New Size(TailleMario)
    End Sub

Et entrons-les dans les variables. Vu que Point et Size sont eux-mêmes des objets, il faut les instancier avec New.

Nous voilà donc avec la taille et les coordonnées de notre Mario.

Je rappelle rapidement ce que sont les méthodes et les attributs. Les méthodes sont des fonctions de type privé, leur nécessité est interne, rien n'est visible depuis l'extérieur. Les attributs sont publics, visibles depuis l'extérieur, accessibles.

Codons quelques fonctions qui vont nous permettre de déplacer notre Mario. À première vue, rien de problématique, on va jouer sur la propriété .X de nos coordonnées pour déplacer Mario en horizontal, .Y pour le vertical. Mais de combien allons-nous le bouger ?

C'est là que notre notion de « case » et de taille intervient. On va le faire bouger d'une case.

Créons une nouvelle fonction de type Public. Cette fonction sera destinée à faire avancer Mario d'une case. Appelons-la donc Avance.

Public Sub Avance()
        _CoordonneesActuelles.X = _CoordonneesActuelles.X + _PasX()
    End Sub

Une petite fonction qui nous renvoie la taille en longueur de Mario (pour savoir quelle est la valeur de la case en longueur). Eh oui, je ne lésine pas sur les fonctions. Elle est précédée d'un underscore car c'est un attribut, elle est private :

#Region "Fonctions privées"

    Private Function _PasX()
        Return _Taille.Width
    End Function

    Private Function _PasY()
        Return _Taille.Height
    End Function

#End Region

Je renvoie simplement la longueur, et pour le _PasY, c'est la hauteur. Si vous avez suivi, cette méthode publique va déplacer Mario d'une case sur la droite. Mais ce n'est pas une fonction, on n'a aucun retour, comment est-ce que notre panel va bien pouvoir se déplacer ? Il va falloir se servir des propriétés.

Vous savez déjà ce que sont les propriétés, vous en assignez tout le temps quand vous modifiez vos contrôles. On va apprendre à faire de même pour nos objets.

La syntaxe de déclaration d'une propriété est assez particulière. Il va falloir gérer lorsqu'on assigne cette propriété et lorsqu'on la récupère. Pour commencer, voici la syntaxe :

Public Property Position()
        Get

        End Get
        Set(ByVal value)

        End Set
    End Property

Vous voyez qu’elle fonctionne comme une fonction sauf qu'à l'intérieur on a deux nouveaux mots-clés :

• Set : sera appelée lorsque l'on assignera une valeur à cette propriété ;

• Get : sera appelée lorsque l'on demandera une valeur à cette propriété.

Pour le moment l'argument fourni au Set n'a pas de type défini, ce qui est renvoyé non plus. Commençons par les définir :

Public Property Position() As Point
        Get

        End Get
        Set(ByVal value As Point)

        End Set
    End Property

On attend donc un Point et on renvoie un Point.

Notre propriété va seulement assigner la valeur à la variable _CoordonneesActuelles et renvoyer sa valeur, rien de bien sorcier (vous pouvez même le faire par vous-mêmes) mais on aurait pu effectuer beaucoup d'autre choses en même temps. Assigner plusieurs variables, incrémenter un compteur, les possibilités sont infinies. :D

Voici donc la propriété au final :

Public Property Position() As Point
        Get
            Return _CoordonneesActuelles
        End Get
        Set(ByVal value As Point)
            _CoordonneesActuelles = value
        End Set
    End Property

On assigne la valeur, on la retourne.

Avec cette nouvelle propriété et la fonction précédente, on peut désormais retourner sur notre code relatif à la fenêtre et faire bouger Mario simplement en quelques lignes :

Public Class PlateauDeJeu

    'Mario déclaré en global
    Dim MonMario As Mario
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Un nouveau Mario
        MonMario = New Mario(Me.PAN_MARIO.Location, Me.PAN_MARIO.Size)
    End Sub

    Private Sub BT_AVANCE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_AVANCE.Click
        'On le fait avancer
        MonMario.Avance()
        'On recupère la nouvelle position
        Me.PAN_MARIO.Location = MonMario.Position
    End Sub

End Class

Je déclare un Mario en variable globale, donc il sera accessible et utilisable pendant toute la durée de vie de la fenêtre. Je l'instancie au load de la fenêtre en passant la position du panel et ses dimensions en paramètres au constructeur. Puis lors du clic sur le bouton, on fait avancer Mario et on récupère sa nouvelle position pour l'affecter au panel.

Vous pouvez essayer, ça fonctionne !

Cette section est là pour vous donner le reste du code de notre déplacement de Mario, on s'en servira sûrement plus tard.

La figure suivante vous montre à quoi ressemble ma fenêtre finale (on mettra une image de Mario plus tard ;) )

Ma classe :

Public Class Mario

    Private _CoordonneesActuelles As Point
    Private _Taille As Size

    Sub New(ByVal PositionOriginelle As Point, ByVal TailleMario As Size)
        _CoordonneesActuelles = New Point(PositionOriginelle)
        _Taille = New Size(TailleMario)
    End Sub

    Public Sub Avance()
        _CoordonneesActuelles.X = _CoordonneesActuelles.X + _PasX()
    End Sub

    Public Sub Recule()
        _CoordonneesActuelles.X = _CoordonneesActuelles.X - _PasX()
    End Sub

    Public Sub Monte()
        _CoordonneesActuelles.Y = _CoordonneesActuelles.Y - _PasY()
    End Sub

    Public Sub Descend()
        _CoordonneesActuelles.Y = _CoordonneesActuelles.Y + _PasY()
    End Sub

    Public Property Position() As Point
        Get
            Return _CoordonneesActuelles
        End Get
        Set(ByVal value As Point)
            _CoordonneesActuelles = value
        End Set
    End Property

#Region "Fonctions privées"

    Private Function _PasX()
        Return _Taille.Width
    End Function

    Private Function _PasY()
        Return _Taille.Height
    End Function

#End Region

End Class

Et le code final avec la gestion des touches :

Public Class PlateauDeJeu

    'Mario déclaré en global
    Dim MonMario As Mario

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Se met en écoute des touches
        Me.KeyPreview = True
        'Un nouveau Mario
        MonMario = New Mario(Me.PAN_MARIO.Location, Me.PAN_MARIO.Size)
    End Sub

    Sub Form1_KeyDown(ByVal sender As Object, ByVal e As KeyEventArgs) Handles Me.KeyDown
        Select Case e.KeyCode
            Case Keys.Z
                MonMario.Monte()
            Case Keys.S
                MonMario.Descend()
            Case Keys.Q
                MonMario.Recule()
            Case Keys.D
                MonMario.Avance()
        End Select
        Me.PAN_MARIO.Location = MonMario.Position
    End Sub


#Region "Boutons de l'interface"

    Private Sub BT_AVANCE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_AVANCE.Click
        'On le fait avancer
        MonMario.Avance()
        'On recupère la nouvelle position
        Me.PAN_MARIO.Location = MonMario.Position
    End Sub

    Private Sub BT_RECULE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_RECULE.Click
        'On le fait reculer
        MonMario.Recule()
        'On recupère la nouvelle position
        Me.PAN_MARIO.Location = MonMario.Position
    End Sub

    Private Sub BT_DESCEND_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_DESCEND.Click
        'On le fait descendre
        MonMario.Descend()
        'On recupère la nouvelle position
        Me.PAN_MARIO.Location = MonMario.Position
    End Sub

    Private Sub BT_MONTE_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BT_MONTE.Click
        'On le fait monter
        MonMario.Monte()
        'On recupère la nouvelle position
        Me.PAN_MARIO.Location = MonMario.Position
    End Sub

#End Region

End Class

Voilà. Amusez-vous bien. :)

• Une classe contient des variables au même titre que notre programme principal.

• Pour chaque classe instanciée, la variable va être différente.

• Donc chaque classe est unique et se comportera différemment en fonction des ses attributs et méthodes.

Premier concept important : l'héritage. J'ai déjà tenté de vous exposer cette notion dans la partie sur les fenêtres, mais ce n'était pas très judicieux, vous ne connaissiez pas la POO. On va donc tout recommencer ici.

Bon, j'espère que les principes de création de classe et de programmation orientée objet sont acquis. Je sais que c'est une rude partie, mais allez chercher un café et reprenez tout ça calmement.

Vous connaissez tous les mots français « héritage » et « hériter ». Wikipédia nous donne la définition suivante : « devenir propriétaire d’une chose par droit de succession ». Eh bien ce concept est quasiment le même en programmation, à une petite nuance près. Dans la vraie vie un héritage transmet simplement une chose, en programmation l'héritage d'une classe va dupliquer cette dernière et donner ses caractéristiques à la classe qui hérite.

Regardez la figure suivante.

Admettons que je veuille créer deux classes comme celles-là. Une classe Guitare et une classe Piano. Vous remarquez qu'elles présentent des similitudes, elles possèdent toutes les deux un attribut Notes qui va contenir le panel de notes que cet instrument peut jouer et un Sub Joue qui va lui permettre de produire un son.

En plus de ces deux éléments communs, elles présentent des particularités spécifiques à leur type : la guitare aura en plus le nombre de cordes qu'elle possède et une fonction permettant d'utiliser le vibrato. Le piano quand à lui, contiendra une variable comptant le nombre de touches qu'il possède et un Sub pour appuyer sur une touche spécifique.

Vous remarquez tout de suite que ces similitudes vont devoir être écrites en double. Beaucoup de travail et de lignes pour rien. C'est pour cela que les programmeurs ont introduit le concept de l'héritage.

Regardez, si nous créons une troisième classe nommée Instrument qui contient des choses communes à tous les instruments, comme l'attribut Notes par exemple, il serait simple d'inclure cette classe dans les autres, de façon à bénéficier de ses caractéristiques, comme le montre le schéma de la figure suivante.

C'est justement là toute la puissance de l'héritage. En une ligne de programmation nous allons pouvoir faire hériter nos classes Guitare et Piano de Instrument de façon à leur donner la possibilité d'utiliser ses membres.

Eh bien d'un point de vue extérieur à la classe, une fois instanciée par exemple, c'est transparent. C'est-à-dire qu'on ne saura pas si le membre de la classe auquel on va accéder appartient à la classe mère ou fille.

En revanche, d'un point de vue interne à la classe, ça se complique. Nous allons devoir apprendre à jongler entre les membres appartenant à la classe fille ou à la classe mère au travers de préfixes (du même type que Me).

Ce mot est MyBase.

Dans le schéma visible à la figure suivante, on se place du point de vue de la classe fille. Si depuis cette classe fille on débute une ligne par Me., les membres auxquels nous pourrons accéder seront ceux de la classe fille et de toutes les classes dont elle hérite. En revanche, en utilisant MyBase. nous accèderons uniquement aux membres de la classe mère.

Cette information va nous être très précieuse, surtout lorsque nous allons faire appel à des classes héritées qui ont besoin d'être instanciées.

Vous avez deux choix possibles dans notre exemple : créer un constructeur dans Instrument ou non. Si vous décidez de ne pas en mettre, cette classe va être considérée comme abstraite (le chapitre d'après). En revanche, si vous décidez de mettre un constructeur, il va falloir instancier la classe mère au même moment que la classe fille.

Bon, arrêtons la théorie et attaquons tout de suite la pratique pour que vous puissiez voir concrètement à quoi ça ressemble.

Public Class Instrument

    Private _Notes() As Integer

    Sub New(ByVal Notes() as Integer)
        _Notes = Notes
    End Sub

End Class

Public Class Guitare
    Inherits Instrument 'Hérite d'Instrument
    
    Private _NbCordes As Integer

    Sub New(ByVal Notes() As Integer, ByVal NbCordes As Integer)
        MyBase.New(Notes) 'On instancie la mère
        _NbCordes  = NbCordes
    End Sub

End Class

Dans ce petit bout de code, j'ai créé deux classes : Instrument et Guitare.

La classe Instrument est la classe mère, elle a un attribut _Notes et un constructeur. La classe Guitare est la classe fille, elle a également un attribut _NbCordes et un constructeur.

La ligne Inherits Instrument indique que la classe hérite d'Instrument. Et lors de l'instanciation de la classe fille, le constructeur de la classe mère est lui aussi appelé via MyBase.New(Notes).

Une classe abstraite est une classe ne pouvant pas être instanciée, autrement dit on ne peut pas créer d'objet à partir de ce moule.

Elle va permettre de créer des classes dérivées. En clair, cette classe va seulement servir de base (une classe mère) pour des classes qui vont en dériver. Comme notre exemple sur les instruments. Une guitare, un piano, bref des instruments concrets, nous allons les instancier et les utiliser. Cependant la classe Instrument, la classe mère de toutes les autres, nous aurions pu la définir en classe abstraite.

Donc notre précédent code va devenir :

Public MustInherit Class Instrument

    Private _Notes() As Integer

    Public Property Notes As Integer()
        Set(ByVal value() As Integer)
            _Notes = value
        End Set
        Get
            Return _Notes
        End Get
    End Property

End Class

Public Class Guitare
    Inherits Instrument 'Hérite d'Instrument

    Private _NbCordes As Integer

    Sub New(ByVal Notes() As Integer, ByVal NbCordes As Integer)
        MyBase.Notes = Notes 'On spécifie la propriété Notes de la mère
        _NbCordes = NbCordes
    End Sub

End Class

Vous voyez qu'ici le mot-clé MustInherit spécifié dans la déclaration de la classe (qui signifie en français « doit hériter », mais qu'il est mieux de traduire par « doit être hérité »), spécifie que cette classe sera abstraite, elle ne pourra pas être utilisée telle quelle.

Ma classe Guitare est donc ici pour hériter d'Instrument. Une fois la classe Guitare instanciée, on peut très bien accéder aux membres d'Instrument. La syntaxe MaGuitare.Notes(0) est tout à fait correcte (où MaGuitare est mon objet créé).

Il existe toutefois une seconde utilisation possible pour les classes abstraites ; en tant que bibliothèques de fonctions.

Plutôt que de placer toutes vos fonctions dans le fichier qui contient la fenêtre, il vous est possible de créer un fichier de classe, nommé « Fonctions » par exemple, et d'y inscrire des fonctions qui pourront être utilisées à partir de n'importe où dans votre programme.

Public Class Fonctions

    Shared Function Somme(ByVal X As Integer, ByVal y As Integer) As Integer
        Return X + y
    End Function

    Shared Function Difference(ByVal X As Integer, ByVal y As Integer) As Integer
        Return X - y
    End Function

End Class

Ma classe Fonctions, j'ai retiré le mot MustInherit.

Vous vous apercevez que mes fonctions ne sont pas publiques ou privées, mais Shared. Le mot-clé Shared, signifiant « partagé » en français, indique que cette fonction peut être utilisée sans avoir besoin d'instancier la classe. Autrement dit, dans le programme on pourra utiliser Fonctions.Addition(1,2) où l'on veut.

Les avantages : la possibilité de regrouper des fonctions utiles dans le même fichier. Les inconvénients : puisque la classe n'est pas instanciée, il n'est pas possible d'accéder à des membres externes à la fonction. Des variables globales ne pourront pas être utilisées par exemple.

Vous vous souvenez des événements dans nos contrôles ? Eh bien ici c'est le même principe.

Un événement est une fonction appelée lorsque quelque chose se produit. Ce « quelque chose » peut être l'appui d'un clic sur un bouton, l'insertion de texte dans une textbox, le chargement d'une fenêtre, etc. Vous vous souvenez du mot-clé Handles ? C'est ce qui indique l'écoute d'un événement sur un objet. On avait l'habitude de l'utiliser pour des contrôles visuels, nous allons désormais apprendre à écouter un événement sur notre classe.

Pour commencer, il faut spécifier ce qui va déclencher l'événement à l'intérieur de notre classe.

Dans ma classe je déclare un timer en global avec WithEvents, ce qui signifie que je vais pouvoir écouter les événements de cet objet. Vous avez déjà utilisé un timer en tant que contrôle (les contrôles étant d'office avec WithEvents), cette fois il ne sera visible que côté code. Je l'instancie, puis le lance dans le constructeur avec une seconde en interval, j'utilise la fonction Start() pour le démarrer plutôt que Enable = true.

Dans l'événement Tick du timer, j'incrémente un compteur ; une fois arrivé à 10 je déclenche l'événement.

Ça donne le code suivant dans notre classe :

Private WithEvents _Tim As Timer
    Private _Compteur As Integer

    Sub New()
        _Tim = New Timer
        _Tim.Interval = 1000
        _Tim.Start()
        _Compteur = 0
    End Sub

    Public Event DixSecondes()

    Sub _Tim_Tick() Handles _Tim.Tick
        _Compteur += 1
        If _Compteur = 10 Then
            RaiseEvent DixSecondes()
        End If
    End Sub

Vous voyez pour commencer la déclaration des variables (compteur et timer). Puis le constructeur initialise, instancie et démarre tout ça. Vient l'événement Tick du timer, je compte et je déclenche l'événement avec le mot-clé RaiseEvent. L'événement déclenché doit être déclaré : Public Event DixSecondes(), en public pour pouvoir « l'écouter » de l'extérieur.

Allons du côté de notre fenêtre qui va instancier notre objet. La classe déclarée en globale doit être faite avec le mot-clé WithEvents également :

Dim WithEvents MaClasse1 As MaClasse

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        MaClasse1 = New MaClasse1()
    End Sub

    Sub AttendsLesDixSecondes() Handles MaClasse1.DixSecondes
        MsgBox("Dix secondes que l'objet est crée")
    End Sub

Puis je l'instancie dans le form.

Pour finir j'ai écouté l'événement avec Sub AttendsLesDixSecondes() Handles MaClasse1.DixSecondes. Lorsque les 10 secondes sont écoulées, je déclenche une MsgBox.

Avec des arguments

Et on peut passer des arguments avec nos événements. Côté classe on déclare l'événement avec :

Public Event DixSecondes(ByVal Message As String)

On voit qu'il attend un argument de type String.

Donc lorsqu’on va l'appeler :

RaiseEvent DixSecondes("Dix secondes que l'objet est crée")

… je lui passe mon argument. Et finalement côté fenêtre, le Handles de mon événement s'effectue ainsi :

Sub AttendsLesDixSecondes(ByVal Message As String) Handles MaClasse1.DixSecondes
        MsgBox(Message)
    End Sub

Même si vous ne savez pas ce que ce mot signifie, je peux vous dire que vous y avez déjà été confrontés. Souvenez-vous, lorsque vous passez des arguments à une fonction et que l'assistant de Visual Basic vous propose plusieurs possibilités pour passer ces arguments, comme à la figure suivante.

Vous voyez que l'infobulle spécifie « 2 sur 15 ». J'ai choisi la seconde possibilité, sur quinze possibles, de donner les arguments. C'est cela la surcharge, pour la même fonction, avoir plusieurs « résultats » possibles en fonction du passage des arguments.

Créons tout de suite un constructeur surchargé pour vous montrer ce que cela implique :

Public MustInherit Class Instrument

    Private _Notes() As Integer

    Public Property Notes As Integer()
        Set(ByVal value() As Integer)
            _Notes = value
        End Set
        Get
            Return _Notes
        End Get
    End Property

End Class

Public Class Guitare
    Inherits Instrument 'Hérite d'Instrument

    Private _NbCordes As Integer

    Sub New()
        _NbCordes = 0
    End Sub

    Sub New(ByVal Notes() As Integer)
        MyBase.Notes = Notes
        _NbCordes = 0
    End Sub

    Sub New(ByVal Notes() As Integer, ByVal NbCordes As Integer)
        MyBase.Notes = Notes
        _NbCordes = NbCordes
    End Sub

End Class

J'ai déclaré dans ma classe Guitare trois constructeurs différents, j'ai donc surchargé le constructeur.

Ce qui me donne le droit à l'infobulle visible à la figure suivante lorsque je veux l'instancier.

Deux fonctions avec des arguments de types différents apportent aussi une surcharge :

Sub New(ByVal Notes() As Integer, ByVal NbCordes As Integer)
        MyBase.Notes = Notes
        _NbCordes = NbCordes
    End Sub

    Sub New(ByVal Notes() As Integer, ByVal NbCordes As String)
        MyBase.Notes = Notes
        _NbCordes = NbCordes
    End Sub

Ici le nombre de cordes est une fois un String, une autre fois un Integer, la fonction appelée va dépendre du type passé lors de l'instanciation.

Surcharger la classe mère

Pour surcharger une méthode de la classe mère, la technique est presque la même. Il va juste falloir ajouter le mot-clé Overloads devant la méthode de la classe fille. Ce qui nous donne :

Public MustInherit Class Instrument

    Private _Notes() As Integer

    Public Property Notes As Integer()
        Set(ByVal value() As Integer)
            _Notes = value
        End Set
        Get
            Return _Notes
        End Get
    End Property

    Sub Joue()
        'Ding
    End Sub

End Class

Public Class Guitare
    Inherits Instrument 'Hérite d'Instrument

    Private _NbCordes As Integer

    Sub New(ByVal Notes() As Integer, ByVal NbCordes As Integer)
        MyBase.Notes = Notes
        _NbCordes = NbCordes
    End Sub

    Overloads Sub Joue(ByVal Note As Integer)
        'Ding
    End Sub

End Class

J'ai bien ajouté Overloads devant la méthode Joue de la classe fille, et lors de son appel j'ai le choix entre les deux possibilités : avec ou sans argument.

Dernière chose : on peut « bypasser » une méthode mère. Autrement dit, créer une méthode de la même déclaration dans l'enfant et spécifier que c'est cette dernière qui a la priorité sur l'autre. Cela grâce à Overrides.

Public MustInherit Class Instrument

    Private _Notes() As Integer

    Public Property Notes As Integer()
        Set(ByVal value() As Integer)
            _Notes = value
        End Set
        Get
            Return _Notes
        End Get
    End Property

    Overridable Sub Joue()
        'Ding
    End Sub

End Class

Public Class Guitare
    Inherits Instrument 'Hérite d'Instrument

    Private _NbCordes As Integer

    Sub New(ByVal Notes() As Integer, ByVal NbCordes As Integer)
        MyBase.Notes = Notes
        _NbCordes = NbCordes
    End Sub

    Overrides Sub Joue()
        MyBase.Joue() 'Ding de la mère
        'Ding
    End Sub

End Class

La méthode Joue de la fille prime sur la mère. Le mot-clé Overrides dans la déclaration de la méthode fille est nécessaire, tout comme le mot-clé Overridable dans la déclaration de la méthode mère.

Et j'ai pu utiliser MyBase.Joue() pour que la méthode mère soit quand même appelée.

Paramètres dans les propriétés

Avant de comprendre les propriétés par défaut il faut juste que je vous montre comment utiliser un paramètre dans une propriété, ça me semble logique, mais quelques lignes d'éclaircissement ne feront pas de mal. Admettons que je veuille accéder à un certain index dans un tableau à partir d'une propriété, je vais devoir passer un argument à cette dernière :

Module Module1

    Sub Main()
        Dim MaClasse As New Classe
        Console.WriteLine(MaClasse.Variable(0))
        Console.Read()
    End Sub

End Module

Public Class Classe

    Dim _Variable() As String

    Sub New()
        _Variable = {"a", "b", "c", "d"}
    End Sub

    Property Variable(ByVal Index As Integer) As String
        Get
            Return _Variable(Index)
        End Get
        Set(ByVal value As String)
            _Variable(Index) = value
        End Set
    End Property

End Class

Ici (je ne devrais même plus avoir à vous expliquer le code je pense :p ), je demande lors de l'appel de la propriété un paramètre spécifiant l'index, même principe qu'une fonction demandant des arguments : Property Variable(ByVal Index As Integer) As String.

Les propriétés par défaut

Les propriétés par défaut vont vous permettre de vous soustraire à quelques lignes dans votre code source.
Ce concept a pour but d'attribuer à une certaine propriété la particularité d'être « par défaut ».

Lorsque vous voudrez utiliser cette propriété vous n'aurez plus besoin d'écrire MaClasse.Variable(0), mais seulement MaClasse(0).

À utiliser avec précaution si vous ne voulez pas vite être embrouillés. :)

Un simple mot suffit dans le code que je viens de faire, pour la spécifier en défaut :

Module Module1

    Sub Main()
        Dim MaClasse As New Classe
        Console.WriteLine(MaClasse(0))
        Console.Read()
    End Sub

End Module

Public Class Classe

    Dim _Variable() As String

    Sub New()
        _Variable = {"a", "b", "c", "d"}
    End Sub

    Default Property Variable(ByVal Index As Integer) As String
        Get
            Return _Variable(Index)
        End Get
        Set(ByVal value As String)
            _Variable(Index) = value
        End Set
    End Property

End Class

Le mot-clé Default spécifie quelle propriété doit être considérée comme étant celle par défaut.

Surcharge d'opérateurs

Comme son nom l'indique, cette surcharge va être spécifique aux opérateurs +, -, /, *, &, =, <, >, Not, And, et j'en passe…

Vous savez déjà qu'ils n'ont pas la même action en fonction des types que vous utilisez :

• Entre deux Integer : 10 + 10 = 20 ;

• Entre deux String : « Sal » + « ut » = « Salut » ;

• Entre deux Date : CDate("20/10/2010") + CDate("20/10/2010")= 20/10/201020/10/2010.